1 ;; (define apply-in-underlying-scheme apply)
2 ;; (define eval-in-underlying-scheme eval)
3 
4 (define (eval exp env)
5   (cond ((self-evaluating? exp) exp)
6         ((variable? exp) (lookup-variable-value exp env))
7         ((quoted? exp) (text-of-quotation exp))
8         ((assignment? exp) (eval-assignment exp env))
9         ((definition? exp) (eval-definition exp env))
10         ((if? exp) (eval-if exp env))
11 	((and? exp) (eval-and exp env))
12 	((or? exp) (eval-or exp env))
13         ((lambda? exp)
14          (make-procedure (lambda-parameters exp)
15                          (lambda-body exp)
16                          env))
17         ((begin? exp) 
18          (eval-sequence (begin-actions exp) env))
19         ((cond? exp) (eval (cond->if exp) env))
20 	((let? exp) (eval (let->combination exp) env))
21         ((application? exp)
22          (apply (eval (operator exp) env)
23                 (list-of-values (operands exp) env)))
24         (else
25          (error "Unknown expression type -- EVAL" exp))))
26 
27 (define (apply procedure arguments)
28   (cond ((primitive-procedure? procedure)
29          (apply-primitive-procedure procedure arguments))
30         ((compound-procedure? procedure)
31          (eval-sequence
32            (procedure-body procedure)
33            (extend-environment
34              (procedure-parameters procedure)
35              arguments
36              (procedure-environment procedure))))
37         (else
38          (error
39           "Unknown procedure type -- APPLY" procedure))))
40 (define (list-of-values exps env)
41   (if (no-operands? exps)
42       '()
43       (cons (eval (first-operand exps) env)
44             (list-of-values (rest-operands exps) env))))
45 
46 (define (eval-if exp env)
47   (if (true? (eval (if-predicate exp) env))
48       (eval (if-consequent exp) env)
49       (eval (if-alternative exp) env)))
50 (define (eval-sequence exps env)
51   (cond ((last-exp? exps) (eval (first-exp exps) env))
52         (else (eval (first-exp exps) env)
53               (eval-sequence (rest-exps exps) env))))
54 (define (eval-assignment exp env)
55   (set-variable-value! (assignment-variable exp)
56                        (eval (assignment-value exp) env)
57                        env)
58   'ok)
59 (define (eval-definition exp env)
60   (define-variable! (definition-variable exp)
61                     (eval (definition-value exp) env)
62                     env)
63   'ok)
64 (define (self-evaluating? exp)
65   (cond ((number? exp) true)
66         ((string? exp) true)
67         (else false)))
68 (define (variable? exp) (symbol? exp))
69 (define (quoted? exp)
70   (tagged-list? exp 'quote))
71 
72 (define (text-of-quotation exp) (cadr exp))
73 (define (tagged-list? exp tag)
74   (if (pair? exp)
75       (eq? (car exp) tag)
76       false))
77 (define (assignment? exp)
78   (tagged-list? exp 'set!))
79 (define (assignment-variable exp) (cadr exp))
80 (define (assignment-value exp) (caddr exp))
81 (define (definition? exp)
82   (tagged-list? exp 'define))
83 (define (definition-variable exp)
84   (if (symbol? (cadr exp))
85       (cadr exp)
86       (caadr exp)))
87 (define (definition-value exp)
88   (if (symbol? (cadr exp))
89       (caddr exp)
90       (make-lambda (cdadr exp)   ; formal parameters
91                    (cddr exp)))) ; body
92 (define (lambda? exp) (tagged-list? exp 'lambda))
93 (define (lambda-parameters exp) (cadr exp))
94 (define (lambda-body exp) (cddr exp))
95 (define (make-lambda parameters body)
96   (cons 'lambda (cons parameters body)))
97 (define (if? exp) (tagged-list? exp 'if))
98 (define (if-predicate exp) (cadr exp))
99 (define (if-consequent exp) (caddr exp))
100 (define (if-alternative exp)
101   (if (not (null? (cdddr exp)))
102       (cadddr exp)
103       'false))
104 (define (make-if predicate consequent alternative)
105   (list 'if predicate consequent alternative))
106 (define (begin? exp) (tagged-list? exp 'begin))
107 (define (begin-actions exp) (cdr exp))
108 (define (last-exp? seq) (null? (cdr seq)))
109 (define (first-exp seq) (car seq))
110 (define (rest-exps seq) (cdr seq))
111 
112 (define (sequence->exp seq)
113   (cond ((null? seq) seq)
114         ((last-exp? seq) (first-exp seq))
115         (else (make-begin seq))))
116 (define (make-begin seq) (cons 'begin seq))
117 (define (application? exp) (pair? exp))
118 (define (operator exp) (car exp))
119 (define (operands exp) (cdr exp))
120 (define (no-operands? ops) (null? ops))
121 (define (first-operand ops) (car ops))
122 (define (rest-operands ops) (cdr ops))
123 (define (true? x)
124   (not (eq? x false)))
125 (define (false? x)
126   (eq? x false))
127 (define (make-procedure parameters body env)
128   (list 'procedure parameters body env))
129 (define (compound-procedure? p)
130   (tagged-list? p 'procedure))
131 (define (procedure-parameters p) (cadr p))
132 (define (procedure-body p) (caddr p))
133 (define (procedure-environment p) (cadddr p))
134 (define (enclosing-environment env) (cdr env))
135 (define (first-frame env) (car env))
136 (define the-empty-environment '())
137 (define (make-frame variables values)
138   (cons variables values))
139 (define (frame-variables frame) (car frame))
140 (define (frame-values frame) (cdr frame))
141 (define (add-binding-to-frame! var val frame)
142   (set-car! frame (cons var (car frame)))
143   (set-cdr! frame (cons val (cdr frame))))
144 (define (extend-environment vars vals base-env)
145   (if (= (length vars) (length vals))
146       (cons (make-frame vars vals) base-env)
147       (if (< (length vars) (length vals))
148           (error "Too many arguments supplied" vars vals)
149           (error "Too few arguments supplied" vars vals))))
150 (define (lookup-variable-value var env)
151   (define (env-loop env)
152     (define (scan vars vals)
153       (cond ((null? vars)
154              (env-loop (enclosing-environment env)))
155             ((eq? var (car vars))
156              (car vals))
157             (else (scan (cdr vars) (cdr vals)))))
158     (if (eq? env the-empty-environment)
159         (error "Unbound variable" var)
160         (let ((frame (first-frame env)))
161           (scan (frame-variables frame)
162                 (frame-values frame)))))
163   (env-loop env))
164 (define (set-variable-value! var val env)
165   (define (env-loop env)
166     (define (scan vars vals)
167       (cond ((null? vars)
168              (env-loop (enclosing-environment env)))
169             ((eq? var (car vars))
170              (set-car! vals val))
171             (else (scan (cdr vars) (cdr vals)))))
172     (if (eq? env the-empty-environment)
173         (error "Unbound variable -- SET!" var)
174         (let ((frame (first-frame env)))
175           (scan (frame-variables frame)
176                 (frame-values frame)))))
177   (env-loop env))
178 (define (define-variable! var val env)
179   (let ((frame (first-frame env)))
180     (define (scan vars vals)
181       (cond ((null? vars)
182              (add-binding-to-frame! var val frame))
183             ((eq? var (car vars))
184              (set-car! vals val))
185             (else (scan (cdr vars) (cdr vals)))))
186     (scan (frame-variables frame)
187           (frame-values frame))))
188 (define (primitive-procedure? proc)
189   (tagged-list? proc 'primitive))
190 
191 (define (primitive-implementation proc) (cadr proc))
192 (define primitive-procedures
193   (list (list 'car car)
194         (list 'cdr cdr)
195 	(list 'caar caar)
196 	(list 'cadr cadr)
197 	(list 'cddr cddr)
198         (list 'cons cons)
199         (list 'null? null?)
200 	(list '* *)
201 	(list '/ /)
202 	(list '+ +)
203 	(list '- -)
204 	(list '= =)
205 	(list 'eq? eq?)
206 	(list 'equal? equal?)
207 	(list 'display display)))
208 (define (primitive-procedure-names)
209   (map car
210        primitive-procedures))
211 
212 (define (primitive-procedure-objects)
213   (map (lambda (proc) (list 'primitive (cadr proc)))
214        primitive-procedures))
215 (define (apply-primitive-procedure proc args)
216   (apply-in-underlying-scheme
217    (primitive-implementation proc) args))
218 (define input-prompt ";;; M-Eval input:")
219 (define output-prompt ";;; M-Eval value:")
220 (define (driver-loop)
221   (prompt-for-input input-prompt)
222   (let ((input (read)))
223     (let ((output (eval input the-global-environment)))
224       (announce-output output-prompt)
225       (user-print output)))
226   (driver-loop))
227 (define (prompt-for-input string)
228   (newline) (newline) (display string) (newline))
229 
230 (define (announce-output string)
231   (newline) (display string) (newline))
232 (define (user-print object)
233   (if (compound-procedure? object)
234       (display (list 'compound-procedure
235                      (procedure-parameters object)
236                      (procedure-body object)
237                      '<procedure-env>))
238       (display object)))
239 (define (setup-environment)
240   (let ((initial-env
241          (extend-environment (primitive-procedure-names)
242                              (primitive-procedure-objects)
243                              the-empty-environment)))
244     (define-variable! 'true true initial-env)
245     (define-variable! 'false false initial-env)
246     initial-env))
247 (define the-global-environment (setup-environment))
248 
249 (define (make-let vars vals body)
250   (cons 'let
251 	(cons (map (lambda (var val)
252 		     (list var val))
253 		   vars vals)
254 	      body)))
255 (define (let? exp)
256   (tagged-list? exp 'let))
257 (define (let-vars exp)
258   (map car (cadr exp)))
259 (define (let-vals exp)
260   (map cadr (cadr exp)))
261 (define (let-body exp)
262   (cddr exp))
263 (define (let->combination exp)
264   (make-application (make-lambda (let-vars exp) (let-body exp))
265 		    (let-vals exp)))
266 (define (make-application op args)
267   (cons op args))
268 
269 (define (test-case actual expected)
270   (newline)
271   (display "Actual:   ")
272   (display actual)
273   (newline)
274   (display "Expected: ")
275   (display expected)
276   (newline))
277 
278 (define (geval exp) ;; eval globally
279   (eval exp the-global-environment))
280 
281 ;; Exercise 4.4.  Recall the definitions of the special forms and and or from chapter 1:
282 
283 ;;    and: The expressions are evaluated from left to right. If any expression evaluates to false, false is returned; any remaining expressions are not evaluated. If all the expressions evaluate to true values, the value of the last expression is returned. If there are no expressions then true is returned.
284 
285 ;;    or: The expressions are evaluated from left to right. If any expression evaluates to a true value, that value is returned; any remaining expressions are not evaluated. If all expressions evaluate to false, or if there are no expressions, then false is returned. 
286 
287 ;; Install and and or as new special forms for the evaluator by defining appropriate syntax procedures and evaluation procedures eval-and and eval-or. Alternatively, show how to implement and and or as derived expressions. 
288 
289 (define (and? exp)
290   (tagged-list? exp 'and))
291 (define (and-clauses exp)
292   (cdr exp))
293 ;; (define (and->if exp)
294 ;;   (define (expand-clauses clauses)
295 ;;     (cond ((null? clauses) 'true)
296 ;; 	  ((null? (cdr clauses)) (car clauses))
297 ;; 	  (else (make-if (car clauses)
298 ;; 			 (expand-clauses (cdr clauses))
299 ;; 			 'false))))
300 ;;   (expand-clauses (and-clauses exp)))
301 (define (or? exp)
302   (tagged-list? exp 'or))
303 (define (or-clauses exp)
304   (cdr exp))
305 ;; the problem with this definition is that each clause will be evaluated twice; this is unacceptable if there are side effects
306 ;; (define (or->if exp)
307 ;;   (define (expand-clauses clauses)
308 ;;     (if (null? clauses)
309 ;; 	'false
310 ;;         (make-if (car clauses)
311 ;; 		 (car clauses)
312 ;; 		 (expand-clauses (cdr clauses)))))
313 ;;   (expand-clauses (or-clauses exp)))
314 
315 
316 ;; we can also install and/or as special forms
317 
318 (define (eval-and exp env)
319   (define (eval-clauses clauses)
320     (cond ((null? clauses) true)
321 	  ((null? (cdr clauses)) (eval (car clauses) env))
322 	  (else (and (eval (car clauses) env)
323 		     (eval-clauses (cdr clauses))))))
324   (eval-clauses (and-clauses exp)))
325 (define (eval-or exp env)
326   (define (eval-clauses clauses)
327     (if (null? clauses)
328 	false
329 	(or (eval (car clauses) env)
330 	    (eval-clauses (cdr clauses)))))
331   (eval-clauses (or-clauses exp)))
332 
333 
334 ;; Exercise 4.5.  Scheme allows an additional syntax for cond clauses, (<test> => <recipient>). If <test> evaluates to a true value, then <recipient> is evaluated. Its value must be a procedure of one argument; this procedure is then invoked on the value of the <test>, and the result is returned as the value of the cond expression. For example
335 
336 ;; (cond ((assoc 'b '((a 1) (b 2))) => cadr)
337 ;;       (else false))
338 
339 ;; returns 2. Modify the handling of cond so that it supports this extended syntax. 
340 
341 (define (cond? exp) (tagged-list? exp 'cond))
342 (define (cond-clauses exp) (cdr exp))
343 (define (cond-else-clause? clause)
344   (eq? (cond-predicate clause) 'else))
345 (define (cond-predicate clause) (car clause))
346 (define (cond-actions clause) (cdr clause))
347 (define (cond-extended-clause? clause)
348   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
349 (define (cond-extended-proc clause)
350   (caddr clause))
351 (define (cond->if exp)
352   (expand-clauses (cond-clauses exp)))
353 
354 (define (expand-clauses clauses)
355   (if (null? clauses)
356       'false                          ; no else clause
357       (let ((first (car clauses))
358             (rest (cdr clauses)))
359         (if (cond-else-clause? first)
360             (if (null? rest)
361                 (sequence->exp (cond-actions first))
362                 (error "ELSE clause isn't last -- COND->IF"
363                        clauses))
364 	    (if (cond-extended-clause? first)
365 		(make-if (cond-predicate first)
366 			 (make-application
367 			  (cond-extended-proc first)
368 			  (list (cond-predicate first)))
369 			 (expand-clauses rest))
370 		(make-if (cond-predicate first)
371 			 (sequence->exp (cond-actions first))
372 			 (expand-clauses rest)))))))
373 
374 
375 ;; procedure definitions
376 
377 (geval 
378  '(define (assoc key records)
379     (cond ((null? records) false)
380 	  ((equal? key (caar records)) (car records))
381 	  (else (assoc key (cdr records))))))
382 
383 (geval
384  '(define (map proc list)
385     (if (null? list)
386 	'()
387 	(cons (proc (car list))
388 	      (map proc (cdr list))))))
389 
390 (geval 
391  '(define (accumulate op initial sequence)
392     (if (null? sequence)
393 	initial
394 	(op (car sequence)
395 	    (accumulate op initial (cdr sequence))))))
396 
397 ;; cond
398 
399 (test-case
400  (geval 
401   '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
402 	 (else false)))
403  2)
404 
405 (test-case 
406  (geval '((lambda (x)
407 	    (accumulate + 0 x))
408 	  (map (lambda (x)
409 		 (* x (+ x 1)))
410 	       '(2 4 1 9))))
411  118)
412 
413 (test-case 
414  (geval
415   '(cond ((= 3 4) 'not-true)
416 	 ((= (* 2 4) 3) 'also-false)
417 	 ((map (lambda (x)
418 		 (* x (+ x 1)))
419 	       '(2 4 1 9))
420 	  =>
421 	  (lambda (x)
422 	    (accumulate + 0 x)))
423 	 (else 'never-reach)))
424  118)
425 ;; '(6 20 2 90)
426 
427 
428 ;; test-suite
429 
430 ;; make-let
431 (test-case (geval (make-let '(x y) '(3 5) '((+ x y))))
432 	   8)
433 
434 ;; and/or
435 (geval '(define x (+ 3 8)))
436 (test-case (geval '(and 0 true x)) 11)
437 (test-case (geval '(and 0 true x false)) false)
438 (test-case (geval '(and 0 true x (set! x -2) false)) false)
439 (test-case (geval 'x) -2)
440 (test-case (geval '(and 0 true x false (set! x -5))) false)
441 (test-case (geval 'x) -2)
442 (test-case (geval '(or false (set! x 25))) 'ok)
443 (test-case (geval 'x) 25)
444 (test-case (geval '(or (set! x 2) (set! x 4))) 'ok)
445 (test-case (geval 'x) 2)
446 (test-case (geval '(or false (set! x 25) true false)) 'ok)
447 (test-case (geval 'x) 25)
448 (test-case (geval '(or ((lambda (x) x) 5))) 5)
449 (test-case (geval '(or (begin (set! x (+ x 1)) x))) 26)
450 
451 
452 ;; all special forms
453 (test-case (geval '(begin 5 6)) 6)
454 (test-case (geval '10) 10)
455 (geval '(define x 3))
456 (test-case (geval 'x) 3)
457 (test-case (geval '(set! x -25)) 'ok)
458 (test-case (geval 'x) -25)
459 (geval '(define z (lambda (x y) (+ x (* x y)))))
460 (test-case (geval '(z 3 4)) 15)
461 (test-case (geval '(cond ((= x -2) 'x=-2)
462 			 ((= x -25) 'x=-25)
463 			 (else 'failed)))
464 	   'x=-25)
465 (test-case (geval '(if true false true)) false)
466 (test-case (geval 
467 	    '(let ((x 4) (y 7))
468 	       (+ x y (* x y))))
469 	   (+ 4 7 (* 4 7)))
470 
471 ;; procedure definition and application
472 (geval
473  '(define (factorial n)
474     (if (= n 0)
475 	1
476 	(* n (factorial (- n 1))))))
477 (test-case (geval '(factorial 5)) 120)
478 
479 ;; map
480 
481 (test-case
482  (geval '(map (lambda (x)
483 		(* x (+ x 1)))
484 	      '(2 1 4 2 8 3)))
485  '(6 2 20 6 72 12))
486 ;; accumulate
487 
488 (test-case
489  (geval
490   '(accumulate + 0 '(1 2 3 4 5)))
491  15)