1 ;; (define apply-in-underlying-scheme apply)
2 
3 (define (eval exp env)
4   (cond ((self-evaluating? exp) exp)
5         ((variable? exp) (lookup-variable-value exp env))
6         ((quoted? exp) (text-of-quotation exp))
7         ((assignment? exp) (eval-assignment exp env))
8         ((definition? exp) (eval-definition exp env))
9 ;;	((unbound? exp) (eval-unbound exp env))
10         ((if? exp) (eval-if exp env))
11 	((and? exp) (eval-and exp env))
12 	((or? exp) (eval-or exp env))
13         ((lambda? exp)
14          (make-procedure (lambda-parameters exp)
15                          (lambda-body exp)
16                          env))
17         ((begin? exp) 
18          (eval-sequence (begin-actions exp) env))
19         ((cond? exp) (eval (cond->if exp) env))
20 	((let? exp) (eval (let->combination exp) env))
21 	((let*? exp) (eval (let*->nested-lets exp) env))
22 	((named-let? exp) (eval (named-let->combination exp) env))
23 	((do? exp) (eval (do->combination exp) env))
24         ((application? exp)
25          (apply (eval (operator exp) env)
26                 (list-of-values (operands exp) env)))
27         (else
28          (error "Unknown expression type -- EVAL" exp))))
29 (define (apply procedure arguments)
30   (cond ((primitive-procedure? procedure)
31          (apply-primitive-procedure procedure arguments))
32         ((compound-procedure? procedure)
33          (eval-sequence
34            (procedure-body procedure)
35            (extend-environment
36              (procedure-parameters procedure)
37              arguments
38              (procedure-environment procedure))))
39         (else
40          (error
41           "Unknown procedure type -- APPLY" procedure))))
42 
43 (define (list-of-values exps env)
44   (if (no-operands? exps)
45       '()
46       (cons (eval (first-operand exps) env)
47             (list-of-values (rest-operands exps) env))))
48 
49 (define (tagged-list? exp tag)
50   (if (pair? exp)
51       (eq? (car exp) tag)
52       false))
53 
54 ;; self-evaluating/variable/quoted
55 (define (self-evaluating? exp)
56   (cond ((number? exp) true)
57         ((string? exp) true)
58         (else false)))
59 (define (variable? exp) (symbol? exp))
60 (define (quoted? exp)
61   (tagged-list? exp 'quote))
62 (define (text-of-quotation exp) (cadr exp))
63 
64 ;; assignment/definition
65 (define (assignment? exp)
66   (tagged-list? exp 'set!))
67 (define (assignment-variable exp) (cadr exp))
68 (define (assignment-value exp) (caddr exp))
69 (define (definition? exp)
70   (tagged-list? exp 'define))
71 (define (definition-variable exp)
72   (if (symbol? (cadr exp))
73       (cadr exp)
74       (caadr exp)))
75 (define (definition-value exp)
76   (if (symbol? (cadr exp))
77       (caddr exp)
78       (make-lambda (cdadr exp)   ; formal parameters
79                    (cddr exp)))) ; body
80 (define (eval-assignment exp env)
81   (set-variable-value! (assignment-variable exp)
82                        (eval (assignment-value exp) env)
83                        env)
84   'ok)
85 (define (eval-definition exp env)
86   (define-variable! (definition-variable exp)
87                     (eval (definition-value exp) env)
88                     env)
89   'ok)
90 (define (make-definition var val)
91   `(define ,var ,val))
92 
93 ;; make-unbound!
94 
95 ;; (define (unbound? exp)
96 ;;   (tagged-list? exp 'make-unbound!))
97 ;; (define (unbound-var exp)
98 ;;   (cadr exp))
99 ;; (define (eval-unbound exp env)
100 ;;   (remove-binding-from-frame! (unbound-var exp) (first-frame env)))
101 
102 
103 
104 ;; if/and/or
105 (define (if? exp) (tagged-list? exp 'if))
106 (define (if-predicate exp) (cadr exp))
107 (define (if-consequent exp) (caddr exp))
108 (define (if-alternative exp)
109   (if (not (null? (cdddr exp)))
110       (cadddr exp)
111       'false))
112 (define (make-if predicate consequent alternative)
113   (list 'if predicate consequent alternative))
114 (define (eval-if exp env)
115   (if (true? (eval (if-predicate exp) env))
116       (eval (if-consequent exp) env)
117       (eval (if-alternative exp) env)))
118 
119 (define (and? exp)
120   (tagged-list? exp 'and))
121 (define (and-clauses exp)
122   (cdr exp))
123 (define (or? exp)
124   (tagged-list? exp 'or))
125 (define (or-clauses exp)
126   (cdr exp))
127 (define (eval-and exp env)
128   (define (eval-clauses clauses)
129     (cond ((null? clauses) true)
130 	  ((null? (cdr clauses)) (eval (car clauses) env))
131 	  (else (and (eval (car clauses) env)
132 		     (eval-clauses (cdr clauses))))))
133   (eval-clauses (and-clauses exp)))
134 (define (eval-or exp env)
135   (define (eval-clauses clauses)
136     (if (null? clauses)
137 	false
138 	(or (eval (car clauses) env)
139 	    (eval-clauses (cdr clauses)))))
140   (eval-clauses (or-clauses exp)))
141 
142 
143 ;; lambda/let/let*
144 (define (lambda? exp) (tagged-list? exp 'lambda))
145 (define (lambda-parameters exp) (cadr exp))
146 (define (lambda-body exp) (cddr exp))
147 (define (make-lambda parameters body)
148   (cons 'lambda (cons parameters body)))
149 
150 (define (make-let vars vals body)
151   (cons 'let
152 	(cons (map list vars vals)
153 	      body)))
154 (define (let? exp)
155   (and (tagged-list? exp 'let)
156        (not (symbol? (cadr exp)))))
157 (define (let-vars exp)
158   (map car (cadr exp)))
159 (define (let-vals exp)
160   (map cadr (cadr exp)))
161 (define (let-body exp)
162   (cddr exp))
163 (define (let->combination exp)
164   (make-application (make-lambda (let-vars exp) (let-body exp))
165 		    (let-vals exp)))
166 (define (named-let? exp)
167   (and (tagged-list? exp 'let)
168        (symbol? (cadr exp))))
169 (define (named-let-name exp)
170   (cadr exp))
171 (define (named-let-vars exp)
172   (map car (caddr exp)))
173 (define (named-let-vals exp)
174   (map cadr (caddr exp)))
175 (define (named-let-body exp)
176   (cdddr exp))
177 (define (named-let->combination exp)
178   (sequence->exp
179    (list (make-definition (named-let-name exp)
180 			  (make-lambda (named-let-vars exp)
181 				       (named-let-body exp)))
182 	 (make-application (named-let-name exp)
183 			   (named-let-vals exp)))))
184 (define (make-named-let name vars vals body)
185   (cons 'let 
186 	(cons name
187 	      (cons (map list vars vals)
188 		    body))))
189 
190 (define (make-application op args)
191   (cons op args))
192 
193 (define (let*? exp)
194   (tagged-list? exp 'let*))
195 (define let*-vars let-vars)
196 (define let*-vals let-vals)
197 (define let*-body let-body)
198 (define (let*->nested-lets exp)
199   (define (expand-lets vars vals)
200     (if (null? (cdr vars))
201 	(make-let (list (car vars)) 
202 		  (list (car vals))
203 		  (let*-body exp))
204 	(make-let (list (car vars))
205 		  (list (car vals))
206 		  (list (expand-lets (cdr vars) (cdr vals))))))
207   (let ((vars (let*-vars exp))
208 	(vals (let*-vals exp)))
209     (if (null? vars)
210 	(sequence->exp (let*-body exp))
211 	(expand-lets vars vals))))
212 
213 ;; do loop
214 (define (do? exp)
215   (tagged-list? exp 'do))
216 (define (do-vars exp)
217   (map car (cadr exp)))
218 (define (do-inits exp)
219   (map cadr (cadr exp)))
220 (define (do-steps exp)
221   (map (lambda (var-init-step)
222 	 (if (null? (cddr var-init-step))
223 	     (car var-init-step)
224 	     (caddr var-init-step)))
225        (cadr exp)))
226 (define (do-test exp)
227   (caaddr exp))
228 (define (do-expressions exp)
229   (if (null? (cdaddr exp))
230       (caddr exp)
231       (cdaddr exp)))
232 (define (do-commands exp)
233   (cdddr exp))
234 (define (do->combination exp)
235   (make-named-let
236    'do-iter
237    (do-vars exp)
238    (do-inits exp)
239    (list
240     (make-if
241      (do-test exp)
242      (sequence->exp (do-expressions exp))
243      (sequence->exp
244       (append (do-commands exp)
245 	      (list (make-application
246 		     'do-iter
247 		     (do-steps exp)))))))))
248 
249 
250 ;; begin/sequence
251 (define (begin? exp) (tagged-list? exp 'begin))
252 (define (begin-actions exp) (cdr exp))
253 (define (last-exp? seq) (null? (cdr seq)))
254 (define (first-exp seq) (car seq))
255 (define (rest-exps seq) (cdr seq))
256 (define (sequence->exp seq)
257   (cond ((null? seq) seq)
258         ((last-exp? seq) (first-exp seq))
259         (else (make-begin seq))))
260 (define (make-begin seq) (cons 'begin seq))
261 (define (eval-sequence exps env)
262   (cond ((last-exp? exps) (eval (first-exp exps) env))
263         (else (eval (first-exp exps) env)
264               (eval-sequence (rest-exps exps) env))))
265 
266 ;; application
267 (define (application? exp) (pair? exp))
268 (define (operator exp) (car exp))
269 (define (operands exp) (cdr exp))
270 (define (no-operands? ops) (null? ops))
271 (define (first-operand ops) (car ops))
272 (define (rest-operands ops) (cdr ops))
273 
274 ;; cond
275 (define (cond? exp) (tagged-list? exp 'cond))
276 (define (cond-clauses exp) (cdr exp))
277 (define (cond-else-clause? clause)
278   (eq? (cond-predicate clause) 'else))
279 (define (cond-predicate clause) (car clause))
280 (define (cond-actions clause) (cdr clause))
281 (define (cond-extended-clause? clause)
282   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
283 (define (cond-extended-proc clause)
284   (caddr clause))
285 (define (cond->if exp)
286   (expand-clauses (cond-clauses exp)))
287 (define (expand-clauses clauses)
288   (if (null? clauses)
289       'false                          ; no else clause
290       (let ((first (car clauses))
291             (rest (cdr clauses)))
292         (if (cond-else-clause? first)
293             (if (null? rest)
294                 (sequence->exp (cond-actions first))
295                 (error "ELSE clause isn't last -- COND->IF"
296                        clauses))
297 	    (if (cond-extended-clause? first)
298 		(make-if (cond-predicate first)
299 			 (make-application
300 			  (cond-extended-proc first)
301 			  (list (cond-predicate first)))
302 			 (expand-clauses rest))
303 		(make-if (cond-predicate first)
304 			 (sequence->exp (cond-actions first))
305 			 (expand-clauses rest)))))))
306 (define (true? x)
307   (not (eq? x false)))
308 (define (false? x)
309   (eq? x false))
310 
311 ;; procedure
312 (define (make-procedure parameters body env)
313   (list 'procedure parameters (scan-out-defines body) env))
314 (define (compound-procedure? p)
315   (tagged-list? p 'procedure))
316 (define (procedure-parameters p) (cadr p))
317 (define (procedure-body p) (caddr p))
318 (define (procedure-environment p) (cadddr p))
319 
320 ;; environment
321 (define (enclosing-environment env) (cdr env))
322 (define (first-frame env) (car env))
323 (define the-empty-environment '())
324 (define (make-frame variables values)
325   (cons variables values))
326 (define (frame-variables frame) (car frame))
327 (define (frame-values frame) (cdr frame))
328 (define (add-binding-to-frame! var val frame)
329   (set-car! frame (cons var (car frame)))
330   (set-cdr! frame (cons val (cdr frame))))
331 (define (extend-environment vars vals base-env)
332   (if (= (length vars) (length vals))
333       (cons (make-frame vars vals) base-env)
334       (if (< (length vars) (length vals))
335           (error "Too many arguments supplied" vars vals)
336           (error "Too few arguments supplied" vars vals))))
337 (define (lookup-variable-value var env)
338   (define (env-loop env)
339     (define (scan vars vals)
340       (cond ((null? vars)
341              (env-loop (enclosing-environment env)))
342             ((eq? var (car vars))
343 	     (let ((val (car vals)))
344 	       (if (eq? val '*unassigned*)
345 		   (error "Var not yet defined -- LOOKUP-VARIABLE-VALUE" var)
346 		   val)))
347             (else (scan (cdr vars) (cdr vals)))))
348     (if (eq? env the-empty-environment)
349         (error "Unbound variable" var)
350         (let ((frame (first-frame env)))
351           (scan (frame-variables frame)
352                 (frame-values frame)))))
353   (env-loop env))
354 (define (set-variable-value! var val env)
355   (define (env-loop env)
356     (define (scan vars vals)
357       (cond ((null? vars)
358              (env-loop (enclosing-environment env)))
359             ((eq? var (car vars))
360              (set-car! vals val))
361             (else (scan (cdr vars) (cdr vals)))))
362     (if (eq? env the-empty-environment)
363         (error "Unbound variable -- SET!" var)
364         (let ((frame (first-frame env)))
365           (scan (frame-variables frame)
366                 (frame-values frame)))))
367   (env-loop env))
368 (define (define-variable! var val env)
369   (let ((frame (first-frame env)))
370     (define (scan vars vals)
371       (cond ((null? vars)
372              (add-binding-to-frame! var val frame))
373             ((eq? var (car vars))
374              (set-car! vals val))
375             (else (scan (cdr vars) (cdr vals)))))
376     (scan (frame-variables frame)
377           (frame-values frame))))
378 
379 (define (remove-binding-from-frame! var frame)
380   (define (scan vars vals)
381     (cond ((null? (cdr vars))
382 	   (error "Binding not found -- REMOVE-BINDING-FROM-FRAME!" var))
383 	  ((eq? var (cadr vars))
384 	   (set-cdr! vars (cddr vars))
385 	   (set-cdr! vals (cddr vals)))
386 	  (else (scan (cdr vars) (cdr vals)))))
387   (let ((vars (frame-variables frame))
388 	(vals (frame-values frame)))
389     (if (eq? var (car vars))
390 	(begin (set-car! frame (cdr vars))
391 	       (set-cdr! frame (cdr vals)))
392 	(scan vars vals))))
393 
394 ;; primitives
395 (define (primitive-procedure? proc)
396   (tagged-list? proc 'primitive))
397 (define (primitive-implementation proc) (cadr proc))
398 (define primitive-procedures
399   (list (list 'car car)
400         (list 'cdr cdr)
401 	(list 'caar caar)
402 	(list 'cadr cadr)
403 	(list 'cddr cddr)
404         (list 'cons cons)
405         (list 'null? null?)
406 	(list '* *)
407 	(list '/ /)
408 	(list '+ +)
409 	(list '- -)
410 	(list '= =)
411 	(list '< <)
412 	(list '> >)
413 	(list '<= <=)
414 	(list '>= >=)
415 	(list 'remainder remainder)
416 	(list 'eq? eq?)
417 	(list 'equal? equal?)
418 	(list 'display display)))
419 (define (primitive-procedure-names)
420   (map car
421        primitive-procedures))
422 (define (primitive-procedure-objects)
423   (map (lambda (proc) (list 'primitive (cadr proc)))
424        primitive-procedures))
425 (define (apply-primitive-procedure proc args)
426   (apply-in-underlying-scheme
427    (primitive-implementation proc) args))
428 
429 ;; driver-loop
430 (define input-prompt ";;; M-Eval input:")
431 (define output-prompt ";;; M-Eval value:")
432 (define (driver-loop)
433   (prompt-for-input input-prompt)
434   (let ((input (read)))
435     (let ((output (eval input the-global-environment)))
436       (announce-output output-prompt)
437       (user-print output)))
438   (driver-loop))
439 (define (prompt-for-input string)
440   (newline) (newline) (display string) (newline))
441 
442 (define (announce-output string)
443   (newline) (display string) (newline))
444 (define (user-print object)
445   (if (compound-procedure? object)
446       (display (list 'compound-procedure
447                      (procedure-parameters object)
448                      (procedure-body object)
449                      '<procedure-env>))
450       (display object)))
451 (define (setup-environment)
452   (let ((initial-env
453          (extend-environment (primitive-procedure-names)
454                              (primitive-procedure-objects)
455                              the-empty-environment)))
456     (define-variable! 'true true initial-env)
457     (define-variable! 'false false initial-env)
458     initial-env))
459 (define the-global-environment (setup-environment))
460 
461 ;; auxiliary
462 (define (test-case actual expected)
463   (newline)
464   (display "Actual:   ")
465   (display actual)
466   (newline)
467   (display "Expected: ")
468   (display expected)
469   (newline))
470 (define (geval exp) ;; eval globally
471   (eval exp the-global-environment))
472 (define (test-eval exp expected)
473   (test-case (geval exp) expected))
474 
475 
476 ;;  Exercise 4.16.  In this exercise we implement the method just described for interpreting internal definitions. We assume that the evaluator supports let (see exercise 4.6).
477 
478 ;; a.  Change lookup-variable-value (section 4.1.3) to signal an error if the value it finds is the symbol *unassigned*.
479 
480 ;; see above
481 
482 ;; b.  Write a procedure scan-out-defines that takes a procedure body and returns an equivalent one that has no internal definitions, by making the transformation described above.
483 
484 ;; (lambda <vars>
485 ;;   (define u <e1>)
486 ;;   (define v <e2>)
487 ;;   <e3>)
488 
489 ;; would be transformed into
490 
491 ;; (lambda <vars>
492 ;;   (let ((u '*unassigned*)
493 ;;         (v '*unassigned*))
494 ;;     (set! u <e1>)
495 ;;     (set! v <e2>)
496 ;;     <e3>))
497 
498 ;; (newline)
499 ;; (display "test")
500 ;; (newline)
501 
502 
503 (define (make-assignment var val)
504   (list 'set! var val))
505 
506 (define (scan-out-defines body)
507   (let* ((definitions (filter definition? body))
508 	 (vars (map definition-variable definitions))
509 	 (unassigneds (map (lambda (var) ''*unassigned*) 
510 			   vars))
511 	 (vals (map definition-value definitions))
512 	 (assignments 
513 	  (map (lambda (var val)
514 		 (make-assignment var val))
515 	       vars vals))
516 	 (exps (remove definition? body)))
517     (if (null? definitions)
518 	body
519 	(list
520 	 (make-let vars
521 		   unassigneds
522 		   (append assignments exps))))))
523 
524 ;; ((let ((even? (quote *unassigned*))
525 ;;        (odd? (quote *unassigned*)))
526 ;;    (set! even?
527 ;; 	 (lambda (n) 
528 
529 ;; 	   (if (= n 0) 
530 ;; 	       true
531 ;; 	       (odd? (- n 1)))))
532 ;;    (set! odd? 
533 ;; 	 (lambda (n)
534 ;; 	   (if (= n 0)
535 ;; 	       false
536 ;; 	       (even? (- n 1)))))
537 ;;    (even? x)))
538 
539 
540 
541 
542 ;; c.  Install scan-out-defines in the interpreter, either in make-procedure or in procedure-body (see section 4.1.3). Which place is better? Why? 
543 
544 ;; better to put it in make-procedure. Otherwise, every time the procedure-body is requested for an application, we'd have to repeat the scanning. This would make applications quite slow and would be very inefficient.
545 
546 ;; N.B.: make-unbound! is now broken because the defines are scanned out. The problem is that if there are internal defines, the frames of the defines have been moved around.
547 
548 ;; scan-out-defines
549 
550 (geval
551  '(define (f x)
552     (define (even? n)
553       (if (= n 0)
554 	  true
555 	  (odd? (- n 1))))
556     (define (odd? n)
557       (if (= n 0)
558 	  false
559 	  (even? (- n 1))))
560     (even? x)))
561 (test-eval '(f 5) false)
562 (test-eval '(f 10) true)
563 
564 ;; (geval
565 ;;  '(let ((x 5))
566 ;;     (define y x)
567 ;;     (define x 3)
568 ;;     (+ x y)))
569 ;; signal an error because x is undefined if variables are scanned out
570 
571 
572 
573 
574 ;; test-suite
575 
576 ;; procedure definitions
577 
578 (geval 
579  '(define (assoc key records)
580     (cond ((null? records) false)
581 	  ((equal? key (caar records)) (car records))
582 	  (else (assoc key (cdr records))))))
583 
584 (geval
585  '(define (map proc list)
586     (if (null? list)
587 	'()
588 	(cons (proc (car list))
589 	      (map proc (cdr list))))))
590 
591 (geval 
592  '(define (accumulate op initial sequence)
593     (if (null? sequence)
594 	initial
595 	(op (car sequence)
596 	    (accumulate op initial (cdr sequence))))))
597 
598 ;; all special forms
599 (test-eval '(begin 5 6) 6)
600 (test-eval '10 10)
601 (geval '(define x 3))
602 (test-eval 'x 3)
603 (test-eval '(set! x -25) 'ok)
604 (test-eval 'x -25)
605 (geval '(define z (lambda (x y) (+ x (* x y)))))
606 (test-eval '(z 3 4) 15)
607 (test-eval '(cond ((= x -2) 'x=-2)
608 		  ((= x -25) 'x=-25)
609 		  (else 'failed))
610 	   'x=-25)
611 (test-eval '(if true false true) false)
612 (test-eval 
613  '(let ((x 4) (y 7))
614     (+ x y (* x y)))
615  (+ 4 7 (* 4 7)))
616 
617 
618 ;; and/or
619 (geval '(define x (+ 3 8)))
620 (test-eval '(and 0 true x) 11)
621 (test-eval '(and 0 true x false) false)
622 (test-eval '(and 0 true x (set! x -2) false) false)
623 (test-eval 'x -2)
624 (test-eval '(and 0 true x false (set! x -5)) false)
625 (test-eval 'x -2)
626 (test-eval '(or false (set! x 25)) 'ok)
627 (test-eval 'x 25)
628 (test-eval '(or (set! x 2) (set! x 4)) 'ok)
629 (test-eval 'x 2)
630 (test-eval '(or false (set! x 25) true false) 'ok)
631 (test-eval 'x 25)
632 (test-eval '(or ((lambda (x) x) 5)) 5)
633 (test-eval '(or (begin (set! x (+ x 1)) x)) 26)
634 
635 
636 ;; cond
637 
638 (test-eval 
639  '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
640 	(else false))
641  2)
642 
643 (test-eval
644  '(cond ((= 3 4) 'not-true)
645 	((= (* 2 4) 3) 'also-false)
646 	((map (lambda (x)
647 		(* x (+ x 1)))
648 	      '(2 4 1 9))
649 	 =>
650 	 (lambda (x)
651 	   (accumulate + 0 x)))
652 	(else 'never-reach))
653  118)
654 ;; '(6 20 2 90)
655 
656 
657 ;; procedure definition and application
658 (geval
659  '(define (factorial n)
660     (if (= n 0)
661 	1
662 	(* n (factorial (- n 1))))))
663 (test-eval '(factorial 5) 120)
664 
665 ;; map
666 
667 (test-eval
668  '(map (lambda (x)
669 	 (* x (+ x 1)))
670        '(2 1 4 2 8 3))
671  '(6 2 20 6 72 12))
672 ;; accumulate
673 
674 (test-eval
675  '(accumulate + 0 '(1 2 3 4 5))
676  15)
677 
678 ;; make-let
679 (test-eval 
680  (make-let '(x y) '(3 5) '((+ x y)))
681  8)
682 (test-eval 
683  '(let ()
684     5)
685  5)
686 (test-eval
687  '(let ((x 3))
688     x)
689  3)
690 (test-eval
691  '(let ((x 3)
692 	(y 5))
693     (+ x y))
694  8)
695 (test-eval 
696  '(let ((x 3)
697 	(y 2))
698     (+ (let ((x (+ y 2))
699 	     (y x))
700 	 (* x y))
701        x y))
702  (+ (* 4 3) 3 2))
703 (test-eval
704  '(let ((x 6)
705 	(y (let ((x 2))
706 	     (+ x 3)))
707 	(z (let ((a (* 3 2)))
708 	     (+ a 3))))
709     (+ x y z))
710  (+ 6 5 9))
711     
712 
713 ;; let*
714 
715 (test-eval
716  '(let* ((x 3)
717 	 (y (+ x 2))
718 	 (z (+ x y 5)))
719     (* x z))
720  39)
721 
722 (test-eval
723  '(let* ()
724     5)
725  5)
726 (test-eval
727  '(let* ((x 3))
728     (let* ((y 5))
729       (+ x y)))
730  8)
731 
732 (test-eval 
733  '(let* ((x 3)
734 	 (y (+ x 1)))
735     (+ (let* ((x (+ y 2))
736 	      (y x))
737 	 (* x y))
738        x y))
739  (+ (* 6 6) 3 4))
740 (test-eval
741  '(let* ((x 6)
742 	 (y (let* ((x 2)
743 		   (a (let* ((x (* 3 x)))
744 			(+ x 2))))       
745 	      (+ x a)))                  
746 	 (z (+ x y)))                    
747     (+ x y z))
748  32)
749 
750 ;; named-let
751 
752 (test-eval
753  '(let eight ()
754     5
755     7
756     8)
757  8)
758 (test-eval
759  '(let loop ((count 0))
760     (if (= 100 count)
761 	count
762 	(loop (+ count 1))))
763  100)
764 (geval
765  '(define (prime? x)
766     (let prime-iter ((i 2))
767       (cond ((> (* i i) x) true)
768 	    ((= (remainder x i) 0) false)
769 	    (else (prime-iter (+ i 1)))))))
770 (test-eval
771  '(let primes ((x 2)
772 	       (n 20))
773     (cond ((= n 0) '())
774 	  ((prime? x) 
775 	   (cons x
776 		 (primes (+ x 1) (- n 1))))
777 	  (else (primes (+ x 1) n))))
778  '(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71))
779 
780 (geval
781  '(define (fib n)
782     (let fib-iter ((a 1)
783 		   (b 0)
784 		   (count n))
785       (if (= count 0)
786 	  b
787 	  (fib-iter (+ a b) a (- count 1))))))
788 (test-eval '(fib 19) 4181)
789 
790 ;; do-loop	  
791 (test-eval
792  '(let ((y 0))
793     (do ((x 0 (+ x 1)))
794 	((= x 5) y)
795       (set! y (+ y 1))))
796  5)
797 (test-eval
798  '(do ()
799       (true))
800  true)
801 (test-eval
802  '(do ()
803       (true 5))
804  5)
805 (test-eval
806  '(let ((y 0))
807     (do ()
808 	((= y 5) y)
809       (set! y (+ y 1))))
810  5)
811 
812 (test-eval
813  '(do ((y '(1 2 3 4)))
814       ((null? y))
815     (set! y (cdr y)))
816  true)
817 (test-eval
818  '(let ((y 0))
819     (do ((x 0 (+ x 1)))
820 	((= x 5) y)
821       (set! y (+ y 1))))
822  5)
823 (test-eval
824  '(let ((x '(1 3 5 7 9)))
825     (do ((x x (cdr x))
826 	 (sum 0 (+ sum (car x))))
827 	((null? x) sum)))
828  25)
829 (test-eval 
830  '(let ((z '()))
831     (do ((x '(1 2 3 4) (cdr x))
832 	 (y '(1 2 3 4 5 6 7 8) (cddr y)))
833 	((null? x) y x z)
834       (set! z (cons (car x) z))))
835  '(4 3 2 1))
836 
837 
838 
839 ;; make-unbound!
840 ;; broken now due to scan-out-defines
841 
842 ;; (test-eval
843 ;;  '(let ((x 3))
844 ;;     (let ((x 5))
845 ;;       (make-unbound! x)
846 ;;       (* x x)))
847 ;;  9)
848 
849 ;; (test-eval
850 ;;  '(let ((x 3))
851 ;;     (let ((x 5))
852 ;;       (define y x)
853 ;;       (make-unbound! x)
854 ;;       (* y x)))
855 ;;  15)
856 
857 ;; (test-eval
858 ;;  '(let ((y -1) (x 3))
859 ;;     (let ((y 0.5) (x 5))
860 ;;       (define a x)
861 ;;       (define b y)
862 ;;       (make-unbound! x)
863 ;;       (make-unbound! y)
864 ;;       (* a b x y)))
865 ;;  (* 5 3 -1 0.5))
866 
867 ;; (test-eval
868 ;;  '(let ((x 3) (y 4))
869 ;;     (let ((x 5))
870 ;;       (make-unbound! x)
871 ;;       (+ x 4)))
872 ;;  7)
873 
874 ;; (test-eval 
875 ;;  '(let ((a 1) (b 2) (c 3) (d 4))
876 ;;     (make-unbound! b)
877 ;;     (+ a c d))
878 ;;  (+ 1 3 4))
879 
880 ;; (test-eval
881 ;;  '(let ((x 4) (y 5))
882 ;;     (let ((a 1) (b 2) (c 3))
883 ;;       (let ((x (+ a b)) (y (+ c a)))
884 ;; 	(make-unbound! x)
885 ;; 	(let ((a x) (b (+ x y)))
886 ;; 	  (define z b)
887 ;; 	  (make-unbound! b)
888 ;; 	  (* (+ a z)
889 ;; 	     (+ a b y))))))
890 ;;  (* (+ 4 8)
891 ;;     (+ 4 2 4)))
892  
893 ;; x 3 -- y 4
894 ;; x 4 -- y 4
895 ;; a 4 -- b 4
896 ;; a 4 -- b 2