1 ;; Exercise 2.83.  Suppose you are designing a generic arithmetic system for dealing with the tower of types shown in figure 2.25: integer, rational, real, complex. For each type (except complex), design a procedure that raises objects of that type one level in the tower. Show how to install a generic raise operation that will work for each type (except complex). 
2 
3 ;; we have to modify our packages so that we have 4 types: integer, rational, real, and complex
4 
5 (define (attach-tag type-tag contents)
6   (if (or (eq? type-tag 'integer)
7 	  (eq? type-tag 'real))
8       contents
9       (cons type-tag contents)))
10 (define (type-tag datum)
11   (cond ((pair? datum) (car datum))
12 	((exact? datum) 'integer)
13 	((number? datum) 'real)
14 	((error "error -- invalid datum" datum))))
15 (define (contents datum)
16   (cond ((pair? datum) (cdr datum))
17 	((exact? datum) datum)
18 	((number? datum) (exact->inexact datum))
19 	((error "error -- invalid datum" datum))))
20 
21 (define (make-table)
22   (define (assoc key records)
23     (cond ((null? records) false)
24 	  ((equal? key (caar records)) (car records))
25 	  (else (assoc key (cdr records)))))
26   (let ((local-table (list '*table*)))
27     (define (lookup key-1 key-2)
28       (let ((subtable (assoc key-1 (cdr local-table))))
29 	(if subtable
30 	    (let ((record (assoc key-2 (cdr subtable))))
31 	      (if record
32 		  (cdr record)
33 		  false))
34 	    false)))
35     (define (insert! key-1 key-2 value)
36       (let ((subtable (assoc key-1 (cdr local-table))))
37 	(if subtable
38 	    (let ((record (assoc key-2 (cdr subtable))))
39 	      (if record
40 		  (set-cdr! record value)
41 		  (set-cdr! subtable
42 			    (cons (cons key-2 value)
43 				  (cdr subtable)))))
44 	    (set-cdr! local-table
45 		      (cons (list key-1
46 				  (cons key-2 value))
47 			    (cdr local-table)))))
48       'ok)
49     (define (dispatch m)
50       (cond ((eq? m 'lookup-proc) lookup)
51 	    ((eq? m 'insert-proc!) insert!)
52 	    (else (error "Unknown operation -- TABLE" m))))
53     dispatch))
54 
55 (define operation-table (make-table))
56 (define get (operation-table 'lookup-proc))
57 (define put (operation-table 'insert-proc!))
58 (define coercion-table (make-table))
59 (define get-coercion (coercion-table 'lookup-proc))
60 (define put-coercion (coercion-table 'insert-proc!))
61 
62 (define (add x y) (apply-generic 'add x y))
63 (define (sub x y) (apply-generic 'sub x y))
64 (define (mul x y) (apply-generic 'mul x y))
65 (define (div x y) (apply-generic 'div x y))
66 (define (equ? x y) (apply-generic 'equ? x y))
67 (define (=zero? x) (apply-generic '=zero? x))
68 (define (raise x) (apply-generic 'raise x))
69 
70 (define (install-integer-package)
71   (define (tag x) (attach-tag 'integer x))
72   (put 'add '(integer integer)
73        (lambda (x y) (tag (+ x y))))
74   (put 'sub '(integer integer) 
75        (lambda (x y) (tag (- x y))))
76   (put 'mul '(integer integer)
77        (lambda (x y) (tag (* x y))))
78   (put 'div '(integer integer)
79        (lambda (x y) (tag (quotient x y))))
80   ;; 	 (if (integer? (/ x y))
81   ;; 	     (tag (/ x y))
82   ;; 	     (div (raise (tag x))
83   ;; 		  (raise (tag y))))))
84   ;; ;; we avoided calling make-rational to avoid dependencies
85   (put 'equ? '(integer integer) =)
86   (put '=zero? '(integer) zero?)
87   (put 'make 'integer
88        (lambda (n) 
89 	 (if (exact? n)
90 	     (tag n)
91 	     (error "Not an exact integer" n))))
92   (put 'raise '(integer)
93        (lambda (x) (make-rational x 1)))
94   'done)
95 
96 (define (install-rational-package)
97   (define (gcd a b)
98     (if (= b 0)
99 	a
100 	(gcd b (remainder a b))))
101   (define (numer x) (car x))
102   (define (denom x) (cdr x))
103   (define (make-rat n d)
104     (if (not (and (integer? n) (integer? d)))
105 	(error "Both numerator and denominator must be integers" 
106 	       (list n d))
107 	(let ((g (gcd n d)))
108 	  (cons (/ n g) (/ d g)))))
109   (define (add-rat x y)
110     (make-rat (+ (* (numer x) (denom y))
111 		 (* (numer y) (denom x)))
112 	      (* (denom x) (denom y))))
113   (define (sub-rat x y)
114     (make-rat (- (* (numer x) (denom y))
115 		 (* (numer y) (denom x)))
116 	      (* (denom x) (denom y))))
117   (define (mul-rat x y)
118     (make-rat (* (numer x) (numer y))
119 	      (* (denom x) (denom y))))
120   (define (div-rat x y)
121     (make-rat (* (numer x) (denom y))
122 	      (* (denom x) (numer y))))
123   (define (equ-rat? x y)
124     (and (= (numer x) (numer y))
125 	 (= (denom x) (denom y))))
126   (define (=zero-rat? x) (= (numer x) 0))
127   (define (tag x) (attach-tag 'rational x))
128   (put 'add '(rational rational) 
129        (lambda (x y) (tag (add-rat x y))))
130   (put 'sub '(rational rational) 
131        (lambda (x y) (tag (sub-rat x y))))
132   (put 'mul '(rational rational) 
133        (lambda (x y) (tag (mul-rat x y))))
134   (put 'div '(rational rational) 
135        (lambda (x y) (tag (div-rat x y))))
136   (put 'equ? '(rational rational) equ-rat?)
137   (put '=zero? '(rational) =zero-rat?)
138   (put 'make 'rational
139        (lambda (n d) (tag (make-rat n d))))
140   (put 'raise '(rational)
141        (lambda (x) (make-real (/ (numer x) (denom x)))))
142 
143   'done)
144 
145 (define (install-real-package)
146   (define (tag x) (attach-tag 'real x))
147   (put 'add '(real real)
148        (lambda (x y) (tag (+ x y))))
149   (put 'sub '(real real) 
150        (lambda (x y) (tag (- x y))))
151   (put 'mul '(real real)
152        (lambda (x y) (tag (* x y))))
153   (put 'div '(real real)
154        (lambda (x y) (tag (/ x y))))
155   (put 'equ? '(real real) =)
156   (put '=zero? '(real) zero?)
157   (put 'make 'real
158        (lambda (n) 
159 	 (if (rational? n)
160 	     (tag (exact->inexact n))
161 	     (tag n))))
162   (put 'raise '(real)
163        (lambda (x) (make-complex-from-real-imag x 0)))
164 
165   'done)
166 
167 (define (install-complex-package)
168   (define (make-from-real-imag x y)
169     ((get 'make-from-real-imag 'rectangular) x y))
170   (define (make-from-mag-ang r a)
171     ((get 'make-from-mag-ang 'polar) r a))
172 
173   (define (real-part z) (apply-generic 'real-part z))
174   (define (imag-part z) (apply-generic 'imag-part z))
175   (define (magnitude z) (apply-generic 'magnitude z))
176   (define (angle z) (apply-generic 'angle z))
177 
178   ;; rectangular and polar representations...
179 
180   (define (install-complex-rectangular)
181     (define (make-from-real-imag-rectangular x y)
182       (cons x y))
183     (define (make-from-mag-ang-rectangular r a)
184       (cons (* r (cos a)) (* r (sin a))))
185     (define (real-part z) (car z))
186     (define (imag-part z) (cdr z))
187     (define (magnitude z)
188       (sqrt (+ (square (real-part z)) 
189 	       (square (imag-part z)))))
190     (define (angle z) (atan (imag-part z) (real-part z)))
191     (define (tag x) (attach-tag 'rectangular x))
192     (put 'real-part '(rectangular) real-part)
193     (put 'imag-part '(rectangular) imag-part)
194     (put 'magnitude '(rectangular) magnitude)
195     (put 'angle '(rectangular) angle)
196     (put 'make-from-real-imag 'rectangular
197 	 (lambda (x y) (tag (make-from-real-imag-rectangular x y))))
198     (put 'make-from-mag-ang 'rectangular
199 	 (lambda (r a) (tag (make-from-mag-ang-rectangular r a))))
200     'done)
201   (define (install-complex-polar)
202     (define (make-from-real-imag-polar x y)
203       (cons (sqrt (+ (square x) (square y)))
204 	    (atan y x)))
205     (define (make-from-mag-ang-polar r a)
206       (cons r a))
207     (define (real-part z) (* (magnitude z) (cos (angle z))))
208     (define (imag-part z) (* (magnitude z) (sin (angle z))))
209     (define (magnitude z) (car z))
210     (define (angle z) (cdr z))
211     (define (tag x) (attach-tag 'polar x))
212     (put 'real-part '(polar) real-part)
213     (put 'imag-part '(polar) imag-part)
214     (put 'magnitude '(polar) magnitude)
215     (put 'angle '(polar) angle)
216     (put 'make-from-real-imag 'polar
217 	 (lambda (x y) (tag (make-from-real-imag-polar x y))))
218     (put 'make-from-mag-ang 'polar
219 	 (lambda (r a) (tag (make-from-mag-ang-polar r a))))
220     'done)  
221   (install-complex-rectangular)
222   (install-complex-polar)
223   ;; end rectangular and polar representations
224 
225   (define (add-complex z1 z2)
226     (make-from-real-imag (+ (real-part z1) (real-part z2))
227 			 (+ (imag-part z1) (imag-part z2))))
228   (define (sub-complex z1 z2)
229     (make-from-real-imag (- (real-part z1) (real-part z2))
230 			 (- (imag-part z1) (imag-part z2))))
231   (define (mul-complex z1 z2)
232     (make-from-mag-ang (* (magnitude z1) (magnitude z2))
233 		       (+ (angle z1) (angle z2))))
234   (define (div-complex z1 z2)
235     (make-from-mag-ang (/ (magnitude z1) (magnitude z2))
236 		       (- (angle z1) (angle z2))))
237   (define (equ-complex? z1 z2)
238     (or (and (= (real-part z1) (real-part z2))
239 	     (= (imag-part z1) (imag-part z2))) ;; in case of rounding error
240 	(and (= (magnitude z1) (magnitude z2))
241 	     (= (angle z1) (angle z2)))))
242   (define (=zero-complex? z) 
243     (and (= (real-part z) 0)
244 	 (= (imag-part z) 0)))
245 
246   (define (tag x) (attach-tag 'complex x))
247   (put 'add '(complex complex) 
248        (lambda (z1 z2) (tag (add-complex z1 z2))))
249   (put 'sub '(complex complex) 
250        (lambda (z1 z2) (tag (sub-complex z1 z2))))
251   (put 'mul '(complex complex) 
252        (lambda (z1 z2) (tag (mul-complex z1 z2))))
253   (put 'div '(complex complex) 
254        (lambda (z1 z2) (tag (div-complex z1 z2))))
255   (put 'equ? '(complex complex) equ-complex?)
256   (put '=zero? '(complex) =zero-complex?)
257   (put 'make-from-real-imag 'complex 
258        (lambda (x y) (tag (make-from-real-imag x y))))
259   (put 'make-from-mag-ang 'complex 
260        (lambda (r a) (tag (make-from-mag-ang r a))))
261   'done)
262 
263 (define (make-integer n)
264   ((get 'make 'integer) n))
265 (define (make-rational n d)
266   ((get 'make 'rational) n d))
267 (define (make-real n)
268   ((get 'make 'real) n))
269 (define (make-complex-from-real-imag x y) 
270   ((get 'make-from-real-imag 'complex) x y))
271 (define (make-complex-from-mag-ang r a) 
272   ((get 'make-from-mag-ang 'complex) r a))
273 
274 (define (apply-generic op . args)
275   (let ((type-tags (map type-tag args)))
276     (let ((proc (get op type-tags)))
277       (if proc
278 	  (apply proc (map contents args))
279 	  (if (= (length args) 2)
280 	      (let ((type1 (car type-tags))
281 		    (type2 (cadr type-tags))
282 		    (a1 (car args))
283 		    (a2 (cadr args)))
284 		(let ((t1->t2 (get-coercion type1 type2))
285 		      (t2->t1 (get-coercion type2 type1)))
286 		  (cond (t1->t2
287 			 (apply-generic op (t1->t2 a1) a2))
288 			(t2->t1
289 			 (apply-generic op a1 (t2->t1 a2)))
290 			(else
291 			 (error "No method for these types"
292 				(list op type-tags))))))			
293 	      (error "No method for these types"
294 		     (list op type-tags)))))))
295 
296 ;; install number packages
297 
298 (install-integer-package)
299 (install-rational-package)
300 (install-real-package)
301 (install-complex-package)
302 
303 
304 (define (test-case actual expected)
305   (newline)
306   (display "Actual:   ")
307   (display actual)
308   (newline)
309   (display "Expected: ")
310   (display expected)
311   (newline))
312 
313 (test-case (equ? (add (make-integer 3) (make-integer 4))
314 		 (sub (make-integer 12) (make-integer 5))) #t)
315 (test-case (equ? (div (make-integer 24) (make-integer 4))
316 		 (mul (make-integer 2) (make-integer 3))) #t)
317 (test-case (equ? (add (make-integer 3) (make-integer 3))
318 		 (sub (make-integer 12) (make-integer 5))) #f)
319 (test-case (equ? (div (make-integer 24) (make-integer 4))
320 		 (mul (make-integer 2) (make-integer 2))) #f)
321 (test-case (=zero? (sub (div (make-integer 24) (make-integer 4))
322 		       (mul (make-integer 2) (make-integer 3)))) #t)
323 (test-case (=zero? (sub (div (make-integer 24) (make-integer 4))
324 		       (mul (make-integer 2) (make-integer 4)))) #f)
325 (test-case (make-integer 5) 5)
326 (test-case (type-tag (make-integer 5)) 'integer)
327 (test-case (type-tag (make-real 5)) 'real)
328 (test-case (make-real 1.66667) 1.66667)
329 (test-case (make-real (/ 5 3)) 1.66667)
330 (test-case (type-tag (make-real (/ 5 3))) 'real)
331 
332 (test-case (div (make-integer 3) (make-integer 4)) 0)
333 (test-case (=zero? (sub (make-rational 4 1)
334 		       (div (add (make-rational 1 2)
335 				 (make-rational 3 2))
336 			    (mul (make-rational 3 2)
337 				 (make-rational 2 6))))) #t)
338 (test-case (=zero? (sub (make-rational 4 1)
339 		       (div (add (make-rational 1 2)
340 				 (make-rational 3 2))
341 			    (mul (make-rational 3 2)
342 				 (make-rational 2 5))))) #f)
343 (test-case (equ? (add (make-rational 7 2)
344 		      (make-rational 2 4))
345 		 (div (add (make-rational 1 2)
346 			   (make-rational 3 2))
347 		      (mul (make-rational 3 2)
348 			   (make-rational 2 6)))) #t)
349 (test-case (equ? (add (make-rational 3 2)
350 		      (make-rational 2 4))
351 		 (div (add (make-rational 1 2)
352 			   (make-rational 3 2))
353 		      (mul (make-rational 3 2)
354 			   (make-rational 1 6)))) #f)
355 (test-case (equ? (div (make-rational 4 2)
356 		      (make-rational 1 3))
357 		 (sub (make-rational 9 1)
358 		      (mul (make-rational 4 1)
359 			   (make-rational 3 4)))) #t)
360 (test-case (equ? (div (make-rational 4 2)
361 		      (make-rational 1 3))
362 		 (sub (make-rational 9 1)
363 		      (mul (make-rational 4 1)
364 			   (make-rational 3 5)))) #f)
365 (test-case (equ? (add (make-complex-from-real-imag 3 4)
366 		      (make-complex-from-real-imag -5 -3))
367 		 '(complex rectangular -2 . 1))
368 	   #t)
369 (test-case (equ? (add (make-complex-from-real-imag 3 4.5)
370 		      (make-complex-from-real-imag -5 -3))
371 		 '(complex rectangular -2 . 1))
372 	   #f)
373 (test-case (=zero? (sub (add (make-complex-from-real-imag 3 4)
374 			     (make-complex-from-real-imag -5 -3))
375 			'(complex rectangular -2 . 1)))
376 	   #t)
377 
378 (test-case (=zero? (sub (add (make-complex-from-real-imag 3 5)
379 			     (make-complex-from-real-imag -5 -3))
380 			'(complex rectangular -2 . 1)))
381 	   #f)
382 
383 
384 (test-case (raise (make-integer 5)) '(rational 5 . 1))
385 (test-case (raise (raise (make-integer 5))) 5.)
386 (test-case (raise (raise (raise (make-integer 5)))) '(complex rectangular 5. . 0))
387 
388 (test-case (raise (make-rational 5 3)) 1.666667)
389 (test-case (raise (raise (make-rational 5 3))) '(complex rectangular 1.666667 . 0))
390 
391 
392 
393