1 ;; (define apply-in-underlying-scheme apply)
2 
3 (define (eval exp env)
4   ((analyze exp) env))
5 (define (analyze exp)
6   (cond ((self-evaluating? exp) 
7          (analyze-self-evaluating exp))
8         ((quoted? exp) (analyze-quoted exp))
9         ((variable? exp) (analyze-variable exp))
10         ((assignment? exp) (analyze-assignment exp))
11         ((definition? exp) (analyze-definition exp))
12         ((if? exp) (analyze-if exp))
13         ((lambda? exp) (analyze-lambda exp))
14 	((let? exp) (analyze (let->combination exp)))
15         ((begin? exp) (analyze-sequence (begin-actions exp)))
16         ((cond? exp) (analyze (cond->if exp)))
17         ((application? exp) (analyze-application exp))
18         (else
19          (error "Unknown expression type -- ANALYZE" exp))))
20 (define (analyze-self-evaluating exp)
21   (lambda (env) exp))
22 (define (analyze-quoted exp)
23   (let ((qval (text-of-quotation exp)))
24     (lambda (env) qval)))
25 (define (analyze-variable exp)
26   (lambda (env) (lookup-variable-value exp env)))
27 (define (analyze-assignment exp)
28   (let ((var (assignment-variable exp))
29         (vproc (analyze (assignment-value exp))))
30     (lambda (env)
31       (set-variable-value! var (vproc env) env)
32       'ok)))
33 (define (analyze-definition exp)
34   (let ((var (definition-variable exp))
35         (vproc (analyze (definition-value exp))))
36     (lambda (env)
37       (define-variable! var (vproc env) env)
38       'ok)))    
39 (define (analyze-if exp)
40   (let ((pproc (analyze (if-predicate exp)))
41         (cproc (analyze (if-consequent exp)))
42         (aproc (analyze (if-alternative exp))))
43     (lambda (env)
44       (if (true? (pproc env))
45           (cproc env)
46           (aproc env)))))
47 (define (analyze-lambda exp)
48   (let ((vars (lambda-parameters exp))
49         (bproc (analyze-sequence (lambda-body exp))))
50     (lambda (env) (make-procedure vars bproc env))))
51 (define (analyze-sequence exps)
52   (define (sequentially proc1 proc2)
53     (lambda (env) (proc1 env) (proc2 env)))
54   (define (loop first-proc rest-procs)
55     (if (null? rest-procs)
56         first-proc
57         (loop (sequentially first-proc (car rest-procs))
58               (cdr rest-procs))))
59   (let ((procs (map analyze exps)))
60     (if (null? procs)
61         (error "Empty sequence -- ANALYZE"))
62     (loop (car procs) (cdr procs))))
63 (define (analyze-application exp)
64   (let ((fproc (analyze (operator exp)))
65         (aprocs (map analyze (operands exp))))
66     (lambda (env)
67       (execute-application (fproc env)
68                            (map (lambda (aproc) (aproc env))
69                                 aprocs)))))
70 (define (execute-application proc args)
71   (cond ((primitive-procedure? proc)
72          (apply-primitive-procedure proc args))
73         ((compound-procedure? proc)
74          ((procedure-body proc)
75           (extend-environment (procedure-parameters proc)
76                               args
77                               (procedure-environment proc))))
78         (else
79          (error
80           "Unknown procedure type -- EXECUTE-APPLICATION"
81           proc))))
82 
83 
84 ;; (define (eval exp env)
85 ;;   (cond ((self-evaluating? exp) exp)
86 ;;         ((variable? exp) (lookup-variable-value exp env))
87 ;;         ((quoted? exp) (text-of-quotation exp))
88 ;;         ((assignment? exp) (eval-assignment exp env))
89 ;;         ((definition? exp) (eval-definition exp env))
90 ;; ;;	((unbound? exp) (eval-unbound exp env))
91 ;;         ((if? exp) (eval-if exp env))
92 ;; 	((and? exp) (eval-and exp env))
93 ;; 	((or? exp) (eval-or exp env))
94 ;;         ((lambda? exp)
95 ;;          (make-procedure (lambda-parameters exp)
96 ;;                          (lambda-body exp)
97 ;;                          env))
98 ;;         ((begin? exp) 
99 ;;          (eval-sequence (begin-actions exp) env))
100 ;;         ((cond? exp) (eval (cond->if exp) env))
101 ;; 	((let? exp) (eval (let->combination exp) env))
102 ;; 	((let*? exp) (eval (let*->nested-lets exp) env))
103 ;; 	((named-let? exp) (eval (named-let->combination exp) env))
104 ;; 	((letrec? exp) (eval (letrec->let exp) env))
105 ;; 	((do? exp) (eval (do->combination exp) env))
106 ;;         ((application? exp)
107 ;;          (apply (eval (operator exp) env)
108 ;;                 (list-of-values (operands exp) env)))
109 ;;         (else
110 ;;          (error "Unknown expression type -- EVAL" exp))))
111 ;; (define (apply procedure arguments)
112 ;;   (cond ((primitive-procedure? procedure)
113 ;;          (apply-primitive-procedure procedure arguments))
114 ;;         ((compound-procedure? procedure)
115 ;;          (eval-sequence
116 ;;            (procedure-body procedure)
117 ;;            (extend-environment
118 ;;              (procedure-parameters procedure)
119 ;;              arguments
120 ;;              (procedure-environment procedure))))
121 ;;         (else
122 ;;          (error
123 ;;           "Unknown procedure type -- APPLY" procedure))))
124 
125 (define (list-of-values exps env)
126   (if (no-operands? exps)
127       '()
128       (cons (eval (first-operand exps) env)
129             (list-of-values (rest-operands exps) env))))
130 
131 (define (tagged-list? exp tag)
132   (if (pair? exp)
133       (eq? (car exp) tag)
134       false))
135 
136 ;; self-evaluating/variable/quoted
137 (define (self-evaluating? exp)
138   (cond ((number? exp) true)
139         ((string? exp) true)
140         (else false)))
141 (define (variable? exp) (symbol? exp))
142 (define (quoted? exp)
143   (tagged-list? exp 'quote))
144 (define (text-of-quotation exp) (cadr exp))
145 
146 ;; assignment/definition
147 (define (assignment? exp)
148   (tagged-list? exp 'set!))
149 (define (assignment-variable exp) (cadr exp))
150 (define (assignment-value exp) (caddr exp))
151 (define (make-assignment var val)
152   (list 'set! var val))
153 (define (definition? exp)
154   (tagged-list? exp 'define))
155 (define (definition-variable exp)
156   (if (symbol? (cadr exp))
157       (cadr exp)
158       (caadr exp)))
159 (define (definition-value exp)
160   (if (symbol? (cadr exp))
161       (caddr exp)
162       (make-lambda (cdadr exp)   ; formal parameters
163                    (cddr exp)))) ; body
164 (define (eval-assignment exp env)
165   (set-variable-value! (assignment-variable exp)
166                        (eval (assignment-value exp) env)
167                        env)
168   'ok)
169 (define (eval-definition exp env)
170   (define-variable! (definition-variable exp)
171                     (eval (definition-value exp) env)
172                     env)
173   'ok)
174 (define (make-definition var val)
175   `(define ,var ,val))
176 
177 ;; make-unbound!
178 
179 ;; (define (unbound? exp)
180 ;;   (tagged-list? exp 'make-unbound!))
181 ;; (define (unbound-var exp)
182 ;;   (cadr exp))
183 ;; (define (eval-unbound exp env)
184 ;;   (remove-binding-from-frame! (unbound-var exp) (first-frame env)))
185 
186 
187 
188 ;; if/and/or
189 (define (if? exp) (tagged-list? exp 'if))
190 (define (if-predicate exp) (cadr exp))
191 (define (if-consequent exp) (caddr exp))
192 (define (if-alternative exp)
193   (if (not (null? (cdddr exp)))
194       (cadddr exp)
195       'false))
196 (define (make-if predicate consequent alternative)
197   (list 'if predicate consequent alternative))
198 (define (eval-if exp env)
199   (if (true? (eval (if-predicate exp) env))
200       (eval (if-consequent exp) env)
201       (eval (if-alternative exp) env)))
202 
203 (define (and? exp)
204   (tagged-list? exp 'and))
205 (define (and-clauses exp)
206   (cdr exp))
207 (define (or? exp)
208   (tagged-list? exp 'or))
209 (define (or-clauses exp)
210   (cdr exp))
211 (define (eval-and exp env)
212   (define (eval-clauses clauses)
213     (cond ((null? clauses) true)
214 	  ((null? (cdr clauses)) (eval (car clauses) env))
215 	  (else (and (eval (car clauses) env)
216 		     (eval-clauses (cdr clauses))))))
217   (eval-clauses (and-clauses exp)))
218 (define (eval-or exp env)
219   (define (eval-clauses clauses)
220     (if (null? clauses)
221 	false
222 	(or (eval (car clauses) env)
223 	    (eval-clauses (cdr clauses)))))
224   (eval-clauses (or-clauses exp)))
225 
226 
227 ;; lambda/let/let*/letrec
228 (define (lambda? exp) (tagged-list? exp 'lambda))
229 (define (lambda-parameters exp) (cadr exp))
230 (define (lambda-body exp) (cddr exp))
231 (define (make-lambda parameters body)
232   (cons 'lambda (cons parameters body)))
233 
234 (define (make-let vars vals body)
235   (cons 'let
236 	(cons (map list vars vals)
237 	      body)))
238 (define (let? exp)
239   (and (tagged-list? exp 'let)
240        (not (symbol? (cadr exp)))))
241 (define (let-vars exp)
242   (map car (cadr exp)))
243 (define (let-vals exp)
244   (map cadr (cadr exp)))
245 (define (let-body exp)
246   (cddr exp))
247 (define (let->combination exp)
248   (make-application (make-lambda (let-vars exp) (let-body exp))
249 		    (let-vals exp)))
250 (define (named-let? exp)
251   (and (tagged-list? exp 'let)
252        (symbol? (cadr exp))))
253 (define (named-let-name exp)
254   (cadr exp))
255 (define (named-let-vars exp)
256   (map car (caddr exp)))
257 (define (named-let-vals exp)
258   (map cadr (caddr exp)))
259 (define (named-let-body exp)
260   (cdddr exp))
261 (define (named-let->combination exp)
262   (sequence->exp
263    (list (make-definition (named-let-name exp)
264 			  (make-lambda (named-let-vars exp)
265 				       (named-let-body exp)))
266 	 (make-application (named-let-name exp)
267 			   (named-let-vals exp)))))
268 (define (make-named-let name vars vals body)
269   (cons 'let 
270 	(cons name
271 	      (cons (map list vars vals)
272 		    body))))
273 
274 (define (letrec? exp)
275   (tagged-list? exp 'letrec))
276 
277 (define (letrec-vars exp)
278   (map car (cadr exp)))
279 (define (letrec-vals exp)
280   (map cadr (cadr exp)))
281 (define (letrec-body exp)
282   (cddr exp))
283 (define (letrec->let exp)
284   (let* ((vars (letrec-vars exp))
285 	 (unassigneds (map (lambda (var) ''*unassigned*)
286 			   vars))
287 	 (vals (letrec-vals exp))
288 	 (assignments (map (lambda (var val)
289 			     (make-assignment var val))
290 			   vars
291 			   vals))
292 	 (body (letrec-body exp)))
293   (make-let vars 
294 	    unassigneds
295 	    (append assignments body))))
296 
297 
298 
299 
300 (define (make-application op args)
301   (cons op args))
302 
303 (define (let*? exp)
304   (tagged-list? exp 'let*))
305 (define let*-vars let-vars)
306 (define let*-vals let-vals)
307 (define let*-body let-body)
308 (define (let*->nested-lets exp)
309   (define (expand-lets vars vals)
310     (if (null? (cdr vars))
311 	(make-let (list (car vars)) 
312 		  (list (car vals))
313 		  (let*-body exp))
314 	(make-let (list (car vars))
315 		  (list (car vals))
316 		  (list (expand-lets (cdr vars) (cdr vals))))))
317   (let ((vars (let*-vars exp))
318 	(vals (let*-vals exp)))
319     (if (null? vars)
320 	(sequence->exp (let*-body exp))
321 	(expand-lets vars vals))))
322 
323 ;; do loop
324 (define (do? exp)
325   (tagged-list? exp 'do))
326 (define (do-vars exp)
327   (map car (cadr exp)))
328 (define (do-inits exp)
329   (map cadr (cadr exp)))
330 (define (do-steps exp)
331   (map (lambda (var-init-step)
332 	 (if (null? (cddr var-init-step))
333 	     (car var-init-step)
334 	     (caddr var-init-step)))
335        (cadr exp)))
336 (define (do-test exp)
337   (caaddr exp))
338 (define (do-expressions exp)
339   (if (null? (cdaddr exp))
340       (caddr exp)
341       (cdaddr exp)))
342 (define (do-commands exp)
343   (cdddr exp))
344 (define (do->combination exp)
345   (make-named-let
346    'do-iter
347    (do-vars exp)
348    (do-inits exp)
349    (list
350     (make-if
351      (do-test exp)
352      (sequence->exp (do-expressions exp))
353      (sequence->exp
354       (append (do-commands exp)
355 	      (list (make-application
356 		     'do-iter
357 		     (do-steps exp)))))))))
358 
359 
360 ;; begin/sequence
361 (define (begin? exp) (tagged-list? exp 'begin))
362 (define (begin-actions exp) (cdr exp))
363 (define (last-exp? seq) (null? (cdr seq)))
364 (define (first-exp seq) (car seq))
365 (define (rest-exps seq) (cdr seq))
366 (define (sequence->exp seq)
367   (cond ((null? seq) seq)
368         ((last-exp? seq) (first-exp seq))
369         (else (make-begin seq))))
370 (define (make-begin seq) (cons 'begin seq))
371 (define (eval-sequence exps env)
372   (cond ((last-exp? exps) (eval (first-exp exps) env))
373         (else (eval (first-exp exps) env)
374               (eval-sequence (rest-exps exps) env))))
375 
376 ;; application
377 (define (application? exp) (pair? exp))
378 (define (operator exp) (car exp))
379 (define (operands exp) (cdr exp))
380 (define (no-operands? ops) (null? ops))
381 (define (first-operand ops) (car ops))
382 (define (rest-operands ops) (cdr ops))
383 
384 ;; cond
385 (define (cond? exp) (tagged-list? exp 'cond))
386 (define (cond-clauses exp) (cdr exp))
387 (define (cond-else-clause? clause)
388   (eq? (cond-predicate clause) 'else))
389 (define (cond-predicate clause) (car clause))
390 (define (cond-actions clause) (cdr clause))
391 (define (cond-extended-clause? clause)
392   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
393 (define (cond-extended-proc clause)
394   (caddr clause))
395 (define (cond->if exp)
396   (expand-clauses (cond-clauses exp)))
397 (define (expand-clauses clauses)
398   (if (null? clauses)
399       'false                          ; no else clause
400       (let ((first (car clauses))
401             (rest (cdr clauses)))
402         (if (cond-else-clause? first)
403             (if (null? rest)
404                 (sequence->exp (cond-actions first))
405                 (error "ELSE clause isn't last -- COND->IF"
406                        clauses))
407 	    (if (cond-extended-clause? first)
408 		(make-if (cond-predicate first)
409 			 (make-application
410 			  (cond-extended-proc first)
411 			  (list (cond-predicate first)))
412 			 (expand-clauses rest))
413 		(make-if (cond-predicate first)
414 			 (sequence->exp (cond-actions first))
415 			 (expand-clauses rest)))))))
416 (define (true? x)
417   (not (eq? x false)))
418 (define (false? x)
419   (eq? x false))
420 
421 ;; procedure
422 (define (make-procedure parameters body env)
423   (list 'procedure parameters body env))
424 ;; (define (scan-out-defines body)
425 ;;   (let* ((definitions (filter definition? body))
426 ;; 	 (vars (map definition-variable definitions))
427 ;; 	 (unassigneds (map (lambda (var) ''*unassigned*) 
428 ;; 			   vars))
429 ;; 	 (vals (map definition-value definitions))
430 ;; 	 (assignments 
431 ;; 	  (map (lambda (var val)
432 ;; 		 (make-assignment var val))
433 ;; 	       vars vals))
434 ;; 	 (exps (remove definition? body)))
435 ;;     (if (null? definitions)
436 ;; 	body
437 ;; 	(list
438 ;; 	 (make-let vars
439 ;; 		   unassigneds
440 ;; 		   (append assignments exps))))))
441 (define (compound-procedure? p)
442   (tagged-list? p 'procedure))
443 (define (procedure-parameters p) (cadr p))
444 (define (procedure-body p) (caddr p))
445 (define (procedure-environment p) (cadddr p))
446 
447 ;; environment
448 (define (enclosing-environment env) (cdr env))
449 (define (first-frame env) (car env))
450 (define the-empty-environment '())
451 (define (make-frame variables values)
452   (cons variables values))
453 (define (frame-variables frame) (car frame))
454 (define (frame-values frame) (cdr frame))
455 (define (add-binding-to-frame! var val frame)
456   (set-car! frame (cons var (car frame)))
457   (set-cdr! frame (cons val (cdr frame))))
458 (define (extend-environment vars vals base-env)
459   (if (= (length vars) (length vals))
460       (cons (make-frame vars vals) base-env)
461       (if (< (length vars) (length vals))
462           (error "Too many arguments supplied" vars vals)
463           (error "Too few arguments supplied" vars vals))))
464 (define (lookup-variable-value var env)
465   (define (env-loop env)
466     (define (scan vars vals)
467       (cond ((null? vars)
468              (env-loop (enclosing-environment env)))
469             ((eq? var (car vars))
470 	     (let ((val (car vals)))
471 	       (if (eq? val '*unassigned*)
472 		   (error "Var not yet defined -- LOOKUP-VARIABLE-VALUE" var)
473 		   val)))
474             (else (scan (cdr vars) (cdr vals)))))
475     (if (eq? env the-empty-environment)
476         (error "Unbound variable" var)
477         (let ((frame (first-frame env)))
478           (scan (frame-variables frame)
479                 (frame-values frame)))))
480   (env-loop env))
481 (define (set-variable-value! var val env)
482   (define (env-loop env)
483     (define (scan vars vals)
484       (cond ((null? vars)
485              (env-loop (enclosing-environment env)))
486             ((eq? var (car vars))
487              (set-car! vals val))
488             (else (scan (cdr vars) (cdr vals)))))
489     (if (eq? env the-empty-environment)
490         (error "Unbound variable -- SET!" var)
491         (let ((frame (first-frame env)))
492           (scan (frame-variables frame)
493                 (frame-values frame)))))
494   (env-loop env))
495 (define (define-variable! var val env)
496   (let ((frame (first-frame env)))
497     (define (scan vars vals)
498       (cond ((null? vars)
499              (add-binding-to-frame! var val frame))
500             ((eq? var (car vars))
501              (set-car! vals val))
502             (else (scan (cdr vars) (cdr vals)))))
503     (scan (frame-variables frame)
504           (frame-values frame))))
505 
506 (define (remove-binding-from-frame! var frame)
507   (define (scan vars vals)
508     (cond ((null? (cdr vars))
509 	   (error "Binding not found -- REMOVE-BINDING-FROM-FRAME!" var))
510 	  ((eq? var (cadr vars))
511 	   (set-cdr! vars (cddr vars))
512 	   (set-cdr! vals (cddr vals)))
513 	  (else (scan (cdr vars) (cdr vals)))))
514   (let ((vars (frame-variables frame))
515 	(vals (frame-values frame)))
516     (if (eq? var (car vars))
517 	(begin (set-car! frame (cdr vars))
518 	       (set-cdr! frame (cdr vals)))
519 	(scan vars vals))))
520 
521 ;; primitives
522 (define (primitive-procedure? proc)
523   (tagged-list? proc 'primitive))
524 (define (primitive-implementation proc) (cadr proc))
525 (define primitive-procedures
526   (list (list 'car car)
527         (list 'cdr cdr)
528 	(list 'caar caar)
529 	(list 'cadr cadr)
530 	(list 'cddr cddr)
531         (list 'cons cons)
532         (list 'null? null?)
533 	(list '* *)
534 	(list '/ /)
535 	(list '+ +)
536 	(list '- -)
537 	(list '= =)
538 	(list '< <)
539 	(list '> >)
540 	(list '<= <=)
541 	(list '>= >=)
542 	(list 'remainder remainder)
543 	(list 'eq? eq?)
544 	(list 'equal? equal?)
545 	(list 'display display)))
546 (define (primitive-procedure-names)
547   (map car
548        primitive-procedures))
549 (define (primitive-procedure-objects)
550   (map (lambda (proc) (list 'primitive (cadr proc)))
551        primitive-procedures))
552 (define (apply-primitive-procedure proc args)
553   (apply-in-underlying-scheme
554    (primitive-implementation proc) args))
555 
556 ;; driver-loop
557 (define input-prompt ";;; M-Eval input:")
558 (define output-prompt ";;; M-Eval value:")
559 (define (driver-loop)
560   (prompt-for-input input-prompt)
561   (let ((input (read)))
562     (let ((output (eval input the-global-environment)))
563       (announce-output output-prompt)
564       (user-print output)))
565   (driver-loop))
566 (define (prompt-for-input string)
567   (newline) (newline) (display string) (newline))
568 
569 (define (announce-output string)
570   (newline) (display string) (newline))
571 (define (user-print object)
572   (if (compound-procedure? object)
573       (display (list 'compound-procedure
574                      (procedure-parameters object)
575                      (procedure-body object)
576                      '<procedure-env>))
577       (display object)))
578 (define (setup-environment)
579   (let ((initial-env
580          (extend-environment (primitive-procedure-names)
581                              (primitive-procedure-objects)
582                              the-empty-environment)))
583     (define-variable! 'true true initial-env)
584     (define-variable! 'false false initial-env)
585     initial-env))
586 (define the-global-environment (setup-environment))
587 
588 ;; auxiliary
589 (define (test-case actual expected)
590   (newline)
591   (display "Actual:   ")
592   (display actual)
593   (newline)
594   (display "Expected: ")
595   (display expected)
596   (newline))
597 (define (geval exp) ;; eval globally
598   (eval exp the-global-environment))
599 (define (test-eval exp expected)
600   (test-case (geval exp) expected))
601 
602 
603 
604 ;; test-suite
605 
606 ;; procedure definitions
607 
608 (geval 
609  '(define (assoc key records)
610     (cond ((null? records) false)
611 	  ((equal? key (caar records)) (car records))
612 	  (else (assoc key (cdr records))))))
613 
614 (geval
615  '(define (map proc list)
616     (if (null? list)
617 	'()
618 	(cons (proc (car list))
619 	      (map proc (cdr list))))))
620 
621 (geval 
622  '(define (accumulate op initial sequence)
623     (if (null? sequence)
624 	initial
625 	(op (car sequence)
626 	    (accumulate op initial (cdr sequence))))))
627 
628 ;; all special forms
629 (test-eval '(begin 5 6) 6)
630 (test-eval '10 10)
631 (geval '(define x 3))
632 (test-eval 'x 3)
633 (test-eval '(set! x -25) 'ok)
634 (test-eval 'x -25)
635 (geval '(define z (lambda (x y) (+ x (* x y)))))
636 (test-eval '(z 3 4) 15)
637 (test-eval '(cond ((= x -2) 'x=-2)
638 		  ((= x -25) 'x=-25)
639 		  (else 'failed))
640 	   'x=-25)
641 (test-eval '(if true false true) false)
642 
643 (test-eval 
644  '(let ((x 4) (y 7))
645     (+ x y (* x y)))
646  (+ 4 7 (* 4 7)))
647 
648 
649 ;; and/or
650 (geval '(define x (+ 3 8)))
651 (test-eval '(and 0 true x) 11)
652 (test-eval '(and 0 true x false) false)
653 (test-eval '(and 0 true x (set! x -2) false) false)
654 (test-eval 'x -2)
655 (test-eval '(and 0 true x false (set! x -5)) false)
656 (test-eval 'x -2)
657 (test-eval '(or false (set! x 25)) 'ok)
658 (test-eval 'x 25)
659 (test-eval '(or (set! x 2) (set! x 4)) 'ok)
660 (test-eval 'x 2)
661 (test-eval '(or false (set! x 25) true false) 'ok)
662 (test-eval 'x 25)
663 (test-eval '(or ((lambda (x) x) 5)) 5)
664 (test-eval '(or (begin (set! x (+ x 1)) x)) 26)
665 
666 
667 ;; cond
668 
669 (test-eval 
670  '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
671 	(else false))
672  2)
673 
674 (test-eval
675  '(cond ((= 3 4) 'not-true)
676 	((= (* 2 4) 3) 'also-false)
677 	((map (lambda (x)
678 		(* x (+ x 1)))
679 	      '(2 4 1 9))
680 	 =>
681 	 (lambda (x)
682 	   (accumulate + 0 x)))
683 	(else 'never-reach))
684  118)
685 ;; '(6 20 2 90)
686 
687 
688 ;; procedure definition and application
689 (geval
690  '(define (factorial n)
691     (if (= n 0)
692 	1
693 	(* n (factorial (- n 1))))))
694 (test-eval '(factorial 5) 120)
695 
696 ;; map
697 
698 (test-eval
699  '(map (lambda (x)
700 	 (* x (+ x 1)))
701        '(2 1 4 2 8 3))
702  '(6 2 20 6 72 12))
703 ;; accumulate
704 
705 (test-eval
706  '(accumulate + 0 '(1 2 3 4 5))
707  15)
708 
709 ;; make-let
710 (test-eval 
711  (make-let '(x y) '(3 5) '((+ x y)))
712  8)
713 (test-eval 
714  '(let ()
715     5)
716  5)
717 (test-eval
718  '(let ((x 3))
719     x)
720  3)
721 (test-eval
722  '(let ((x 3)
723 	(y 5))
724     (+ x y))
725  8)
726 (test-eval 
727  '(let ((x 3)
728 	(y 2))
729     (+ (let ((x (+ y 2))
730 	     (y x))
731 	 (* x y))
732        x y))
733  (+ (* 4 3) 3 2))
734 (test-eval
735  '(let ((x 6)
736 	(y (let ((x 2))
737 	     (+ x 3)))
738 	(z (let ((a (* 3 2)))
739 	     (+ a 3))))
740     (+ x y z))
741  (+ 6 5 9))
742     
743 
744 ;; let*
745 
746 (test-eval
747  '(let* ((x 3)
748 	 (y (+ x 2))
749 	 (z (+ x y 5)))
750     (* x z))
751  39)
752 
753 (test-eval
754  '(let* ()
755     5)
756  5)
757 (test-eval
758  '(let* ((x 3))
759     (let* ((y 5))
760       (+ x y)))
761  8)
762 
763 (test-eval 
764  '(let* ((x 3)
765 	 (y (+ x 1)))
766     (+ (let* ((x (+ y 2))
767 	      (y x))
768 	 (* x y))
769        x y))
770  (+ (* 6 6) 3 4))
771 (test-eval
772  '(let* ((x 6)
773 	 (y (let* ((x 2)
774 		   (a (let* ((x (* 3 x)))
775 			(+ x 2))))       
776 	      (+ x a)))                  
777 	 (z (+ x y)))                    
778     (+ x y z))
779  32)
780 
781 ;; named-let
782 
783 (test-eval
784  '(let eight ()
785     5
786     7
787     8)
788  8)
789 (test-eval
790  '(let loop ((count 0))
791     (if (= 100 count)
792 	count
793 	(loop (+ count 1))))
794  100)
795 (geval
796  '(define (prime? x)
797     (let prime-iter ((i 2))
798       (cond ((> (* i i) x) true)
799 	    ((= (remainder x i) 0) false)
800 	    (else (prime-iter (+ i 1)))))))
801 (test-eval
802  '(let primes ((x 2)
803 	       (n 20))
804     (cond ((= n 0) '())
805 	  ((prime? x) 
806 	   (cons x
807 		 (primes (+ x 1) (- n 1))))
808 	  (else (primes (+ x 1) n))))
809  '(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71))
810 
811 (geval
812  '(define (fib n)
813     (let fib-iter ((a 1)
814 		   (b 0)
815 		   (count n))
816       (if (= count 0)
817 	  b
818 	  (fib-iter (+ a b) a (- count 1))))))
819 (test-eval '(fib 19) 4181)
820 
821 ;; do-loop	  
822 (test-eval
823  '(let ((y 0))
824     (do ((x 0 (+ x 1)))
825 	((= x 5) y)
826       (set! y (+ y 1))))
827  5)
828 (test-eval
829  '(do ()
830       (true))
831  true)
832 (test-eval
833  '(do ()
834       (true 5))
835  5)
836 (test-eval
837  '(let ((y 0))
838     (do ()
839 	((= y 5) y)
840       (set! y (+ y 1))))
841  5)
842 
843 (test-eval
844  '(do ((y '(1 2 3 4)))
845       ((null? y))
846     (set! y (cdr y)))
847  true)
848 (test-eval
849  '(let ((y 0))
850     (do ((x 0 (+ x 1)))
851 	((= x 5) y)
852       (set! y (+ y 1))))
853  5)
854 (test-eval
855  '(let ((x '(1 3 5 7 9)))
856     (do ((x x (cdr x))
857 	 (sum 0 (+ sum (car x))))
858 	((null? x) sum)))
859  25)
860 (test-eval 
861  '(let ((z '()))
862     (do ((x '(1 2 3 4) (cdr x))
863 	 (y '(1 2 3 4 5 6 7 8) (cddr y)))
864 	((null? x) y x z)
865       (set! z (cons (car x) z))))
866  '(4 3 2 1))
867 
868 
869 
870 ;; make-unbound!
871 ;; broken now due to scan-out-defines
872 
873 ;; (test-eval
874 ;;  '(let ((x 3))
875 ;;     (let ((x 5))
876 ;;       (make-unbound! x)
877 ;;       (* x x)))
878 ;;  9)
879 
880 ;; (test-eval
881 ;;  '(let ((x 3))
882 ;;     (let ((x 5))
883 ;;       (define y x)
884 ;;       (make-unbound! x)
885 ;;       (* y x)))
886 ;;  15)
887 
888 ;; (test-eval
889 ;;  '(let ((y -1) (x 3))
890 ;;     (let ((y 0.5) (x 5))
891 ;;       (define a x)
892 ;;       (define b y)
893 ;;       (make-unbound! x)
894 ;;       (make-unbound! y)
895 ;;       (* a b x y)))
896 ;;  (* 5 3 -1 0.5))
897 
898 ;; (test-eval
899 ;;  '(let ((x 3) (y 4))
900 ;;     (let ((x 5))
901 ;;       (make-unbound! x)
902 ;;       (+ x 4)))
903 ;;  7)
904 
905 ;; (test-eval 
906 ;;  '(let ((a 1) (b 2) (c 3) (d 4))
907 ;;     (make-unbound! b)
908 ;;     (+ a c d))
909 ;;  (+ 1 3 4))
910 
911 ;; (test-eval
912 ;;  '(let ((x 4) (y 5))
913 ;;     (let ((a 1) (b 2) (c 3))
914 ;;       (let ((x (+ a b)) (y (+ c a)))
915 ;; 	(make-unbound! x)
916 ;; 	(let ((a x) (b (+ x y)))
917 ;; 	  (define z b)
918 ;; 	  (make-unbound! b)
919 ;; 	  (* (+ a z)
920 ;; 	     (+ a b y))))))
921 ;;  (* (+ 4 8)
922 ;;     (+ 4 2 4)))
923  
924 ;; x 3 -- y 4
925 ;; x 4 -- y 4
926 ;; a 4 -- b 4
927 ;; a 4 -- b 2
928 
929 ;; scan-out-defines
930 
931 (geval
932  '(define (f x)
933     (define (even? n)
934       (if (= n 0)
935 	  true
936 	  (odd? (- n 1))))
937     (define (odd? n)
938       (if (= n 0)
939 	  false
940 	  (even? (- n 1))))
941     (even? x)))
942 (test-eval '(f 5) false)
943 (test-eval '(f 10) true)
944 
945 ;; (geval
946 ;;  '(let ((x 5))
947 ;;     (define y x)
948 ;;     (define x 3)
949 ;;     (+ x y)))
950 ;; signal an error because x is undefined if variables are scanned out
951 
952 ;; letrec
953 
954 (geval
955  '(define (f x)
956     (letrec ((even?
957 	      (lambda (n)
958 		(if (= n 0)
959 		    true
960 		    (odd? (- n 1)))))
961 	     (odd?
962 	      (lambda (n)
963 		(if (= n 0)
964 		    false
965 		    (even? (- n 1))))))
966       (even? x))))
967 (test-eval '(f 11) false)
968 (test-eval '(f 16) true)
969 
970 (test-eval 
971  '(letrec ((fact
972 	    (lambda (n)
973 	      (if (= n 1)
974 		  1
975 		  (* n (fact (- n 1)))))))
976     (fact 10))
977  3628800)