1 (define apply-in-underlying-scheme apply)
2 
3 (define (eval exp env)
4   (cond ((self-evaluating? exp) exp)
5         ((variable? exp) (lookup-variable-value exp env))
6         ((quoted? exp) (text-of-quotation exp))
7         ((assignment? exp) (eval-assignment exp env))
8         ((definition? exp) (eval-definition exp env))
9         ((if? exp) (eval-if exp env))
10 	((and? exp) (eval-and exp env))
11 	((or? exp) (eval-or exp env))
12         ((lambda? exp)
13          (make-procedure (lambda-parameters exp)
14                          (lambda-body exp)
15                          env))
16         ((begin? exp) 
17          (eval-sequence (begin-actions exp) env))
18         ((cond? exp) (eval (cond->if exp) env))
19 	((let? exp) (eval (let->combination exp) env))
20 	((let*? exp) (eval (let*->nested-lets exp) env))
21 	((named-let? exp) (eval (named-let->combination exp) env))
22 	((do? exp) (eval (do->combination exp) env))
23         ((application? exp)
24          (apply (eval (operator exp) env)
25                 (list-of-values (operands exp) env)))
26         (else
27          (error "Unknown expression type -- EVAL" exp))))
28 (define (apply procedure arguments)
29   (cond ((primitive-procedure? procedure)
30          (apply-primitive-procedure procedure arguments))
31         ((compound-procedure? procedure)
32          (eval-sequence
33            (procedure-body procedure)
34            (extend-environment
35              (procedure-parameters procedure)
36              arguments
37              (procedure-environment procedure))))
38         (else
39          (error
40           "Unknown procedure type -- APPLY" procedure))))
41 
42 (define (list-of-values exps env)
43   (if (no-operands? exps)
44       '()
45       (cons (eval (first-operand exps) env)
46             (list-of-values (rest-operands exps) env))))
47 
48 (define (tagged-list? exp tag)
49   (if (pair? exp)
50       (eq? (car exp) tag)
51       false))
52 
53 ;; self-evaluating/variable/quoted
54 (define (self-evaluating? exp)
55   (cond ((number? exp) true)
56         ((string? exp) true)
57         (else false)))
58 (define (variable? exp) (symbol? exp))
59 (define (quoted? exp)
60   (tagged-list? exp 'quote))
61 (define (text-of-quotation exp) (cadr exp))
62 
63 ;; assignment/definition
64 (define (assignment? exp)
65   (tagged-list? exp 'set!))
66 (define (assignment-variable exp) (cadr exp))
67 (define (assignment-value exp) (caddr exp))
68 (define (definition? exp)
69   (tagged-list? exp 'define))
70 (define (definition-variable exp)
71   (if (symbol? (cadr exp))
72       (cadr exp)
73       (caadr exp)))
74 (define (definition-value exp)
75   (if (symbol? (cadr exp))
76       (caddr exp)
77       (make-lambda (cdadr exp)   ; formal parameters
78                    (cddr exp)))) ; body
79 (define (eval-assignment exp env)
80   (set-variable-value! (assignment-variable exp)
81                        (eval (assignment-value exp) env)
82                        env)
83   'ok)
84 (define (eval-definition exp env)
85   (define-variable! (definition-variable exp)
86                     (eval (definition-value exp) env)
87                     env)
88   'ok)
89 (define (make-definition var val)
90   `(define ,var ,val))
91 
92 
93 ;; if/and/or
94 (define (if? exp) (tagged-list? exp 'if))
95 (define (if-predicate exp) (cadr exp))
96 (define (if-consequent exp) (caddr exp))
97 (define (if-alternative exp)
98   (if (not (null? (cdddr exp)))
99       (cadddr exp)
100       'false))
101 (define (make-if predicate consequent alternative)
102   (list 'if predicate consequent alternative))
103 (define (eval-if exp env)
104   (if (true? (eval (if-predicate exp) env))
105       (eval (if-consequent exp) env)
106       (eval (if-alternative exp) env)))
107 
108 (define (and? exp)
109   (tagged-list? exp 'and))
110 (define (and-clauses exp)
111   (cdr exp))
112 (define (or? exp)
113   (tagged-list? exp 'or))
114 (define (or-clauses exp)
115   (cdr exp))
116 (define (eval-and exp env)
117   (define (eval-clauses clauses)
118     (cond ((null? clauses) true)
119 	  ((null? (cdr clauses)) (eval (car clauses) env))
120 	  (else (and (eval (car clauses) env)
121 		     (eval-clauses (cdr clauses))))))
122   (eval-clauses (and-clauses exp)))
123 (define (eval-or exp env)
124   (define (eval-clauses clauses)
125     (if (null? clauses)
126 	false
127 	(or (eval (car clauses) env)
128 	    (eval-clauses (cdr clauses)))))
129   (eval-clauses (or-clauses exp)))
130 
131 
132 ;; lambda/let/let*
133 (define (lambda? exp) (tagged-list? exp 'lambda))
134 (define (lambda-parameters exp) (cadr exp))
135 (define (lambda-body exp) (cddr exp))
136 (define (make-lambda parameters body)
137   (cons 'lambda (cons parameters body)))
138 
139 (define (make-let vars vals body)
140   (cons 'let
141 	(cons (map list vars vals)
142 	      body)))
143 (define (let? exp)
144   (and (tagged-list? exp 'let)
145        (not (symbol? (cadr exp)))))
146 (define (let-vars exp)
147   (map car (cadr exp)))
148 (define (let-vals exp)
149   (map cadr (cadr exp)))
150 (define (let-body exp)
151   (cddr exp))
152 (define (let->combination exp)
153   (make-application (make-lambda (let-vars exp) (let-body exp))
154 		    (let-vals exp)))
155 (define (named-let? exp)
156   (and (tagged-list? exp 'let)
157        (symbol? (cadr exp))))
158 (define (named-let-name exp)
159   (cadr exp))
160 (define (named-let-vars exp)
161   (map car (caddr exp)))
162 (define (named-let-vals exp)
163   (map cadr (caddr exp)))
164 (define (named-let-body exp)
165   (cdddr exp))
166 (define (named-let->combination exp)
167   (sequence->exp
168    (list (make-definition (named-let-name exp)
169 			  (make-lambda (named-let-vars exp)
170 				       (named-let-body exp)))
171 	 (make-application (named-let-name exp)
172 			   (named-let-vals exp)))))
173 (define (make-named-let name vars vals body)
174   (cons 'let 
175 	(cons name
176 	      (cons (map list vars vals)
177 		    body))))
178 
179 (define (make-application op args)
180   (cons op args))
181 
182 (define (let*? exp)
183   (tagged-list? exp 'let*))
184 (define let*-vars let-vars)
185 (define let*-vals let-vals)
186 (define let*-body let-body)
187 (define (let*->nested-lets exp)
188   (define (expand-lets vars vals)
189     (if (null? (cdr vars))
190 	(make-let (list (car vars)) 
191 		  (list (car vals))
192 		  (let*-body exp))
193 	(make-let (list (car vars))
194 		  (list (car vals))
195 		  (list (expand-lets (cdr vars) (cdr vals))))))
196   (let ((vars (let*-vars exp))
197 	(vals (let*-vals exp)))
198     (if (null? vars)
199 	(sequence->exp (let*-body exp))
200 	(expand-lets vars vals))))
201 
202 ;; do loop
203 (define (do? exp)
204   (tagged-list? exp 'do))
205 (define (do-vars exp)
206   (map car (cadr exp)))
207 (define (do-inits exp)
208   (map cadr (cadr exp)))
209 (define (do-steps exp)
210   (map (lambda (var-init-step)
211 	 (if (null? (cddr var-init-step))
212 	     (car var-init-step)
213 	     (caddr var-init-step)))
214        (cadr exp)))
215 (define (do-test exp)
216   (caaddr exp))
217 (define (do-expressions exp)
218   (if (null? (cdaddr exp))
219       (caddr exp)
220       (cdaddr exp)))
221 (define (do-commands exp)
222   (cdddr exp))
223 (define (do->combination exp)
224   (make-named-let
225    'do-iter
226    (do-vars exp)
227    (do-inits exp)
228    (list
229     (make-if
230      (do-test exp)
231      (sequence->exp (do-expressions exp))
232      (sequence->exp
233       (append (do-commands exp)
234 	      (list (make-application
235 		     'do-iter
236 		     (do-steps exp)))))))))
237 
238 
239 ;; begin/sequence
240 (define (begin? exp) (tagged-list? exp 'begin))
241 (define (begin-actions exp) (cdr exp))
242 (define (last-exp? seq) (null? (cdr seq)))
243 (define (first-exp seq) (car seq))
244 (define (rest-exps seq) (cdr seq))
245 (define (sequence->exp seq)
246   (cond ((null? seq) seq)
247         ((last-exp? seq) (first-exp seq))
248         (else (make-begin seq))))
249 (define (make-begin seq) (cons 'begin seq))
250 (define (eval-sequence exps env)
251   (cond ((last-exp? exps) (eval (first-exp exps) env))
252         (else (eval (first-exp exps) env)
253               (eval-sequence (rest-exps exps) env))))
254 
255 ;; application
256 (define (application? exp) (pair? exp))
257 (define (operator exp) (car exp))
258 (define (operands exp) (cdr exp))
259 (define (no-operands? ops) (null? ops))
260 (define (first-operand ops) (car ops))
261 (define (rest-operands ops) (cdr ops))
262 
263 ;; cond
264 (define (cond? exp) (tagged-list? exp 'cond))
265 (define (cond-clauses exp) (cdr exp))
266 (define (cond-else-clause? clause)
267   (eq? (cond-predicate clause) 'else))
268 (define (cond-predicate clause) (car clause))
269 (define (cond-actions clause) (cdr clause))
270 (define (cond-extended-clause? clause)
271   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
272 (define (cond-extended-proc clause)
273   (caddr clause))
274 (define (cond->if exp)
275   (expand-clauses (cond-clauses exp)))
276 (define (expand-clauses clauses)
277   (if (null? clauses)
278       'false                          ; no else clause
279       (let ((first (car clauses))
280             (rest (cdr clauses)))
281         (if (cond-else-clause? first)
282             (if (null? rest)
283                 (sequence->exp (cond-actions first))
284                 (error "ELSE clause isn't last -- COND->IF"
285                        clauses))
286 	    (if (cond-extended-clause? first)
287 		(make-if (cond-predicate first)
288 			 (make-application
289 			  (cond-extended-proc first)
290 			  (list (cond-predicate first)))
291 			 (expand-clauses rest))
292 		(make-if (cond-predicate first)
293 			 (sequence->exp (cond-actions first))
294 			 (expand-clauses rest)))))))
295 (define (true? x)
296   (not (eq? x false)))
297 (define (false? x)
298   (eq? x false))
299 
300 ;; procedure
301 (define (make-procedure parameters body env)
302   (list 'procedure parameters body env))
303 (define (compound-procedure? p)
304   (tagged-list? p 'procedure))
305 (define (procedure-parameters p) (cadr p))
306 (define (procedure-body p) (caddr p))
307 (define (procedure-environment p) (cadddr p))
308 
309 ;; environment
310 (define (enclosing-environment env) (cdr env))
311 (define (first-frame env) (car env))
312 (define the-empty-environment '())
313 (define (make-frame variables values)
314   (cons variables values))
315 (define (frame-variables frame) (car frame))
316 (define (frame-values frame) (cdr frame))
317 (define (add-binding-to-frame! var val frame)
318   (set-car! frame (cons var (car frame)))
319   (set-cdr! frame (cons val (cdr frame))))
320 (define (extend-environment vars vals base-env)
321   (if (= (length vars) (length vals))
322       (cons (make-frame vars vals) base-env)
323       (if (< (length vars) (length vals))
324           (error "Too many arguments supplied" vars vals)
325           (error "Too few arguments supplied" vars vals))))
326 (define (env-loop var env found unbound)
327   (define (scan vars vals)
328     (cond ((null? vars)
329 	   (env-loop var (enclosing-environment env) found unbound))
330 	  ((eq? var (car vars))
331 	   (found vals))
332 	  (else (scan (cdr vars) (cdr vals)))))
333   (if (eq? env the-empty-environment)
334       (unbound)
335       (let ((frame (first-frame env)))
336 	(scan (frame-variables frame)
337 	      (frame-values frame)))))
338 (define (lookup-variable-value var env)
339   (env-loop var env car (lambda () 
340 			  (error "Unbound variable" var))))
341 (define (set-variable-value! var val env)
342   (env-loop var
343 	    env 
344 	    (lambda (vals)
345 	      (set-car! vals val))
346 	    (lambda ()
347 	      (error "Unbound variable -- SET!" var))))
348 (define (define-variable! var val env)
349   (let ((frame (first-frame env)))
350     (env-loop var
351 	      (list frame)
352 	      (lambda (vals)
353 		(set-car! vals val))
354 	      (lambda ()
355 		(add-binding-to-frame! var val frame)))))
356 ;; primitives
357 (define (primitive-procedure? proc)
358   (tagged-list? proc 'primitive))
359 (define (primitive-implementation proc) (cadr proc))
360 (define primitive-procedures
361   (list (list 'car car)
362         (list 'cdr cdr)
363 	(list 'caar caar)
364 	(list 'cadr cadr)
365 	(list 'cddr cddr)
366         (list 'cons cons)
367         (list 'null? null?)
368 	(list '* *)
369 	(list '/ /)
370 	(list '+ +)
371 	(list '- -)
372 	(list '= =)
373 	(list '< <)
374 	(list '> >)
375 	(list '<= <=)
376 	(list '>= >=)
377 	(list 'remainder remainder)
378 	(list 'eq? eq?)
379 	(list 'equal? equal?)
380 	(list 'display display)))
381 (define (primitive-procedure-names)
382   (map car
383        primitive-procedures))
384 (define (primitive-procedure-objects)
385   (map (lambda (proc) (list 'primitive (cadr proc)))
386        primitive-procedures))
387 (define (apply-primitive-procedure proc args)
388   (apply-in-underlying-scheme
389    (primitive-implementation proc) args))
390 
391 ;; driver-loop
392 (define input-prompt ";;; M-Eval input:")
393 (define output-prompt ";;; M-Eval value:")
394 (define (driver-loop)
395   (prompt-for-input input-prompt)
396   (let ((input (read)))
397     (let ((output (eval input the-global-environment)))
398       (announce-output output-prompt)
399       (user-print output)))
400   (driver-loop))
401 (define (prompt-for-input string)
402   (newline) (newline) (display string) (newline))
403 
404 (define (announce-output string)
405   (newline) (display string) (newline))
406 (define (user-print object)
407   (if (compound-procedure? object)
408       (display (list 'compound-procedure
409                      (procedure-parameters object)
410                      (procedure-body object)
411                      '<procedure-env>))
412       (display object)))
413 (define (setup-environment)
414   (let ((initial-env
415          (extend-environment (primitive-procedure-names)
416                              (primitive-procedure-objects)
417                              the-empty-environment)))
418     (define-variable! 'true true initial-env)
419     (define-variable! 'false false initial-env)
420     initial-env))
421 (define the-global-environment (setup-environment))
422 
423 ;; auxiliary
424 (define (test-case actual expected)
425   (newline)
426   (display "Actual:   ")
427   (display actual)
428   (newline)
429   (display "Expected: ")
430   (display expected)
431   (newline))
432 (define (geval exp) ;; eval globally
433   (eval exp the-global-environment))
434 (define (test-eval exp expected)
435   (test-case (geval exp) expected))
436 
437 ;; Exercise 4.12.  The procedures set-variable-value!, define-variable!, and lookup-variable-value can be expressed in terms of more abstract procedures for traversing the environment structure. Define abstractions that capture the common patterns and redefine the three procedures in terms of these abstractions. 
438 
439 
440 ;; test-suite
441 
442 ;; procedure definitions
443 
444 (geval 
445  '(define (assoc key records)
446     (cond ((null? records) false)
447 	  ((equal? key (caar records)) (car records))
448 	  (else (assoc key (cdr records))))))
449 
450 (geval
451  '(define (map proc list)
452     (if (null? list)
453 	'()
454 	(cons (proc (car list))
455 	      (map proc (cdr list))))))
456 
457 (geval 
458  '(define (accumulate op initial sequence)
459     (if (null? sequence)
460 	initial
461 	(op (car sequence)
462 	    (accumulate op initial (cdr sequence))))))
463 
464 ;; all special forms
465 (test-eval '(begin 5 6) 6)
466 (test-eval '10 10)
467 (geval '(define x 3))
468 (test-eval 'x 3)
469 (test-eval '(set! x -25) 'ok)
470 (test-eval 'x -25)
471 (geval '(define z (lambda (x y) (+ x (* x y)))))
472 (test-eval '(z 3 4) 15)
473 (test-eval '(cond ((= x -2) 'x=-2)
474 		  ((= x -25) 'x=-25)
475 		  (else 'failed))
476 	   'x=-25)
477 (test-eval '(if true false true) false)
478 (test-eval 
479  '(let ((x 4) (y 7))
480     (+ x y (* x y)))
481  (+ 4 7 (* 4 7)))
482 
483 
484 ;; and/or
485 (geval '(define x (+ 3 8)))
486 (test-eval '(and 0 true x) 11)
487 (test-eval '(and 0 true x false) false)
488 (test-eval '(and 0 true x (set! x -2) false) false)
489 (test-eval 'x -2)
490 (test-eval '(and 0 true x false (set! x -5)) false)
491 (test-eval 'x -2)
492 (test-eval '(or false (set! x 25)) 'ok)
493 (test-eval 'x 25)
494 (test-eval '(or (set! x 2) (set! x 4)) 'ok)
495 (test-eval 'x 2)
496 (test-eval '(or false (set! x 25) true false) 'ok)
497 (test-eval 'x 25)
498 (test-eval '(or ((lambda (x) x) 5)) 5)
499 (test-eval '(or (begin (set! x (+ x 1)) x)) 26)
500 
501 
502 ;; cond
503 
504 (test-eval 
505  '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
506 	(else false))
507  2)
508 
509 (test-eval
510  '(cond ((= 3 4) 'not-true)
511 	((= (* 2 4) 3) 'also-false)
512 	((map (lambda (x)
513 		(* x (+ x 1)))
514 	      '(2 4 1 9))
515 	 =>
516 	 (lambda (x)
517 	   (accumulate + 0 x)))
518 	(else 'never-reach))
519  118)
520 ;; '(6 20 2 90)
521 
522 
523 ;; procedure definition and application
524 (geval
525  '(define (factorial n)
526     (if (= n 0)
527 	1
528 	(* n (factorial (- n 1))))))
529 (test-eval '(factorial 5) 120)
530 
531 ;; map
532 
533 (test-eval
534  '(map (lambda (x)
535 	 (* x (+ x 1)))
536        '(2 1 4 2 8 3))
537  '(6 2 20 6 72 12))
538 ;; accumulate
539 
540 (test-eval
541  '(accumulate + 0 '(1 2 3 4 5))
542  15)
543 
544 ;; make-let
545 (test-eval 
546  (make-let '(x y) '(3 5) '((+ x y)))
547  8)
548 (test-eval 
549  '(let ()
550     5)
551  5)
552 (test-eval
553  '(let ((x 3))
554     x)
555  3)
556 (test-eval
557  '(let ((x 3)
558 	(y 5))
559     (+ x y))
560  8)
561 (test-eval 
562  '(let ((x 3)
563 	(y 2))
564     (+ (let ((x (+ y 2))
565 	     (y x))
566 	 (* x y))
567        x y))
568  (+ (* 4 3) 3 2))
569 (test-eval
570  '(let ((x 6)
571 	(y (let ((x 2))
572 	     (+ x 3)))
573 	(z (let ((a (* 3 2)))
574 	     (+ a 3))))
575     (+ x y z))
576  (+ 6 5 9))
577     
578 
579 ;; let*
580 
581 (test-eval
582  '(let* ((x 3)
583 	 (y (+ x 2))
584 	 (z (+ x y 5)))
585     (* x z))
586  39)
587 
588 (test-eval
589  '(let* ()
590     5)
591  5)
592 (test-eval
593  '(let* ((x 3))
594     (let* ((y 5))
595       (+ x y)))
596  8)
597 
598 (test-eval 
599  '(let* ((x 3)
600 	 (y (+ x 1)))
601     (+ (let* ((x (+ y 2))
602 	      (y x))
603 	 (* x y))
604        x y))
605  (+ (* 6 6) 3 4))
606 (test-eval
607  '(let* ((x 6)
608 	 (y (let* ((x 2)
609 		   (a (let* ((x (* 3 x)))
610 			(+ x 2))))       
611 	      (+ x a)))                  
612 	 (z (+ x y)))                    
613     (+ x y z))
614  32)
615 
616 ;; named-let
617 
618 (test-eval
619  '(let eight ()
620     5
621     7
622     8)
623  8)
624 (test-eval
625  '(let loop ((count 0))
626     (if (= 100 count)
627 	count
628 	(loop (+ count 1))))
629  100)
630 (geval
631  '(define (prime? x)
632     (let prime-iter ((i 2))
633       (cond ((> (* i i) x) true)
634 	    ((= (remainder x i) 0) false)
635 	    (else (prime-iter (+ i 1)))))))
636 (test-eval
637  '(let primes ((x 2)
638 	       (n 20))
639     (cond ((= n 0) '())
640 	  ((prime? x) 
641 	   (cons x
642 		 (primes (+ x 1) (- n 1))))
643 	  (else (primes (+ x 1) n))))
644  '(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71))
645 
646 (geval
647  '(define (fib n)
648     (let fib-iter ((a 1)
649 		   (b 0)
650 		   (count n))
651       (if (= count 0)
652 	  b
653 	  (fib-iter (+ a b) a (- count 1))))))
654 (test-eval '(fib 19) 4181)
655 
656 ;; do-loop	  
657 (test-eval
658  '(let ((y 0))
659     (do ((x 0 (+ x 1)))
660 	((= x 5) y)
661       (set! y (+ y 1))))
662  5)
663 (test-eval
664  '(do ()
665       (true))
666  true)
667 (test-eval
668  '(do ()
669       (true 5))
670  5)
671 (test-eval
672  '(let ((y 0))
673     (do ()
674 	((= y 5) y)
675       (set! y (+ y 1))))
676  5)
677 
678 (test-eval
679  '(do ((y '(1 2 3 4)))
680       ((null? y))
681     (set! y (cdr y)))
682  true)
683 (test-eval
684  '(let ((y 0))
685     (do ((x 0 (+ x 1)))
686 	((= x 5) y)
687       (set! y (+ y 1))))
688  5)
689 (test-eval
690  '(let ((x '(1 3 5 7 9)))
691     (do ((x x (cdr x))
692 	 (sum 0 (+ sum (car x))))
693 	((null? x) sum)))
694  25)
695 (test-eval 
696  '(let ((z '()))
697     (do ((x '(1 2 3 4) (cdr x))
698 	 (y '(1 2 3 4 5 6 7 8) (cddr y)))
699 	((null? x) y x z)
700       (set! z (cons (car x) z))))
701  '(4 3 2 1))
702 
703 
704