1 ;; (define apply-in-underlying-scheme apply)
2 
3 (define (eval exp env)
4   (cond ((self-evaluating? exp) exp)
5         ((variable? exp) (lookup-variable-value exp env))
6         ((quoted? exp) (text-of-quotation exp))
7         ((assignment? exp) (eval-assignment exp env))
8         ((definition? exp) (eval-definition exp env))
9 	((unbound? exp) (eval-unbound exp env))
10         ((if? exp) (eval-if exp env))
11 	((and? exp) (eval-and exp env))
12 	((or? exp) (eval-or exp env))
13         ((lambda? exp)
14          (make-procedure (lambda-parameters exp)
15                          (lambda-body exp)
16                          env))
17         ((begin? exp) 
18          (eval-sequence (begin-actions exp) env))
19         ((cond? exp) (eval (cond->if exp) env))
20 	((let? exp) (eval (let->combination exp) env))
21 	((let*? exp) (eval (let*->nested-lets exp) env))
22 	((named-let? exp) (eval (named-let->combination exp) env))
23 	((do? exp) (eval (do->combination exp) env))
24         ((application? exp)
25          (apply (eval (operator exp) env)
26                 (list-of-values (operands exp) env)))
27         (else
28          (error "Unknown expression type -- EVAL" exp))))
29 (define (apply procedure arguments)
30   (cond ((primitive-procedure? procedure)
31          (apply-primitive-procedure procedure arguments))
32         ((compound-procedure? procedure)
33          (eval-sequence
34            (procedure-body procedure)
35            (extend-environment
36              (procedure-parameters procedure)
37              arguments
38              (procedure-environment procedure))))
39         (else
40          (error
41           "Unknown procedure type -- APPLY" procedure))))
42 
43 (define (list-of-values exps env)
44   (if (no-operands? exps)
45       '()
46       (cons (eval (first-operand exps) env)
47             (list-of-values (rest-operands exps) env))))
48 
49 (define (tagged-list? exp tag)
50   (if (pair? exp)
51       (eq? (car exp) tag)
52       false))
53 
54 ;; self-evaluating/variable/quoted
55 (define (self-evaluating? exp)
56   (cond ((number? exp) true)
57         ((string? exp) true)
58         (else false)))
59 (define (variable? exp) (symbol? exp))
60 (define (quoted? exp)
61   (tagged-list? exp 'quote))
62 (define (text-of-quotation exp) (cadr exp))
63 
64 ;; assignment/definition
65 (define (assignment? exp)
66   (tagged-list? exp 'set!))
67 (define (assignment-variable exp) (cadr exp))
68 (define (assignment-value exp) (caddr exp))
69 (define (definition? exp)
70   (tagged-list? exp 'define))
71 (define (definition-variable exp)
72   (if (symbol? (cadr exp))
73       (cadr exp)
74       (caadr exp)))
75 (define (definition-value exp)
76   (if (symbol? (cadr exp))
77       (caddr exp)
78       (make-lambda (cdadr exp)   ; formal parameters
79                    (cddr exp)))) ; body
80 (define (eval-assignment exp env)
81   (set-variable-value! (assignment-variable exp)
82                        (eval (assignment-value exp) env)
83                        env)
84   'ok)
85 (define (eval-definition exp env)
86   (define-variable! (definition-variable exp)
87                     (eval (definition-value exp) env)
88                     env)
89   'ok)
90 (define (make-definition var val)
91   `(define ,var ,val))
92 
93 
94 ;; if/and/or
95 (define (if? exp) (tagged-list? exp 'if))
96 (define (if-predicate exp) (cadr exp))
97 (define (if-consequent exp) (caddr exp))
98 (define (if-alternative exp)
99   (if (not (null? (cdddr exp)))
100       (cadddr exp)
101       'false))
102 (define (make-if predicate consequent alternative)
103   (list 'if predicate consequent alternative))
104 (define (eval-if exp env)
105   (if (true? (eval (if-predicate exp) env))
106       (eval (if-consequent exp) env)
107       (eval (if-alternative exp) env)))
108 
109 (define (and? exp)
110   (tagged-list? exp 'and))
111 (define (and-clauses exp)
112   (cdr exp))
113 (define (or? exp)
114   (tagged-list? exp 'or))
115 (define (or-clauses exp)
116   (cdr exp))
117 (define (eval-and exp env)
118   (define (eval-clauses clauses)
119     (cond ((null? clauses) true)
120 	  ((null? (cdr clauses)) (eval (car clauses) env))
121 	  (else (and (eval (car clauses) env)
122 		     (eval-clauses (cdr clauses))))))
123   (eval-clauses (and-clauses exp)))
124 (define (eval-or exp env)
125   (define (eval-clauses clauses)
126     (if (null? clauses)
127 	false
128 	(or (eval (car clauses) env)
129 	    (eval-clauses (cdr clauses)))))
130   (eval-clauses (or-clauses exp)))
131 
132 
133 ;; lambda/let/let*
134 (define (lambda? exp) (tagged-list? exp 'lambda))
135 (define (lambda-parameters exp) (cadr exp))
136 (define (lambda-body exp) (cddr exp))
137 (define (make-lambda parameters body)
138   (cons 'lambda (cons parameters body)))
139 
140 (define (make-let vars vals body)
141   (cons 'let
142 	(cons (map list vars vals)
143 	      body)))
144 (define (let? exp)
145   (and (tagged-list? exp 'let)
146        (not (symbol? (cadr exp)))))
147 (define (let-vars exp)
148   (map car (cadr exp)))
149 (define (let-vals exp)
150   (map cadr (cadr exp)))
151 (define (let-body exp)
152   (cddr exp))
153 (define (let->combination exp)
154   (make-application (make-lambda (let-vars exp) (let-body exp))
155 		    (let-vals exp)))
156 (define (named-let? exp)
157   (and (tagged-list? exp 'let)
158        (symbol? (cadr exp))))
159 (define (named-let-name exp)
160   (cadr exp))
161 (define (named-let-vars exp)
162   (map car (caddr exp)))
163 (define (named-let-vals exp)
164   (map cadr (caddr exp)))
165 (define (named-let-body exp)
166   (cdddr exp))
167 (define (named-let->combination exp)
168   (sequence->exp
169    (list (make-definition (named-let-name exp)
170 			  (make-lambda (named-let-vars exp)
171 				       (named-let-body exp)))
172 	 (make-application (named-let-name exp)
173 			   (named-let-vals exp)))))
174 (define (make-named-let name vars vals body)
175   (cons 'let 
176 	(cons name
177 	      (cons (map list vars vals)
178 		    body))))
179 
180 (define (make-application op args)
181   (cons op args))
182 
183 (define (let*? exp)
184   (tagged-list? exp 'let*))
185 (define let*-vars let-vars)
186 (define let*-vals let-vals)
187 (define let*-body let-body)
188 (define (let*->nested-lets exp)
189   (define (expand-lets vars vals)
190     (if (null? (cdr vars))
191 	(make-let (list (car vars)) 
192 		  (list (car vals))
193 		  (let*-body exp))
194 	(make-let (list (car vars))
195 		  (list (car vals))
196 		  (list (expand-lets (cdr vars) (cdr vals))))))
197   (let ((vars (let*-vars exp))
198 	(vals (let*-vals exp)))
199     (if (null? vars)
200 	(sequence->exp (let*-body exp))
201 	(expand-lets vars vals))))
202 
203 ;; do loop
204 (define (do? exp)
205   (tagged-list? exp 'do))
206 (define (do-vars exp)
207   (map car (cadr exp)))
208 (define (do-inits exp)
209   (map cadr (cadr exp)))
210 (define (do-steps exp)
211   (map (lambda (var-init-step)
212 	 (if (null? (cddr var-init-step))
213 	     (car var-init-step)
214 	     (caddr var-init-step)))
215        (cadr exp)))
216 (define (do-test exp)
217   (caaddr exp))
218 (define (do-expressions exp)
219   (if (null? (cdaddr exp))
220       (caddr exp)
221       (cdaddr exp)))
222 (define (do-commands exp)
223   (cdddr exp))
224 (define (do->combination exp)
225   (make-named-let
226    'do-iter
227    (do-vars exp)
228    (do-inits exp)
229    (list
230     (make-if
231      (do-test exp)
232      (sequence->exp (do-expressions exp))
233      (sequence->exp
234       (append (do-commands exp)
235 	      (list (make-application
236 		     'do-iter
237 		     (do-steps exp)))))))))
238 
239 
240 ;; begin/sequence
241 (define (begin? exp) (tagged-list? exp 'begin))
242 (define (begin-actions exp) (cdr exp))
243 (define (last-exp? seq) (null? (cdr seq)))
244 (define (first-exp seq) (car seq))
245 (define (rest-exps seq) (cdr seq))
246 (define (sequence->exp seq)
247   (cond ((null? seq) seq)
248         ((last-exp? seq) (first-exp seq))
249         (else (make-begin seq))))
250 (define (make-begin seq) (cons 'begin seq))
251 (define (eval-sequence exps env)
252   (cond ((last-exp? exps) (eval (first-exp exps) env))
253         (else (eval (first-exp exps) env)
254               (eval-sequence (rest-exps exps) env))))
255 
256 ;; application
257 (define (application? exp) (pair? exp))
258 (define (operator exp) (car exp))
259 (define (operands exp) (cdr exp))
260 (define (no-operands? ops) (null? ops))
261 (define (first-operand ops) (car ops))
262 (define (rest-operands ops) (cdr ops))
263 
264 ;; cond
265 (define (cond? exp) (tagged-list? exp 'cond))
266 (define (cond-clauses exp) (cdr exp))
267 (define (cond-else-clause? clause)
268   (eq? (cond-predicate clause) 'else))
269 (define (cond-predicate clause) (car clause))
270 (define (cond-actions clause) (cdr clause))
271 (define (cond-extended-clause? clause)
272   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
273 (define (cond-extended-proc clause)
274   (caddr clause))
275 (define (cond->if exp)
276   (expand-clauses (cond-clauses exp)))
277 (define (expand-clauses clauses)
278   (if (null? clauses)
279       'false                          ; no else clause
280       (let ((first (car clauses))
281             (rest (cdr clauses)))
282         (if (cond-else-clause? first)
283             (if (null? rest)
284                 (sequence->exp (cond-actions first))
285                 (error "ELSE clause isn't last -- COND->IF"
286                        clauses))
287 	    (if (cond-extended-clause? first)
288 		(make-if (cond-predicate first)
289 			 (make-application
290 			  (cond-extended-proc first)
291 			  (list (cond-predicate first)))
292 			 (expand-clauses rest))
293 		(make-if (cond-predicate first)
294 			 (sequence->exp (cond-actions first))
295 			 (expand-clauses rest)))))))
296 (define (true? x)
297   (not (eq? x false)))
298 (define (false? x)
299   (eq? x false))
300 
301 ;; procedure
302 (define (make-procedure parameters body env)
303   (list 'procedure parameters body env))
304 (define (compound-procedure? p)
305   (tagged-list? p 'procedure))
306 (define (procedure-parameters p) (cadr p))
307 (define (procedure-body p) (caddr p))
308 (define (procedure-environment p) (cadddr p))
309 
310 ;; environment
311 (define (enclosing-environment env) (cdr env))
312 (define (first-frame env) (car env))
313 (define the-empty-environment '())
314 (define (make-frame variables values)
315   (cons variables values))
316 (define (frame-variables frame) (car frame))
317 (define (frame-values frame) (cdr frame))
318 (define (add-binding-to-frame! var val frame)
319   (set-car! frame (cons var (car frame)))
320   (set-cdr! frame (cons val (cdr frame))))
321 (define (extend-environment vars vals base-env)
322   (if (= (length vars) (length vals))
323       (cons (make-frame vars vals) base-env)
324       (if (< (length vars) (length vals))
325           (error "Too many arguments supplied" vars vals)
326           (error "Too few arguments supplied" vars vals))))
327 (define (lookup-variable-value var env)
328   (define (env-loop env)
329     (define (scan vars vals)
330       (cond ((null? vars)
331              (env-loop (enclosing-environment env)))
332             ((eq? var (car vars))
333              (car vals))
334             (else (scan (cdr vars) (cdr vals)))))
335     (if (eq? env the-empty-environment)
336         (error "Unbound variable" var)
337         (let ((frame (first-frame env)))
338           (scan (frame-variables frame)
339                 (frame-values frame)))))
340   (env-loop env))
341 (define (set-variable-value! var val env)
342   (define (env-loop env)
343     (define (scan vars vals)
344       (cond ((null? vars)
345              (env-loop (enclosing-environment env)))
346             ((eq? var (car vars))
347              (set-car! vals val))
348             (else (scan (cdr vars) (cdr vals)))))
349     (if (eq? env the-empty-environment)
350         (error "Unbound variable -- SET!" var)
351         (let ((frame (first-frame env)))
352           (scan (frame-variables frame)
353                 (frame-values frame)))))
354   (env-loop env))
355 (define (define-variable! var val env)
356   (let ((frame (first-frame env)))
357     (define (scan vars vals)
358       (cond ((null? vars)
359              (add-binding-to-frame! var val frame))
360             ((eq? var (car vars))
361              (set-car! vals val))
362             (else (scan (cdr vars) (cdr vals)))))
363     (scan (frame-variables frame)
364           (frame-values frame))))
365 
366 ;; primitives
367 (define (primitive-procedure? proc)
368   (tagged-list? proc 'primitive))
369 (define (primitive-implementation proc) (cadr proc))
370 (define primitive-procedures
371   (list (list 'car car)
372         (list 'cdr cdr)
373 	(list 'caar caar)
374 	(list 'cadr cadr)
375 	(list 'cddr cddr)
376         (list 'cons cons)
377         (list 'null? null?)
378 	(list '* *)
379 	(list '/ /)
380 	(list '+ +)
381 	(list '- -)
382 	(list '= =)
383 	(list '< <)
384 	(list '> >)
385 	(list '<= <=)
386 	(list '>= >=)
387 	(list 'remainder remainder)
388 	(list 'eq? eq?)
389 	(list 'equal? equal?)
390 	(list 'display display)))
391 (define (primitive-procedure-names)
392   (map car
393        primitive-procedures))
394 (define (primitive-procedure-objects)
395   (map (lambda (proc) (list 'primitive (cadr proc)))
396        primitive-procedures))
397 (define (apply-primitive-procedure proc args)
398   (apply-in-underlying-scheme
399    (primitive-implementation proc) args))
400 
401 ;; driver-loop
402 (define input-prompt ";;; M-Eval input:")
403 (define output-prompt ";;; M-Eval value:")
404 (define (driver-loop)
405   (prompt-for-input input-prompt)
406   (let ((input (read)))
407     (let ((output (eval input the-global-environment)))
408       (announce-output output-prompt)
409       (user-print output)))
410   (driver-loop))
411 (define (prompt-for-input string)
412   (newline) (newline) (display string) (newline))
413 
414 (define (announce-output string)
415   (newline) (display string) (newline))
416 (define (user-print object)
417   (if (compound-procedure? object)
418       (display (list 'compound-procedure
419                      (procedure-parameters object)
420                      (procedure-body object)
421                      '<procedure-env>))
422       (display object)))
423 (define (setup-environment)
424   (let ((initial-env
425          (extend-environment (primitive-procedure-names)
426                              (primitive-procedure-objects)
427                              the-empty-environment)))
428     (define-variable! 'true true initial-env)
429     (define-variable! 'false false initial-env)
430     initial-env))
431 (define the-global-environment (setup-environment))
432 
433 ;; auxiliary
434 (define (test-case actual expected)
435   (newline)
436   (display "Actual:   ")
437   (display actual)
438   (newline)
439   (display "Expected: ")
440   (display expected)
441   (newline))
442 (define (geval exp) ;; eval globally
443   (eval exp the-global-environment))
444 (define (test-eval exp expected)
445   (test-case (geval exp) expected))
446 
447 ;; Exercise 4.13.  Scheme allows us to create new bindings for variables by means of define, but provides no way to get rid of bindings. Implement for the evaluator a special form make-unbound! that removes the binding of a given symbol from the environment in which the make-unbound! expression is evaluated. This problem is not completely specified. For example, should we remove only the binding in the first frame of the environment? Complete the specification and justify any choices you make. 
448 
449 ;; we'll remove the binding only from the first frame of the environment in order to avoid remove bindings from other environments, which could potentially be confusing. For example:
450 
451 ;; (let ((x 3) (y 4))
452 ;;   ((lambda (z)
453 ;;      (make-unbound! x)) 3)
454 ;;   ((lambda ()
455 ;;      (+ x 4))))
456 
457 ;; if we were to remove bindings from other environments, then the first procedure would be able to unbind a variable which the second procedure depends on. It would break an environment extended from an enclosing environment
458 
459 (define (unbound? exp)
460   (tagged-list? exp 'make-unbound!))
461 (define (unbound-var exp)
462   (cadr exp))
463 (define (eval-unbound exp env)
464   (remove-binding-from-frame! (unbound-var exp) (first-frame env)))
465 (define (remove-binding-from-frame! var frame)
466   (define (scan vars vals)
467     (cond ((null? (cdr vars))
468 	   (error "Binding not found -- REMOVE-BINDING-FROM-FRAME!" var))
469 	  ((eq? var (cadr vars))
470 	   (set-cdr! vars (cddr vars))
471 	   (set-cdr! vals (cddr vals)))
472 	  (else (scan (cdr vars) (cdr vals)))))
473   (let ((vars (frame-variables frame))
474 	(vals (frame-values frame)))
475     (if (eq? var (car vars))
476 	(begin (set-car! frame (cdr vars))
477 	       (set-cdr! frame (cdr vals)))
478 	(scan vars vals))))
479 
480 ;; make-unbound!
481 
482 (test-eval
483  '(let ((x 3))
484     (let ((x 5))
485       (make-unbound! x)
486       (* x x)))
487  9)
488 
489 (test-eval
490  '(let ((x 3))
491     (let ((x 5))
492       (define y x)
493       (make-unbound! x)
494       (* y x)))
495  15)
496 
497 (test-eval
498  '(let ((y -1) (x 3))
499     (let ((y 0.5) (x 5))
500       (define a x)
501       (define b y)
502       (make-unbound! x)
503       (make-unbound! y)
504       (* a b x y)))
505  (* 5 3 -1 0.5))
506 
507 (test-eval
508  '(let ((x 3) (y 4))
509     (let ((x 5))
510       (make-unbound! x)
511       (+ x 4)))
512  7)
513 
514 (test-eval 
515  '(let ((a 1) (b 2) (c 3) (d 4))
516     (make-unbound! b)
517     (+ a c d))
518  (+ 1 3 4))
519 
520 (test-eval
521  '(let ((x 4) (y 5))
522     (let ((a 1) (b 2) (c 3))
523       (let ((x (+ a b)) (y (+ c a)))
524 	(make-unbound! x)
525 	(let ((a x) (b (+ x y)))
526 	  (define z b)
527 	  (make-unbound! b)
528 	  (* (+ a z)
529 	     (+ a b y))))))
530  (* (+ 4 8)
531     (+ 4 2 4)))
532  
533 ;; x 3 -- y 4
534 ;; x 4 -- y 4
535 ;; a 4 -- b 4
536 ;; a 4 -- b 2
537 
538 ;; test-suite
539 
540 ;; procedure definitions
541 
542 (geval 
543  '(define (assoc key records)
544     (cond ((null? records) false)
545 	  ((equal? key (caar records)) (car records))
546 	  (else (assoc key (cdr records))))))
547 
548 (geval
549  '(define (map proc list)
550     (if (null? list)
551 	'()
552 	(cons (proc (car list))
553 	      (map proc (cdr list))))))
554 
555 (geval 
556  '(define (accumulate op initial sequence)
557     (if (null? sequence)
558 	initial
559 	(op (car sequence)
560 	    (accumulate op initial (cdr sequence))))))
561 
562 ;; all special forms
563 (test-eval '(begin 5 6) 6)
564 (test-eval '10 10)
565 (geval '(define x 3))
566 (test-eval 'x 3)
567 (test-eval '(set! x -25) 'ok)
568 (test-eval 'x -25)
569 (geval '(define z (lambda (x y) (+ x (* x y)))))
570 (test-eval '(z 3 4) 15)
571 (test-eval '(cond ((= x -2) 'x=-2)
572 		  ((= x -25) 'x=-25)
573 		  (else 'failed))
574 	   'x=-25)
575 (test-eval '(if true false true) false)
576 (test-eval 
577  '(let ((x 4) (y 7))
578     (+ x y (* x y)))
579  (+ 4 7 (* 4 7)))
580 
581 
582 ;; and/or
583 (geval '(define x (+ 3 8)))
584 (test-eval '(and 0 true x) 11)
585 (test-eval '(and 0 true x false) false)
586 (test-eval '(and 0 true x (set! x -2) false) false)
587 (test-eval 'x -2)
588 (test-eval '(and 0 true x false (set! x -5)) false)
589 (test-eval 'x -2)
590 (test-eval '(or false (set! x 25)) 'ok)
591 (test-eval 'x 25)
592 (test-eval '(or (set! x 2) (set! x 4)) 'ok)
593 (test-eval 'x 2)
594 (test-eval '(or false (set! x 25) true false) 'ok)
595 (test-eval 'x 25)
596 (test-eval '(or ((lambda (x) x) 5)) 5)
597 (test-eval '(or (begin (set! x (+ x 1)) x)) 26)
598 
599 
600 ;; cond
601 
602 (test-eval 
603  '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
604 	(else false))
605  2)
606 
607 (test-eval
608  '(cond ((= 3 4) 'not-true)
609 	((= (* 2 4) 3) 'also-false)
610 	((map (lambda (x)
611 		(* x (+ x 1)))
612 	      '(2 4 1 9))
613 	 =>
614 	 (lambda (x)
615 	   (accumulate + 0 x)))
616 	(else 'never-reach))
617  118)
618 ;; '(6 20 2 90)
619 
620 
621 ;; procedure definition and application
622 (geval
623  '(define (factorial n)
624     (if (= n 0)
625 	1
626 	(* n (factorial (- n 1))))))
627 (test-eval '(factorial 5) 120)
628 
629 ;; map
630 
631 (test-eval
632  '(map (lambda (x)
633 	 (* x (+ x 1)))
634        '(2 1 4 2 8 3))
635  '(6 2 20 6 72 12))
636 ;; accumulate
637 
638 (test-eval
639  '(accumulate + 0 '(1 2 3 4 5))
640  15)
641 
642 ;; make-let
643 (test-eval 
644  (make-let '(x y) '(3 5) '((+ x y)))
645  8)
646 (test-eval 
647  '(let ()
648     5)
649  5)
650 (test-eval
651  '(let ((x 3))
652     x)
653  3)
654 (test-eval
655  '(let ((x 3)
656 	(y 5))
657     (+ x y))
658  8)
659 (test-eval 
660  '(let ((x 3)
661 	(y 2))
662     (+ (let ((x (+ y 2))
663 	     (y x))
664 	 (* x y))
665        x y))
666  (+ (* 4 3) 3 2))
667 (test-eval
668  '(let ((x 6)
669 	(y (let ((x 2))
670 	     (+ x 3)))
671 	(z (let ((a (* 3 2)))
672 	     (+ a 3))))
673     (+ x y z))
674  (+ 6 5 9))
675     
676 
677 ;; let*
678 
679 (test-eval
680  '(let* ((x 3)
681 	 (y (+ x 2))
682 	 (z (+ x y 5)))
683     (* x z))
684  39)
685 
686 (test-eval
687  '(let* ()
688     5)
689  5)
690 (test-eval
691  '(let* ((x 3))
692     (let* ((y 5))
693       (+ x y)))
694  8)
695 
696 (test-eval 
697  '(let* ((x 3)
698 	 (y (+ x 1)))
699     (+ (let* ((x (+ y 2))
700 	      (y x))
701 	 (* x y))
702        x y))
703  (+ (* 6 6) 3 4))
704 (test-eval
705  '(let* ((x 6)
706 	 (y (let* ((x 2)
707 		   (a (let* ((x (* 3 x)))
708 			(+ x 2))))       
709 	      (+ x a)))                  
710 	 (z (+ x y)))                    
711     (+ x y z))
712  32)
713 
714 ;; named-let
715 
716 (test-eval
717  '(let eight ()
718     5
719     7
720     8)
721  8)
722 (test-eval
723  '(let loop ((count 0))
724     (if (= 100 count)
725 	count
726 	(loop (+ count 1))))
727  100)
728 (geval
729  '(define (prime? x)
730     (let prime-iter ((i 2))
731       (cond ((> (* i i) x) true)
732 	    ((= (remainder x i) 0) false)
733 	    (else (prime-iter (+ i 1)))))))
734 (test-eval
735  '(let primes ((x 2)
736 	       (n 20))
737     (cond ((= n 0) '())
738 	  ((prime? x) 
739 	   (cons x
740 		 (primes (+ x 1) (- n 1))))
741 	  (else (primes (+ x 1) n))))
742  '(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71))
743 
744 (geval
745  '(define (fib n)
746     (let fib-iter ((a 1)
747 		   (b 0)
748 		   (count n))
749       (if (= count 0)
750 	  b
751 	  (fib-iter (+ a b) a (- count 1))))))
752 (test-eval '(fib 19) 4181)
753 
754 ;; do-loop	  
755 (test-eval
756  '(let ((y 0))
757     (do ((x 0 (+ x 1)))
758 	((= x 5) y)
759       (set! y (+ y 1))))
760  5)
761 (test-eval
762  '(do ()
763       (true))
764  true)
765 (test-eval
766  '(do ()
767       (true 5))
768  5)
769 (test-eval
770  '(let ((y 0))
771     (do ()
772 	((= y 5) y)
773       (set! y (+ y 1))))
774  5)
775 
776 (test-eval
777  '(do ((y '(1 2 3 4)))
778       ((null? y))
779     (set! y (cdr y)))
780  true)
781 (test-eval
782  '(let ((y 0))
783     (do ((x 0 (+ x 1)))
784 	((= x 5) y)
785       (set! y (+ y 1))))
786  5)
787 (test-eval
788  '(let ((x '(1 3 5 7 9)))
789     (do ((x x (cdr x))
790 	 (sum 0 (+ sum (car x))))
791 	((null? x) sum)))
792  25)
793 (test-eval 
794  '(let ((z '()))
795     (do ((x '(1 2 3 4) (cdr x))
796 	 (y '(1 2 3 4 5 6 7 8) (cddr y)))
797 	((null? x) y x z)
798       (set! z (cons (car x) z))))
799  '(4 3 2 1))
800 
801 
802