1 ;; (define apply-in-underlying-scheme apply)
2 
3 (define (eval exp env)
4   (cond ((self-evaluating? exp) exp)
5         ((variable? exp) (lookup-variable-value exp env))
6         ((quoted? exp) (text-of-quotation exp))
7         ((assignment? exp) (eval-assignment exp env))
8         ((definition? exp) (eval-definition exp env))
9 ;;	((unbound? exp) (eval-unbound exp env))
10         ((if? exp) (eval-if exp env))
11 	((and? exp) (eval-and exp env))
12 	((or? exp) (eval-or exp env))
13         ((lambda? exp)
14          (make-procedure (lambda-parameters exp)
15                          (lambda-body exp)
16                          env))
17         ((begin? exp) 
18          (eval-sequence (begin-actions exp) env))
19         ((cond? exp) (eval (cond->if exp) env))
20 	((let? exp) (eval (let->combination exp) env))
21 	((let*? exp) (eval (let*->nested-lets exp) env))
22 	((named-let? exp) (eval (named-let->combination exp) env))
23 	((letrec? exp) (eval (letrec->let exp) env))
24 	((do? exp) (eval (do->combination exp) env))
25         ((application? exp)
26          (apply (eval (operator exp) env)
27                 (list-of-values (operands exp) env)))
28         (else
29          (error "Unknown expression type -- EVAL" exp))))
30 (define (apply procedure arguments)
31   (cond ((primitive-procedure? procedure)
32          (apply-primitive-procedure procedure arguments))
33         ((compound-procedure? procedure)
34          (eval-sequence
35            (procedure-body procedure)
36            (extend-environment
37              (procedure-parameters procedure)
38              arguments
39              (procedure-environment procedure))))
40         (else
41          (error
42           "Unknown procedure type -- APPLY" procedure))))
43 
44 (define (list-of-values exps env)
45   (if (no-operands? exps)
46       '()
47       (cons (eval (first-operand exps) env)
48             (list-of-values (rest-operands exps) env))))
49 
50 (define (tagged-list? exp tag)
51   (if (pair? exp)
52       (eq? (car exp) tag)
53       false))
54 
55 ;; self-evaluating/variable/quoted
56 (define (self-evaluating? exp)
57   (cond ((number? exp) true)
58         ((string? exp) true)
59         (else false)))
60 (define (variable? exp) (symbol? exp))
61 (define (quoted? exp)
62   (tagged-list? exp 'quote))
63 (define (text-of-quotation exp) (cadr exp))
64 
65 ;; assignment/definition
66 (define (assignment? exp)
67   (tagged-list? exp 'set!))
68 (define (assignment-variable exp) (cadr exp))
69 (define (assignment-value exp) (caddr exp))
70 (define (make-assignment var val)
71   (list 'set! var val))
72 (define (definition? exp)
73   (tagged-list? exp 'define))
74 (define (definition-variable exp)
75   (if (symbol? (cadr exp))
76       (cadr exp)
77       (caadr exp)))
78 (define (definition-value exp)
79   (if (symbol? (cadr exp))
80       (caddr exp)
81       (make-lambda (cdadr exp)   ; formal parameters
82                    (cddr exp)))) ; body
83 (define (eval-assignment exp env)
84   (set-variable-value! (assignment-variable exp)
85                        (eval (assignment-value exp) env)
86                        env)
87   'ok)
88 (define (eval-definition exp env)
89   (define-variable! (definition-variable exp)
90                     (eval (definition-value exp) env)
91                     env)
92   'ok)
93 (define (make-definition var val)
94   `(define ,var ,val))
95 
96 ;; make-unbound!
97 
98 ;; (define (unbound? exp)
99 ;;   (tagged-list? exp 'make-unbound!))
100 ;; (define (unbound-var exp)
101 ;;   (cadr exp))
102 ;; (define (eval-unbound exp env)
103 ;;   (remove-binding-from-frame! (unbound-var exp) (first-frame env)))
104 
105 
106 
107 ;; if/and/or
108 (define (if? exp) (tagged-list? exp 'if))
109 (define (if-predicate exp) (cadr exp))
110 (define (if-consequent exp) (caddr exp))
111 (define (if-alternative exp)
112   (if (not (null? (cdddr exp)))
113       (cadddr exp)
114       'false))
115 (define (make-if predicate consequent alternative)
116   (list 'if predicate consequent alternative))
117 (define (eval-if exp env)
118   (if (true? (eval (if-predicate exp) env))
119       (eval (if-consequent exp) env)
120       (eval (if-alternative exp) env)))
121 
122 (define (and? exp)
123   (tagged-list? exp 'and))
124 (define (and-clauses exp)
125   (cdr exp))
126 (define (or? exp)
127   (tagged-list? exp 'or))
128 (define (or-clauses exp)
129   (cdr exp))
130 (define (eval-and exp env)
131   (define (eval-clauses clauses)
132     (cond ((null? clauses) true)
133 	  ((null? (cdr clauses)) (eval (car clauses) env))
134 	  (else (and (eval (car clauses) env)
135 		     (eval-clauses (cdr clauses))))))
136   (eval-clauses (and-clauses exp)))
137 (define (eval-or exp env)
138   (define (eval-clauses clauses)
139     (if (null? clauses)
140 	false
141 	(or (eval (car clauses) env)
142 	    (eval-clauses (cdr clauses)))))
143   (eval-clauses (or-clauses exp)))
144 
145 
146 ;; lambda/let/let*/letrec
147 (define (lambda? exp) (tagged-list? exp 'lambda))
148 (define (lambda-parameters exp) (cadr exp))
149 (define (lambda-body exp) (cddr exp))
150 (define (make-lambda parameters body)
151   (cons 'lambda (cons parameters body)))
152 
153 (define (make-let vars vals body)
154   (cons 'let
155 	(cons (map list vars vals)
156 	      body)))
157 (define (let? exp)
158   (and (tagged-list? exp 'let)
159        (not (symbol? (cadr exp)))))
160 (define (let-vars exp)
161   (map car (cadr exp)))
162 (define (let-vals exp)
163   (map cadr (cadr exp)))
164 (define (let-body exp)
165   (cddr exp))
166 (define (let->combination exp)
167   (make-application (make-lambda (let-vars exp) (let-body exp))
168 		    (let-vals exp)))
169 (define (named-let? exp)
170   (and (tagged-list? exp 'let)
171        (symbol? (cadr exp))))
172 (define (named-let-name exp)
173   (cadr exp))
174 (define (named-let-vars exp)
175   (map car (caddr exp)))
176 (define (named-let-vals exp)
177   (map cadr (caddr exp)))
178 (define (named-let-body exp)
179   (cdddr exp))
180 (define (named-let->combination exp)
181   (sequence->exp
182    (list (make-definition (named-let-name exp)
183 			  (make-lambda (named-let-vars exp)
184 				       (named-let-body exp)))
185 	 (make-application (named-let-name exp)
186 			   (named-let-vals exp)))))
187 (define (make-named-let name vars vals body)
188   (cons 'let 
189 	(cons name
190 	      (cons (map list vars vals)
191 		    body))))
192 
193 (define (letrec? exp)
194   (tagged-list? exp 'letrec))
195 
196 (define (letrec-vars exp)
197   (map car (cadr exp)))
198 (define (letrec-vals exp)
199   (map cadr (cadr exp)))
200 (define (letrec-body exp)
201   (cddr exp))
202 (define (letrec->let exp)
203   (let* ((vars (letrec-vars exp))
204 	 (unassigneds (map (lambda (var) ''*unassigned*)
205 			   vars))
206 	 (vals (letrec-vals exp))
207 	 (assignments (map (lambda (var val)
208 			     (make-assignment var val))
209 			   vars
210 			   vals))
211 	 (body (letrec-body exp)))
212   (make-let vars 
213 	    unassigneds
214 	    (append assignments body))))
215 
216 
217 
218 
219 (define (make-application op args)
220   (cons op args))
221 
222 (define (let*? exp)
223   (tagged-list? exp 'let*))
224 (define let*-vars let-vars)
225 (define let*-vals let-vals)
226 (define let*-body let-body)
227 (define (let*->nested-lets exp)
228   (define (expand-lets vars vals)
229     (if (null? (cdr vars))
230 	(make-let (list (car vars)) 
231 		  (list (car vals))
232 		  (let*-body exp))
233 	(make-let (list (car vars))
234 		  (list (car vals))
235 		  (list (expand-lets (cdr vars) (cdr vals))))))
236   (let ((vars (let*-vars exp))
237 	(vals (let*-vals exp)))
238     (if (null? vars)
239 	(sequence->exp (let*-body exp))
240 	(expand-lets vars vals))))
241 
242 ;; do loop
243 (define (do? exp)
244   (tagged-list? exp 'do))
245 (define (do-vars exp)
246   (map car (cadr exp)))
247 (define (do-inits exp)
248   (map cadr (cadr exp)))
249 (define (do-steps exp)
250   (map (lambda (var-init-step)
251 	 (if (null? (cddr var-init-step))
252 	     (car var-init-step)
253 	     (caddr var-init-step)))
254        (cadr exp)))
255 (define (do-test exp)
256   (caaddr exp))
257 (define (do-expressions exp)
258   (if (null? (cdaddr exp))
259       (caddr exp)
260       (cdaddr exp)))
261 (define (do-commands exp)
262   (cdddr exp))
263 (define (do->combination exp)
264   (make-named-let
265    'do-iter
266    (do-vars exp)
267    (do-inits exp)
268    (list
269     (make-if
270      (do-test exp)
271      (sequence->exp (do-expressions exp))
272      (sequence->exp
273       (append (do-commands exp)
274 	      (list (make-application
275 		     'do-iter
276 		     (do-steps exp)))))))))
277 
278 
279 ;; begin/sequence
280 (define (begin? exp) (tagged-list? exp 'begin))
281 (define (begin-actions exp) (cdr exp))
282 (define (last-exp? seq) (null? (cdr seq)))
283 (define (first-exp seq) (car seq))
284 (define (rest-exps seq) (cdr seq))
285 (define (sequence->exp seq)
286   (cond ((null? seq) seq)
287         ((last-exp? seq) (first-exp seq))
288         (else (make-begin seq))))
289 (define (make-begin seq) (cons 'begin seq))
290 (define (eval-sequence exps env)
291   (cond ((last-exp? exps) (eval (first-exp exps) env))
292         (else (eval (first-exp exps) env)
293               (eval-sequence (rest-exps exps) env))))
294 
295 ;; application
296 (define (application? exp) (pair? exp))
297 (define (operator exp) (car exp))
298 (define (operands exp) (cdr exp))
299 (define (no-operands? ops) (null? ops))
300 (define (first-operand ops) (car ops))
301 (define (rest-operands ops) (cdr ops))
302 
303 ;; cond
304 (define (cond? exp) (tagged-list? exp 'cond))
305 (define (cond-clauses exp) (cdr exp))
306 (define (cond-else-clause? clause)
307   (eq? (cond-predicate clause) 'else))
308 (define (cond-predicate clause) (car clause))
309 (define (cond-actions clause) (cdr clause))
310 (define (cond-extended-clause? clause)
311   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
312 (define (cond-extended-proc clause)
313   (caddr clause))
314 (define (cond->if exp)
315   (expand-clauses (cond-clauses exp)))
316 (define (expand-clauses clauses)
317   (if (null? clauses)
318       'false                          ; no else clause
319       (let ((first (car clauses))
320             (rest (cdr clauses)))
321         (if (cond-else-clause? first)
322             (if (null? rest)
323                 (sequence->exp (cond-actions first))
324                 (error "ELSE clause isn't last -- COND->IF"
325                        clauses))
326 	    (if (cond-extended-clause? first)
327 		(make-if (cond-predicate first)
328 			 (make-application
329 			  (cond-extended-proc first)
330 			  (list (cond-predicate first)))
331 			 (expand-clauses rest))
332 		(make-if (cond-predicate first)
333 			 (sequence->exp (cond-actions first))
334 			 (expand-clauses rest)))))))
335 (define (true? x)
336   (not (eq? x false)))
337 (define (false? x)
338   (eq? x false))
339 
340 ;; procedure
341 (define (make-procedure parameters body env)
342   (list 'procedure parameters body env))
343 ;; (define (scan-out-defines body)
344 ;;   (let* ((definitions (filter definition? body))
345 ;; 	 (vars (map definition-variable definitions))
346 ;; 	 (unassigneds (map (lambda (var) ''*unassigned*) 
347 ;; 			   vars))
348 ;; 	 (vals (map definition-value definitions))
349 ;; 	 (assignments 
350 ;; 	  (map (lambda (var val)
351 ;; 		 (make-assignment var val))
352 ;; 	       vars vals))
353 ;; 	 (exps (remove definition? body)))
354 ;;     (if (null? definitions)
355 ;; 	body
356 ;; 	(list
357 ;; 	 (make-let vars
358 ;; 		   unassigneds
359 ;; 		   (append assignments exps))))))
360 (define (compound-procedure? p)
361   (tagged-list? p 'procedure))
362 (define (procedure-parameters p) (cadr p))
363 (define (procedure-body p) (caddr p))
364 (define (procedure-environment p) (cadddr p))
365 
366 ;; environment
367 (define (enclosing-environment env) (cdr env))
368 (define (first-frame env) (car env))
369 (define the-empty-environment '())
370 (define (make-frame variables values)
371   (cons variables values))
372 (define (frame-variables frame) (car frame))
373 (define (frame-values frame) (cdr frame))
374 (define (add-binding-to-frame! var val frame)
375   (set-car! frame (cons var (car frame)))
376   (set-cdr! frame (cons val (cdr frame))))
377 (define (extend-environment vars vals base-env)
378   (if (= (length vars) (length vals))
379       (cons (make-frame vars vals) base-env)
380       (if (< (length vars) (length vals))
381           (error "Too many arguments supplied" vars vals)
382           (error "Too few arguments supplied" vars vals))))
383 (define (lookup-variable-value var env)
384   (define (env-loop env)
385     (define (scan vars vals)
386       (cond ((null? vars)
387              (env-loop (enclosing-environment env)))
388             ((eq? var (car vars))
389 	     (let ((val (car vals)))
390 	       (if (eq? val '*unassigned*)
391 		   (error "Var not yet defined -- LOOKUP-VARIABLE-VALUE" var)
392 		   val)))
393             (else (scan (cdr vars) (cdr vals)))))
394     (if (eq? env the-empty-environment)
395         (error "Unbound variable" var)
396         (let ((frame (first-frame env)))
397           (scan (frame-variables frame)
398                 (frame-values frame)))))
399   (env-loop env))
400 (define (set-variable-value! var val env)
401   (define (env-loop env)
402     (define (scan vars vals)
403       (cond ((null? vars)
404              (env-loop (enclosing-environment env)))
405             ((eq? var (car vars))
406              (set-car! vals val))
407             (else (scan (cdr vars) (cdr vals)))))
408     (if (eq? env the-empty-environment)
409         (error "Unbound variable -- SET!" var)
410         (let ((frame (first-frame env)))
411           (scan (frame-variables frame)
412                 (frame-values frame)))))
413   (env-loop env))
414 (define (define-variable! var val env)
415   (let ((frame (first-frame env)))
416     (define (scan vars vals)
417       (cond ((null? vars)
418              (add-binding-to-frame! var val frame))
419             ((eq? var (car vars))
420              (set-car! vals val))
421             (else (scan (cdr vars) (cdr vals)))))
422     (scan (frame-variables frame)
423           (frame-values frame))))
424 
425 (define (remove-binding-from-frame! var frame)
426   (define (scan vars vals)
427     (cond ((null? (cdr vars))
428 	   (error "Binding not found -- REMOVE-BINDING-FROM-FRAME!" var))
429 	  ((eq? var (cadr vars))
430 	   (set-cdr! vars (cddr vars))
431 	   (set-cdr! vals (cddr vals)))
432 	  (else (scan (cdr vars) (cdr vals)))))
433   (let ((vars (frame-variables frame))
434 	(vals (frame-values frame)))
435     (if (eq? var (car vars))
436 	(begin (set-car! frame (cdr vars))
437 	       (set-cdr! frame (cdr vals)))
438 	(scan vars vals))))
439 
440 ;; primitives
441 (define (primitive-procedure? proc)
442   (tagged-list? proc 'primitive))
443 (define (primitive-implementation proc) (cadr proc))
444 (define primitive-procedures
445   (list (list 'car car)
446         (list 'cdr cdr)
447 	(list 'caar caar)
448 	(list 'cadr cadr)
449 	(list 'cddr cddr)
450         (list 'cons cons)
451         (list 'null? null?)
452 	(list '* *)
453 	(list '/ /)
454 	(list '+ +)
455 	(list '- -)
456 	(list '= =)
457 	(list '< <)
458 	(list '> >)
459 	(list '<= <=)
460 	(list '>= >=)
461 	(list 'remainder remainder)
462 	(list 'eq? eq?)
463 	(list 'equal? equal?)
464 	(list 'display display)))
465 (define (primitive-procedure-names)
466   (map car
467        primitive-procedures))
468 (define (primitive-procedure-objects)
469   (map (lambda (proc) (list 'primitive (cadr proc)))
470        primitive-procedures))
471 (define (apply-primitive-procedure proc args)
472   (apply-in-underlying-scheme
473    (primitive-implementation proc) args))
474 
475 ;; driver-loop
476 (define input-prompt ";;; M-Eval input:")
477 (define output-prompt ";;; M-Eval value:")
478 (define (driver-loop)
479   (prompt-for-input input-prompt)
480   (let ((input (read)))
481     (let ((output (eval input the-global-environment)))
482       (announce-output output-prompt)
483       (user-print output)))
484   (driver-loop))
485 (define (prompt-for-input string)
486   (newline) (newline) (display string) (newline))
487 
488 (define (announce-output string)
489   (newline) (display string) (newline))
490 (define (user-print object)
491   (if (compound-procedure? object)
492       (display (list 'compound-procedure
493                      (procedure-parameters object)
494                      (procedure-body object)
495                      '<procedure-env>))
496       (display object)))
497 (define (setup-environment)
498   (let ((initial-env
499          (extend-environment (primitive-procedure-names)
500                              (primitive-procedure-objects)
501                              the-empty-environment)))
502     (define-variable! 'true true initial-env)
503     (define-variable! 'false false initial-env)
504     initial-env))
505 (define the-global-environment (setup-environment))
506 
507 ;; auxiliary
508 (define (test-case actual expected)
509   (newline)
510   (display "Actual:   ")
511   (display actual)
512   (newline)
513   (display "Expected: ")
514   (display expected)
515   (newline))
516 (define (geval exp) ;; eval globally
517   (eval exp the-global-environment))
518 (define (test-eval exp expected)
519   (test-case (geval exp) expected))
520 
521 
522 
523 ;; test-suite
524 
525 ;; procedure definitions
526 
527 (geval 
528  '(define (assoc key records)
529     (cond ((null? records) false)
530 	  ((equal? key (caar records)) (car records))
531 	  (else (assoc key (cdr records))))))
532 
533 (geval
534  '(define (map proc list)
535     (if (null? list)
536 	'()
537 	(cons (proc (car list))
538 	      (map proc (cdr list))))))
539 
540 (geval 
541  '(define (accumulate op initial sequence)
542     (if (null? sequence)
543 	initial
544 	(op (car sequence)
545 	    (accumulate op initial (cdr sequence))))))
546 
547 ;; all special forms
548 (test-eval '(begin 5 6) 6)
549 (test-eval '10 10)
550 (geval '(define x 3))
551 (test-eval 'x 3)
552 (test-eval '(set! x -25) 'ok)
553 (test-eval 'x -25)
554 (geval '(define z (lambda (x y) (+ x (* x y)))))
555 (test-eval '(z 3 4) 15)
556 (test-eval '(cond ((= x -2) 'x=-2)
557 		  ((= x -25) 'x=-25)
558 		  (else 'failed))
559 	   'x=-25)
560 (test-eval '(if true false true) false)
561 
562 (test-eval 
563  '(let ((x 4) (y 7))
564     (+ x y (* x y)))
565  (+ 4 7 (* 4 7)))
566 
567 
568 ;; and/or
569 (geval '(define x (+ 3 8)))
570 (test-eval '(and 0 true x) 11)
571 (test-eval '(and 0 true x false) false)
572 (test-eval '(and 0 true x (set! x -2) false) false)
573 (test-eval 'x -2)
574 (test-eval '(and 0 true x false (set! x -5)) false)
575 (test-eval 'x -2)
576 (test-eval '(or false (set! x 25)) 'ok)
577 (test-eval 'x 25)
578 (test-eval '(or (set! x 2) (set! x 4)) 'ok)
579 (test-eval 'x 2)
580 (test-eval '(or false (set! x 25) true false) 'ok)
581 (test-eval 'x 25)
582 (test-eval '(or ((lambda (x) x) 5)) 5)
583 (test-eval '(or (begin (set! x (+ x 1)) x)) 26)
584 
585 
586 ;; cond
587 
588 (test-eval 
589  '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
590 	(else false))
591  2)
592 
593 (test-eval
594  '(cond ((= 3 4) 'not-true)
595 	((= (* 2 4) 3) 'also-false)
596 	((map (lambda (x)
597 		(* x (+ x 1)))
598 	      '(2 4 1 9))
599 	 =>
600 	 (lambda (x)
601 	   (accumulate + 0 x)))
602 	(else 'never-reach))
603  118)
604 ;; '(6 20 2 90)
605 
606 
607 ;; procedure definition and application
608 (geval
609  '(define (factorial n)
610     (if (= n 0)
611 	1
612 	(* n (factorial (- n 1))))))
613 (test-eval '(factorial 5) 120)
614 
615 ;; map
616 
617 (test-eval
618  '(map (lambda (x)
619 	 (* x (+ x 1)))
620        '(2 1 4 2 8 3))
621  '(6 2 20 6 72 12))
622 ;; accumulate
623 
624 (test-eval
625  '(accumulate + 0 '(1 2 3 4 5))
626  15)
627 
628 ;; make-let
629 (test-eval 
630  (make-let '(x y) '(3 5) '((+ x y)))
631  8)
632 (test-eval 
633  '(let ()
634     5)
635  5)
636 (test-eval
637  '(let ((x 3))
638     x)
639  3)
640 (test-eval
641  '(let ((x 3)
642 	(y 5))
643     (+ x y))
644  8)
645 (test-eval 
646  '(let ((x 3)
647 	(y 2))
648     (+ (let ((x (+ y 2))
649 	     (y x))
650 	 (* x y))
651        x y))
652  (+ (* 4 3) 3 2))
653 (test-eval
654  '(let ((x 6)
655 	(y (let ((x 2))
656 	     (+ x 3)))
657 	(z (let ((a (* 3 2)))
658 	     (+ a 3))))
659     (+ x y z))
660  (+ 6 5 9))
661     
662 
663 ;; let*
664 
665 (test-eval
666  '(let* ((x 3)
667 	 (y (+ x 2))
668 	 (z (+ x y 5)))
669     (* x z))
670  39)
671 
672 (test-eval
673  '(let* ()
674     5)
675  5)
676 (test-eval
677  '(let* ((x 3))
678     (let* ((y 5))
679       (+ x y)))
680  8)
681 
682 (test-eval 
683  '(let* ((x 3)
684 	 (y (+ x 1)))
685     (+ (let* ((x (+ y 2))
686 	      (y x))
687 	 (* x y))
688        x y))
689  (+ (* 6 6) 3 4))
690 (test-eval
691  '(let* ((x 6)
692 	 (y (let* ((x 2)
693 		   (a (let* ((x (* 3 x)))
694 			(+ x 2))))       
695 	      (+ x a)))                  
696 	 (z (+ x y)))                    
697     (+ x y z))
698  32)
699 
700 ;; named-let
701 
702 (test-eval
703  '(let eight ()
704     5
705     7
706     8)
707  8)
708 (test-eval
709  '(let loop ((count 0))
710     (if (= 100 count)
711 	count
712 	(loop (+ count 1))))
713  100)
714 (geval
715  '(define (prime? x)
716     (let prime-iter ((i 2))
717       (cond ((> (* i i) x) true)
718 	    ((= (remainder x i) 0) false)
719 	    (else (prime-iter (+ i 1)))))))
720 (test-eval
721  '(let primes ((x 2)
722 	       (n 20))
723     (cond ((= n 0) '())
724 	  ((prime? x) 
725 	   (cons x
726 		 (primes (+ x 1) (- n 1))))
727 	  (else (primes (+ x 1) n))))
728  '(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71))
729 
730 (geval
731  '(define (fib n)
732     (let fib-iter ((a 1)
733 		   (b 0)
734 		   (count n))
735       (if (= count 0)
736 	  b
737 	  (fib-iter (+ a b) a (- count 1))))))
738 (test-eval '(fib 19) 4181)
739 
740 ;; do-loop	  
741 (test-eval
742  '(let ((y 0))
743     (do ((x 0 (+ x 1)))
744 	((= x 5) y)
745       (set! y (+ y 1))))
746  5)
747 (test-eval
748  '(do ()
749       (true))
750  true)
751 (test-eval
752  '(do ()
753       (true 5))
754  5)
755 (test-eval
756  '(let ((y 0))
757     (do ()
758 	((= y 5) y)
759       (set! y (+ y 1))))
760  5)
761 
762 (test-eval
763  '(do ((y '(1 2 3 4)))
764       ((null? y))
765     (set! y (cdr y)))
766  true)
767 (test-eval
768  '(let ((y 0))
769     (do ((x 0 (+ x 1)))
770 	((= x 5) y)
771       (set! y (+ y 1))))
772  5)
773 (test-eval
774  '(let ((x '(1 3 5 7 9)))
775     (do ((x x (cdr x))
776 	 (sum 0 (+ sum (car x))))
777 	((null? x) sum)))
778  25)
779 (test-eval 
780  '(let ((z '()))
781     (do ((x '(1 2 3 4) (cdr x))
782 	 (y '(1 2 3 4 5 6 7 8) (cddr y)))
783 	((null? x) y x z)
784       (set! z (cons (car x) z))))
785  '(4 3 2 1))
786 
787 
788 
789 ;; make-unbound!
790 ;; broken now due to scan-out-defines
791 
792 ;; (test-eval
793 ;;  '(let ((x 3))
794 ;;     (let ((x 5))
795 ;;       (make-unbound! x)
796 ;;       (* x x)))
797 ;;  9)
798 
799 ;; (test-eval
800 ;;  '(let ((x 3))
801 ;;     (let ((x 5))
802 ;;       (define y x)
803 ;;       (make-unbound! x)
804 ;;       (* y x)))
805 ;;  15)
806 
807 ;; (test-eval
808 ;;  '(let ((y -1) (x 3))
809 ;;     (let ((y 0.5) (x 5))
810 ;;       (define a x)
811 ;;       (define b y)
812 ;;       (make-unbound! x)
813 ;;       (make-unbound! y)
814 ;;       (* a b x y)))
815 ;;  (* 5 3 -1 0.5))
816 
817 ;; (test-eval
818 ;;  '(let ((x 3) (y 4))
819 ;;     (let ((x 5))
820 ;;       (make-unbound! x)
821 ;;       (+ x 4)))
822 ;;  7)
823 
824 ;; (test-eval 
825 ;;  '(let ((a 1) (b 2) (c 3) (d 4))
826 ;;     (make-unbound! b)
827 ;;     (+ a c d))
828 ;;  (+ 1 3 4))
829 
830 ;; (test-eval
831 ;;  '(let ((x 4) (y 5))
832 ;;     (let ((a 1) (b 2) (c 3))
833 ;;       (let ((x (+ a b)) (y (+ c a)))
834 ;; 	(make-unbound! x)
835 ;; 	(let ((a x) (b (+ x y)))
836 ;; 	  (define z b)
837 ;; 	  (make-unbound! b)
838 ;; 	  (* (+ a z)
839 ;; 	     (+ a b y))))))
840 ;;  (* (+ 4 8)
841 ;;     (+ 4 2 4)))
842  
843 ;; x 3 -- y 4
844 ;; x 4 -- y 4
845 ;; a 4 -- b 4
846 ;; a 4 -- b 2
847 
848 ;; scan-out-defines
849 
850 (geval
851  '(define (f x)
852     (define (even? n)
853       (if (= n 0)
854 	  true
855 	  (odd? (- n 1))))
856     (define (odd? n)
857       (if (= n 0)
858 	  false
859 	  (even? (- n 1))))
860     (even? x)))
861 (test-eval '(f 5) false)
862 (test-eval '(f 10) true)
863 
864 ;; (geval
865 ;;  '(let ((x 5))
866 ;;     (define y x)
867 ;;     (define x 3)
868 ;;     (+ x y)))
869 ;; signal an error because x is undefined if variables are scanned out
870 
871 ;; letrec
872 
873 (geval
874  '(define (f x)
875     (letrec ((even?
876 	      (lambda (n)
877 		(if (= n 0)
878 		    true
879 		    (odd? (- n 1)))))
880 	     (odd?
881 	      (lambda (n)
882 		(if (= n 0)
883 		    false
884 		    (even? (- n 1))))))
885       (even? x))))
886 (test-eval '(f 11) false)
887 (test-eval '(f 16) true)
888 
889 (test-eval 
890  '(letrec ((fact
891 	    (lambda (n)
892 	      (if (= n 1)
893 		  1
894 		  (* n (fact (- n 1)))))))
895     (fact 10))
896  3628800)