1 ;; (define apply-in-underlying-scheme apply)
2 
3 (define (eval exp env)
4   (cond ((self-evaluating? exp) exp)
5         ((variable? exp) (lookup-variable-value exp env))
6         ((quoted? exp) (text-of-quotation exp))
7         ((assignment? exp) (eval-assignment exp env))
8         ((definition? exp) (eval-definition exp env))
9 ;;	((unbound? exp) (eval-unbound exp env))
10         ((if? exp) (eval-if exp env))
11 	((and? exp) (eval-and exp env))
12 	((or? exp) (eval-or exp env))
13         ((lambda? exp)
14          (make-procedure (lambda-parameters exp)
15                          (lambda-body exp)
16                          env))
17         ((begin? exp) 
18          (eval-sequence (begin-actions exp) env))
19         ((cond? exp) (eval (cond->if exp) env))
20 	((let? exp) (eval (let->combination exp) env))
21 	((let*? exp) (eval (let*->nested-lets exp) env))
22 	((named-let? exp) (eval (named-let->combination exp) env))
23 	((letrec? exp) (eval (letrec->let exp) env))
24 	((do? exp) (eval (do->combination exp) env))
25         ((application? exp)
26          (apply (actual-value (operator exp) env)
27                 (operands exp)
28 		env))
29         (else
30          (error "Unknown expression type -- EVAL" exp))))
31 (define (apply procedure arguments env)
32   (cond ((primitive-procedure? procedure)
33          (apply-primitive-procedure 
34 	  procedure 
35 	  (list-of-arg-values arguments env)))
36         ((compound-procedure? procedure)
37          (eval-sequence
38            (procedure-body procedure)
39            (extend-environment
40              (procedure-parameters procedure)
41              (list-of-delayed-args arguments env)
42              (procedure-environment procedure))))
43         (else
44          (error
45           "Unknown procedure type -- APPLY" procedure))))
46 
47 (define (thunk? obj)
48   (tagged-list? obj 'thunk))
49 (define (thunk-exp thunk)
50   (cadr thunk))
51 (define (thunk-env thunk)
52   (caddr thunk))
53 (define (evaluated-thunk? obj)
54   (tagged-list? obj 'evaluated-thunk))
55 (define (thunk-value evaluated-thunk)
56   (cadr evaluated-thunk))
57 (define (delay-it exp env)
58   `(thunk ,exp ,env))
59 (define (actual-value exp env)
60   (force-it (eval exp env)))
61 (define (force-it obj)
62   (cond ((thunk? obj)
63 	 (let ((result (actual-value 
64 			(thunk-exp obj)
65 			(thunk-env obj))))
66 	   (set-car! obj 'evaluated-thunk)
67 	   (set-car! (cdr obj) result)
68 	   (set-cdr! (cdr obj) '())
69 	   result))
70 	((evaluated-thunk? obj)
71 	 (thunk-value obj))
72 	(else obj)))
73 
74 (define (list-of-arg-values exps env)
75   (if (no-operands? exps)
76       '()
77       (cons (actual-value (first-operand exps) env)
78             (list-of-arg-values (rest-operands exps) env))))
79 (define (list-of-delayed-args exps env)
80   (if (no-operands? exps)
81       '()
82       (cons (delay-it (first-operand exps) env)
83 	    (list-of-delayed-args (rest-operands exps) env))))
84 
85 (define (tagged-list? exp tag)
86   (if (pair? exp)
87       (eq? (car exp) tag)
88       false))
89 
90 ;; self-evaluating/variable/quoted
91 (define (self-evaluating? exp)
92   (cond ((number? exp) true)
93         ((string? exp) true)
94         (else false)))
95 (define (variable? exp) (symbol? exp))
96 (define (quoted? exp)
97   (tagged-list? exp 'quote))
98 (define (text-of-quotation exp) (cadr exp))
99 
100 ;; assignment/definition
101 (define (assignment? exp)
102   (tagged-list? exp 'set!))
103 (define (assignment-variable exp) (cadr exp))
104 (define (assignment-value exp) (caddr exp))
105 (define (make-assignment var val)
106   (list 'set! var val))
107 (define (definition? exp)
108   (tagged-list? exp 'define))
109 (define (definition-variable exp)
110   (if (symbol? (cadr exp))
111       (cadr exp)
112       (caadr exp)))
113 (define (definition-value exp)
114   (if (symbol? (cadr exp))
115       (caddr exp)
116       (make-lambda (cdadr exp)   ; formal parameters
117                    (cddr exp)))) ; body
118 (define (eval-assignment exp env)
119   (set-variable-value! (assignment-variable exp)
120                        (eval (assignment-value exp) env)
121                        env)
122   'ok)
123 (define (eval-definition exp env)
124   (define-variable! (definition-variable exp)
125                     (eval (definition-value exp) env)
126                     env)
127   'ok)
128 (define (make-definition var val)
129   `(define ,var ,val))
130 
131 ;; make-unbound!
132 
133 ;; (define (unbound? exp)
134 ;;   (tagged-list? exp 'make-unbound!))
135 ;; (define (unbound-var exp)
136 ;;   (cadr exp))
137 ;; (define (eval-unbound exp env)
138 ;;   (remove-binding-from-frame! (unbound-var exp) (first-frame env)))
139 
140 
141 
142 ;; if/and/or
143 (define (if? exp) (tagged-list? exp 'if))
144 (define (if-predicate exp) (cadr exp))
145 (define (if-consequent exp) (caddr exp))
146 (define (if-alternative exp)
147   (if (not (null? (cdddr exp)))
148       (cadddr exp)
149       'false))
150 (define (make-if predicate consequent alternative)
151   (list 'if predicate consequent alternative))
152 (define (eval-if exp env)
153   (if (true? (actual-value (if-predicate exp) env))
154       (eval (if-consequent exp) env)
155       (eval (if-alternative exp) env)))
156 
157 (define (and? exp)
158   (tagged-list? exp 'and))
159 (define (and-clauses exp)
160   (cdr exp))
161 (define (or? exp)
162   (tagged-list? exp 'or))
163 (define (or-clauses exp)
164   (cdr exp))
165 (define (eval-and exp env)
166   (define (eval-clauses clauses)
167     (cond ((null? clauses) true)
168 	  ((null? (cdr clauses)) (eval (car clauses) env))
169 	  (else (and (eval (car clauses) env)
170 		     (eval-clauses (cdr clauses))))))
171   (eval-clauses (and-clauses exp)))
172 (define (eval-or exp env)
173   (define (eval-clauses clauses)
174     (if (null? clauses)
175 	false
176 	(or (eval (car clauses) env)
177 	    (eval-clauses (cdr clauses)))))
178   (eval-clauses (or-clauses exp)))
179 
180 
181 ;; lambda/let/let*/letrec
182 (define (lambda? exp) (tagged-list? exp 'lambda))
183 (define (lambda-parameters exp) (cadr exp))
184 (define (lambda-body exp) (cddr exp))
185 (define (make-lambda parameters body)
186   (cons 'lambda (cons parameters body)))
187 
188 (define (make-let vars vals body)
189   (cons 'let
190 	(cons (map list vars vals)
191 	      body)))
192 (define (let? exp)
193   (and (tagged-list? exp 'let)
194        (not (symbol? (cadr exp)))))
195 (define (let-vars exp)
196   (map car (cadr exp)))
197 (define (let-vals exp)
198   (map cadr (cadr exp)))
199 (define (let-body exp)
200   (cddr exp))
201 (define (let->combination exp)
202   (make-application (make-lambda (let-vars exp) (let-body exp))
203 		    (let-vals exp)))
204 (define (named-let? exp)
205   (and (tagged-list? exp 'let)
206        (symbol? (cadr exp))))
207 (define (named-let-name exp)
208   (cadr exp))
209 (define (named-let-vars exp)
210   (map car (caddr exp)))
211 (define (named-let-vals exp)
212   (map cadr (caddr exp)))
213 (define (named-let-body exp)
214   (cdddr exp))
215 (define (named-let->combination exp)
216   (sequence->exp
217    (list (make-definition (named-let-name exp)
218 			  (make-lambda (named-let-vars exp)
219 				       (named-let-body exp)))
220 	 (make-application (named-let-name exp)
221 			   (named-let-vals exp)))))
222 (define (make-named-let name vars vals body)
223   (cons 'let 
224 	(cons name
225 	      (cons (map list vars vals)
226 		    body))))
227 
228 (define (letrec? exp)
229   (tagged-list? exp 'letrec))
230 
231 (define (letrec-vars exp)
232   (map car (cadr exp)))
233 (define (letrec-vals exp)
234   (map cadr (cadr exp)))
235 (define (letrec-body exp)
236   (cddr exp))
237 (define (letrec->let exp)
238   (let* ((vars (letrec-vars exp))
239 	 (unassigneds (map (lambda (var) ''*unassigned*)
240 			   vars))
241 	 (vals (letrec-vals exp))
242 	 (assignments (map (lambda (var val)
243 			     (make-assignment var val))
244 			   vars
245 			   vals))
246 	 (body (letrec-body exp)))
247   (make-let vars 
248 	    unassigneds
249 	    (append assignments body))))
250 
251 
252 
253 
254 (define (let*? exp)
255   (tagged-list? exp 'let*))
256 (define let*-vars let-vars)
257 (define let*-vals let-vals)
258 (define let*-body let-body)
259 (define (let*->nested-lets exp)
260   (define (expand-lets vars vals)
261     (if (null? (cdr vars))
262 	(make-let (list (car vars)) 
263 		  (list (car vals))
264 		  (let*-body exp))
265 	(make-let (list (car vars))
266 		  (list (car vals))
267 		  (list (expand-lets (cdr vars) (cdr vals))))))
268   (let ((vars (let*-vars exp))
269 	(vals (let*-vals exp)))
270     (if (null? vars)
271 	(sequence->exp (let*-body exp))
272 	(expand-lets vars vals))))
273 
274 ;; do loop
275 (define (do? exp)
276   (tagged-list? exp 'do))
277 (define (do-vars exp)
278   (map car (cadr exp)))
279 (define (do-inits exp)
280   (map cadr (cadr exp)))
281 (define (do-steps exp)
282   (map (lambda (var-init-step)
283 	 (if (null? (cddr var-init-step))
284 	     (car var-init-step)
285 	     (caddr var-init-step)))
286        (cadr exp)))
287 (define (do-test exp)
288   (caaddr exp))
289 (define (do-expressions exp)
290   (if (null? (cdaddr exp))
291       (caddr exp)
292       (cdaddr exp)))
293 (define (do-commands exp)
294   (cdddr exp))
295 (define (do->combination exp)
296   (make-named-let
297    'do-iter
298    (do-vars exp)
299    (do-inits exp)
300    (list
301     (make-if
302      (do-test exp)
303      (sequence->exp (do-expressions exp))
304      (sequence->exp
305       (append (do-commands exp)
306 	      (list (make-application
307 		     'do-iter
308 		     (do-steps exp)))))))))
309 
310 
311 ;; begin/sequence
312 (define (begin? exp) (tagged-list? exp 'begin))
313 (define (begin-actions exp) (cdr exp))
314 (define (last-exp? seq) (null? (cdr seq)))
315 (define (first-exp seq) (car seq))
316 (define (rest-exps seq) (cdr seq))
317 (define (sequence->exp seq)
318   (cond ((null? seq) seq)
319         ((last-exp? seq) (first-exp seq))
320         (else (make-begin seq))))
321 (define (make-begin seq) (cons 'begin seq))
322 (define (eval-sequence exps env)
323   (cond ((last-exp? exps) (eval (first-exp exps) env))
324         (else (eval (first-exp exps) env)
325               (eval-sequence (rest-exps exps) env))))
326 
327 ;; application
328 (define (make-application op args)
329   (cons op args))
330 (define (application? exp) (pair? exp))
331 (define (operator exp) (car exp))
332 (define (operands exp) (cdr exp))
333 (define (no-operands? ops) (null? ops))
334 (define (first-operand ops) (car ops))
335 (define (rest-operands ops) (cdr ops))
336 
337 ;; cond
338 (define (cond? exp) (tagged-list? exp 'cond))
339 (define (cond-clauses exp) (cdr exp))
340 (define (cond-else-clause? clause)
341   (eq? (cond-predicate clause) 'else))
342 (define (cond-predicate clause) (car clause))
343 (define (cond-actions clause) (cdr clause))
344 (define (cond-extended-clause? clause)
345   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
346 (define (cond-extended-proc clause)
347   (caddr clause))
348 (define (cond->if exp)
349   (expand-clauses (cond-clauses exp)))
350 (define (expand-clauses clauses)
351   (if (null? clauses)
352       'false                          ; no else clause
353       (let ((first (car clauses))
354             (rest (cdr clauses)))
355         (if (cond-else-clause? first)
356             (if (null? rest)
357                 (sequence->exp (cond-actions first))
358                 (error "ELSE clause isn't last -- COND->IF"
359                        clauses))
360 	    (if (cond-extended-clause? first)
361 		(make-if (cond-predicate first)
362 			 (make-application
363 			  (cond-extended-proc first)
364 			  (list (cond-predicate first)))
365 			 (expand-clauses rest))
366 		(make-if (cond-predicate first)
367 			 (sequence->exp (cond-actions first))
368 			 (expand-clauses rest)))))))
369 (define (true? x)
370   (not (eq? x false)))
371 (define (false? x)
372   (eq? x false))
373 
374 ;; procedure
375 (define (make-procedure parameters body env)
376   (list 'procedure parameters body env))
377 ;; (define (scan-out-defines body)
378 ;;   (let* ((definitions (filter definition? body))
379 ;; 	 (vars (map definition-variable definitions))
380 ;; 	 (unassigneds (map (lambda (var) ''*unassigned*) 
381 ;; 			   vars))
382 ;; 	 (vals (map definition-value definitions))
383 ;; 	 (assignments 
384 ;; 	  (map (lambda (var val)
385 ;; 		 (make-assignment var val))
386 ;; 	       vars vals))
387 ;; 	 (exps (remove definition? body)))
388 ;;     (if (null? definitions)
389 ;; 	body
390 ;; 	(list
391 ;; 	 (make-let vars
392 ;; 		   unassigneds
393 ;; 		   (append assignments exps))))))
394 (define (compound-procedure? p)
395   (tagged-list? p 'procedure))
396 (define (procedure-parameters p) (cadr p))
397 (define (procedure-body p) (caddr p))
398 (define (procedure-environment p) (cadddr p))
399 
400 ;; environment
401 (define (enclosing-environment env) (cdr env))
402 (define (first-frame env) (car env))
403 (define the-empty-environment '())
404 (define (make-frame variables values)
405   (cons variables values))
406 (define (frame-variables frame) (car frame))
407 (define (frame-values frame) (cdr frame))
408 (define (add-binding-to-frame! var val frame)
409   (set-car! frame (cons var (car frame)))
410   (set-cdr! frame (cons val (cdr frame))))
411 (define (extend-environment vars vals base-env)
412   (if (= (length vars) (length vals))
413       (cons (make-frame vars vals) base-env)
414       (if (< (length vars) (length vals))
415           (error "Too many arguments supplied" vars vals)
416           (error "Too few arguments supplied" vars vals))))
417 (define (lookup-variable-value var env)
418   (define (env-loop env)
419     (define (scan vars vals)
420       (cond ((null? vars)
421              (env-loop (enclosing-environment env)))
422             ((eq? var (car vars))
423 	     (let ((val (car vals)))
424 	       (if (eq? val '*unassigned*)
425 		   (error "Var not yet defined -- LOOKUP-VARIABLE-VALUE" var)
426 		   val)))
427             (else (scan (cdr vars) (cdr vals)))))
428     (if (eq? env the-empty-environment)
429         (error "Unbound variable" var)
430         (let ((frame (first-frame env)))
431           (scan (frame-variables frame)
432                 (frame-values frame)))))
433   (env-loop env))
434 (define (set-variable-value! var val env)
435   (define (env-loop env)
436     (define (scan vars vals)
437       (cond ((null? vars)
438              (env-loop (enclosing-environment env)))
439             ((eq? var (car vars))
440              (set-car! vals val))
441             (else (scan (cdr vars) (cdr vals)))))
442     (if (eq? env the-empty-environment)
443         (error "Unbound variable -- SET!" var)
444         (let ((frame (first-frame env)))
445           (scan (frame-variables frame)
446                 (frame-values frame)))))
447   (env-loop env))
448 (define (define-variable! var val env)
449   (let ((frame (first-frame env)))
450     (define (scan vars vals)
451       (cond ((null? vars)
452              (add-binding-to-frame! var val frame))
453             ((eq? var (car vars))
454              (set-car! vals val))
455             (else (scan (cdr vars) (cdr vals)))))
456     (scan (frame-variables frame)
457           (frame-values frame))))
458 
459 (define (remove-binding-from-frame! var frame)
460   (define (scan vars vals)
461     (cond ((null? (cdr vars))
462 	   (error "Binding not found -- REMOVE-BINDING-FROM-FRAME!" var))
463 	  ((eq? var (cadr vars))
464 	   (set-cdr! vars (cddr vars))
465 	   (set-cdr! vals (cddr vals)))
466 	  (else (scan (cdr vars) (cdr vals)))))
467   (let ((vars (frame-variables frame))
468 	(vals (frame-values frame)))
469     (if (eq? var (car vars))
470 	(begin (set-car! frame (cdr vars))
471 	       (set-cdr! frame (cdr vals)))
472 	(scan vars vals))))
473 
474 ;; primitives
475 (define (primitive-procedure? proc)
476   (tagged-list? proc 'primitive))
477 (define (primitive-implementation proc) (cadr proc))
478 (define primitive-procedures
479   (list (list 'car car)
480         (list 'cdr cdr)
481 	(list 'caar caar)
482 	(list 'cadr cadr)
483 	(list 'cddr cddr)
484         (list 'cons cons)
485         (list 'null? null?)
486 	(list '* *)
487 	(list '/ /)
488 	(list '+ +)
489 	(list '- -)
490 	(list '= =)
491 	(list '< <)
492 	(list '> >)
493 	(list '<= <=)
494 	(list '>= >=)
495 	(list 'remainder remainder)
496 	(list 'eq? eq?)
497 	(list 'equal? equal?)
498 	(list 'display display)))
499 (define (primitive-procedure-names)
500   (map car
501        primitive-procedures))
502 (define (primitive-procedure-objects)
503   (map (lambda (proc) (list 'primitive (cadr proc)))
504        primitive-procedures))
505 (define (apply-primitive-procedure proc args)
506   (apply-in-underlying-scheme
507    (primitive-implementation proc) args))
508 
509 ;; driver-loop
510 (define input-prompt ";;; M-Eval input:")
511 (define output-prompt ";;; M-Eval value:")
512 (define (driver-loop)
513   (prompt-for-input input-prompt)
514   (let ((input (read)))
515     (let ((output (actual-value input the-global-environment)))
516       (announce-output output-prompt)
517       (user-print output)))
518   (driver-loop))
519 (define (prompt-for-input string)
520   (newline) (newline) (display string) (newline))
521 
522 (define (announce-output string)
523   (newline) (display string) (newline))
524 (define (user-print object)
525   (if (compound-procedure? object)
526       (display (list 'compound-procedure
527                      (procedure-parameters object)
528                      (procedure-body object)
529                      '<procedure-env>))
530       (display object)))
531 (define (setup-environment)
532   (let ((initial-env
533          (extend-environment (primitive-procedure-names)
534                              (primitive-procedure-objects)
535                              the-empty-environment)))
536     (define-variable! 'true true initial-env)
537     (define-variable! 'false false initial-env)
538     initial-env))
539 (define the-global-environment (setup-environment))
540 
541 ;; auxiliary
542 (define (test-case actual expected)
543   (newline)
544   (display "Actual:   ")
545   (display actual)
546   (newline)
547   (display "Expected: ")
548   (display expected)
549   (newline))
550 (define (geval exp) ;; eval globally
551   (eval exp the-global-environment))
552 (define (test-eval exp expected)
553   (test-case (force-it (geval exp)) expected))
554 
555 ;; Exercise 4.29.  Exhibit a program that you would expect to run much more slowly without memoization than with memoization. Also, consider the following interaction, where the id procedure is defined as in exercise 4.27 and count starts at 0:
556 
557 (geval '(define count 0))
558 (geval '(define (id x)
559 	  (set! count (+ count 1))
560 	  x))
561 (geval 
562  '(define (square x)
563     (* x x)))
564 (test-eval 
565  '(square (id 10))
566  100)
567 (test-eval 'count 1)
568 ;; would be 2 without memoization
569 
570 ;; Give the responses both when the evaluator memoizes and when it does not. 
571 
572 
573 
574 ;; test-suite
575 
576 ;; procedure definitions
577 
578 (geval 
579  '(define (assoc key records)
580     (cond ((null? records) false)
581 	  ((equal? key (caar records)) (car records))
582 	  (else (assoc key (cdr records))))))
583 
584 (geval
585  '(define (map proc list)
586     (if (null? list)
587 	'()
588 	(cons (proc (car list))
589 	      (map proc (cdr list))))))
590 
591 (geval 
592  '(define (accumulate op initial sequence)
593     (if (null? sequence)
594 	initial
595 	(op (car sequence)
596 	    (accumulate op initial (cdr sequence))))))
597 
598 ;; all special forms
599 (test-eval '(begin 5 6) 6)
600 (test-eval '10 10)
601 (geval '(define x 3))
602 (test-eval 'x 3)
603 (test-eval '(set! x -25) 'ok)
604 (test-eval 'x -25)
605 (geval '(define z (lambda (x y) (+ x (* x y)))))
606 (test-eval '(z 3 4) 15)
607 (test-eval '(cond ((= x -2) 'x=-2)
608 		  ((= x -25) 'x=-25)
609 		  (else 'failed))
610 	   'x=-25)
611 (test-eval '(if true false true) false)
612 
613 (test-eval 
614  '(let ((x 4) (y 7))
615     (+ x y (* x y)))
616  (+ 4 7 (* 4 7)))
617 
618 
619 ;; and/or
620 (geval '(define x (+ 3 8)))
621 (test-eval '(and 0 true x) 11)
622 (test-eval '(and 0 true x false) false)
623 (test-eval '(and 0 true x (set! x -2) false) false)
624 (test-eval 'x -2)
625 (test-eval '(and 0 true x false (set! x -5)) false)
626 (test-eval 'x -2)
627 (test-eval '(or false (set! x 25)) 'ok)
628 (test-eval 'x 25)
629 (test-eval '(or (set! x 2) (set! x 4)) 'ok)
630 (test-eval 'x 2)
631 (test-eval '(or false (set! x 25) true false) 'ok)
632 (test-eval 'x 25)
633 (test-eval '(or ((lambda (x) x) 5)) 5)
634 (test-eval '(or (begin (set! x (+ x 1)) x)) 26)
635 
636 
637 ;; cond
638 
639 (test-eval 
640  '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
641 	(else false))
642  2)
643 
644 (test-eval
645  '(cond ((= 3 4) 'not-true)
646 	((= (* 2 4) 3) 'also-false)
647 	((map (lambda (x)
648 		(* x (+ x 1)))
649 	      '(2 4 1 9))
650 	 =>
651 	 (lambda (x)
652 	   (accumulate + 0 x)))
653 	(else 'never-reach))
654  118)
655 ;; '(6 20 2 90)
656 
657 
658 ;; procedure definition and application
659 (geval
660  '(define (factorial n)
661     (if (= n 0)
662 	1
663 	(* n (factorial (- n 1))))))
664 (test-eval '(factorial 5) 120)
665 
666 ;; map
667 
668 (test-eval
669  '(map (lambda (x)
670 	 (* x (+ x 1)))
671        '(2 1 4 2 8 3))
672  '(6 2 20 6 72 12))
673 ;; accumulate
674 
675 (test-eval
676  '(accumulate + 0 '(1 2 3 4 5))
677  15)
678 
679 ;; make-let
680 (test-eval 
681  (make-let '(x y) '(3 5) '((+ x y)))
682  8)
683 (test-eval 
684  '(let ()
685     5)
686  5)
687 (test-eval
688  '(let ((x 3))
689     x)
690  3)
691 (test-eval
692  '(let ((x 3)
693 	(y 5))
694     (+ x y))
695  8)
696 (test-eval 
697  '(let ((x 3)
698 	(y 2))
699     (+ (let ((x (+ y 2))
700 	     (y x))
701 	 (* x y))
702        x y))
703  (+ (* 4 3) 3 2))
704 (test-eval
705  '(let ((x 6)
706 	(y (let ((x 2))
707 	     (+ x 3)))
708 	(z (let ((a (* 3 2)))
709 	     (+ a 3))))
710     (+ x y z))
711  (+ 6 5 9))
712     
713 
714 ;; let*
715 
716 (test-eval
717  '(let* ((x 3)
718 	 (y (+ x 2))
719 	 (z (+ x y 5)))
720     (* x z))
721  39)
722 
723 (test-eval
724  '(let* ()
725     5)
726  5)
727 (test-eval
728  '(let* ((x 3))
729     (let* ((y 5))
730       (+ x y)))
731  8)
732 
733 (test-eval 
734  '(let* ((x 3)
735 	 (y (+ x 1)))
736     (+ (let* ((x (+ y 2))
737 	      (y x))
738 	 (* x y))
739        x y))
740  (+ (* 6 6) 3 4))
741 (test-eval
742  '(let* ((x 6)
743 	 (y (let* ((x 2)
744 		   (a (let* ((x (* 3 x)))
745 			(+ x 2))))       
746 	      (+ x a)))                  
747 	 (z (+ x y)))                    
748     (+ x y z))
749  32)
750 
751 ;; named-let
752 
753 (test-eval
754  '(let eight ()
755     5
756     7
757     8)
758  8)
759 (test-eval
760  '(let loop ((count 0))
761     (if (= 100 count)
762 	count
763 	(loop (+ count 1))))
764  100)
765 (geval
766  '(define (prime? x)
767     (let prime-iter ((i 2))
768       (cond ((> (* i i) x) true)
769 	    ((= (remainder x i) 0) false)
770 	    (else (prime-iter (+ i 1)))))))
771 (test-eval
772  '(let primes ((x 2)
773 	       (n 20))
774     (cond ((= n 0) '())
775 	  ((prime? x) 
776 	   (cons x
777 		 (primes (+ x 1) (- n 1))))
778 	  (else (primes (+ x 1) n))))
779  '(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71))
780 
781 (geval
782  '(define (fib n)
783     (let fib-iter ((a 1)
784 		   (b 0)
785 		   (count n))
786       (if (= count 0)
787 	  b
788 	  (fib-iter (+ a b) a (- count 1))))))
789 (test-eval '(fib 19) 4181)
790 
791 ;; do-loop	  
792 (test-eval
793  '(let ((y 0))
794     (do ((x 0 (+ x 1)))
795 	((= x 5) y)
796       (set! y (+ y 1))))
797  5)
798 (test-eval
799  '(do ()
800       (true))
801  true)
802 (test-eval
803  '(do ()
804       (true 5))
805  5)
806 (test-eval
807  '(let ((y 0))
808     (do ()
809 	((= y 5) y)
810       (set! y (+ y 1))))
811  5)
812 
813 (test-eval
814  '(do ((y '(1 2 3 4)))
815       ((null? y))
816     (set! y (cdr y)))
817  true)
818 (test-eval
819  '(let ((y 0))
820     (do ((x 0 (+ x 1)))
821 	((= x 5) y)
822       (set! y (+ y 1))))
823  5)
824 (test-eval
825  '(let ((x '(1 3 5 7 9)))
826     (do ((x x (cdr x))
827 	 (sum 0 (+ sum (car x))))
828 	((null? x) sum)))
829  25)
830 (test-eval 
831  '(let ((z '()))
832     (do ((x '(1 2 3 4) (cdr x))
833 	 (y '(1 2 3 4 5 6 7 8) (cddr y)))
834 	((null? x) y x z)
835       (set! z (cons (car x) z))))
836  '(4 3 2 1))
837 
838 
839 
840 ;; make-unbound!
841 ;; broken now due to scan-out-defines
842 
843 ;; (test-eval
844 ;;  '(let ((x 3))
845 ;;     (let ((x 5))
846 ;;       (make-unbound! x)
847 ;;       (* x x)))
848 ;;  9)
849 
850 ;; (test-eval
851 ;;  '(let ((x 3))
852 ;;     (let ((x 5))
853 ;;       (define y x)
854 ;;       (make-unbound! x)
855 ;;       (* y x)))
856 ;;  15)
857 
858 ;; (test-eval
859 ;;  '(let ((y -1) (x 3))
860 ;;     (let ((y 0.5) (x 5))
861 ;;       (define a x)
862 ;;       (define b y)
863 ;;       (make-unbound! x)
864 ;;       (make-unbound! y)
865 ;;       (* a b x y)))
866 ;;  (* 5 3 -1 0.5))
867 
868 ;; (test-eval
869 ;;  '(let ((x 3) (y 4))
870 ;;     (let ((x 5))
871 ;;       (make-unbound! x)
872 ;;       (+ x 4)))
873 ;;  7)
874 
875 ;; (test-eval 
876 ;;  '(let ((a 1) (b 2) (c 3) (d 4))
877 ;;     (make-unbound! b)
878 ;;     (+ a c d))
879 ;;  (+ 1 3 4))
880 
881 ;; (test-eval
882 ;;  '(let ((x 4) (y 5))
883 ;;     (let ((a 1) (b 2) (c 3))
884 ;;       (let ((x (+ a b)) (y (+ c a)))
885 ;; 	(make-unbound! x)
886 ;; 	(let ((a x) (b (+ x y)))
887 ;; 	  (define z b)
888 ;; 	  (make-unbound! b)
889 ;; 	  (* (+ a z)
890 ;; 	     (+ a b y))))))
891 ;;  (* (+ 4 8)
892 ;;     (+ 4 2 4)))
893  
894 ;; x 3 -- y 4
895 ;; x 4 -- y 4
896 ;; a 4 -- b 4
897 ;; a 4 -- b 2
898 
899 ;; scan-out-defines
900 
901 (geval
902  '(define (f x)
903     (define (even? n)
904       (if (= n 0)
905 	  true
906 	  (odd? (- n 1))))
907     (define (odd? n)
908       (if (= n 0)
909 	  false
910 	  (even? (- n 1))))
911     (even? x)))
912 (test-eval '(f 5) false)
913 (test-eval '(f 10) true)
914 
915 ;; (geval
916 ;;  '(let ((x 5))
917 ;;     (define y x)
918 ;;     (define x 3)
919 ;;     (+ x y)))
920 ;; signal an error because x is undefined if variables are scanned out
921 
922 ;; letrec
923 
924 (geval
925  '(define (f x)
926     (letrec ((even?
927 	      (lambda (n)
928 		(if (= n 0)
929 		    true
930 		    (odd? (- n 1)))))
931 	     (odd?
932 	      (lambda (n)
933 		(if (= n 0)
934 		    false
935 		    (even? (- n 1))))))
936       (even? x))))
937 (test-eval '(f 11) false)
938 (test-eval '(f 16) true)
939 
940 (test-eval 
941  '(letrec ((fact
942 	    (lambda (n)
943 	      (if (= n 1)
944 		  1
945 		  (* n (fact (- n 1)))))))
946     (fact 10))
947  3628800)
948 
949 
950 ;; delayed-evaluation
951 
952 (geval
953  '(define (try a b)
954     (if (= a 0) 1 b)))
955 (test-eval '(try 0 (/ 1 0)) 1)
956 
957 (geval 
958  '(define (unless condition usual-value exceptional-value)
959     (if condition exceptional-value usual-value)))
960 (test-eval
961  '(let ((a 4) (b 0))
962     (unless (= b 0)
963             (/ a b)
964 	    (begin (display "exception: returning 0")
965 		   0)))
966  0)
967 (test-eval
968   '(let ((a 4) (b 2))
969     (unless (= b 0)
970             (/ a b)
971 	    (begin (display "exception: returning 0")
972 		   0)))
973   2)
974 
975 (geval
976  '(define (factorial n)
977     (unless (= n 1)
978             (* n (factorial (- n 1)))
979 	    1)))
980 (test-eval
981  '(factorial 8)
982  40320)
983 
984 (geval '(define count 0))
985 (geval '(define (id x)
986 	  (set! count (+ count 1))
987 	  x))
988 
989 (geval '(define w (id (id 10))))
990 (test-eval 'count 1)
991 (test-eval 'w 10)
992 (test-eval 'count 2)
993 (test-eval
994  '(let ((f (lambda (x) (+ x 1))))
995     (f 1))
996  2)